10   REM LMODL.BS5
11   PRINT TAB(16);"l"
15   PRINT TAB(16);"&[&E&L"
20   PRINT TAB(16);"A"
30   PRINT TAB(16);"&[&E&P"
35   PRINT TAB(15);"/&[&E&J\"
40   PRINT TAB(14);"/&[&E&Y &[&E&Y\"
45   SET S=5
50   PRINT TAB(12);"/&[&E&B=-^-=&[&E&B\"
60   PRINT TAB(12);"I&[&E&X  U  &[&E&XI"
70   PRINT TAB(11);"/I&[&E&X  S  &[&E&XI\"
75   PRINT TAB(9);"/  I&[&E&J  A  &[&E&JI  \"
80   PRINT TAB(9);"I  I&[&E&\     &[&E&_I  I"
85   PRINT TAB(9);"I/-&[&E&V&[&E&Q . . &[&E&T&[&E&V-\I"
90   PRINT TAB(13);"&[&E&G^&[&E&G^&[&E&G^&[&E&G"
100  REM ARKABLE LUNAR LANDING SIMULATION   
110  REM CONVERTED FOR UNIVAC BY MIKE VAN PELT  
120  REM STOLEN BY J. EMMETT BLACK AND IMPLEMENTED  
130  REM COURTESY OF THE DEMONSTRATION PROGRAM PEOPLE  
140  REM AT THE UNIVERSITY OF ALABAMA.  ROLL TIDE!  
150  REM 
160  REM ======= LAST MOD.  07/23/77  R.E.H.   
170  PRINT 
180  PRINT TAB(10);"*** L U N A R  -  M O D U L E ***"
190  PRINT 
195  SET S=40
200  PRINT "GROUND CONTROL CALLING LUNAR MODULE..."
205  SET S=10
210  PRINT "&JON BOARD COMPUTER AND GROUND COMPUTER HAVE"
220  PRINT "SIMULTANEOUSLY MALFUNCTIONED.&J"
225  SET S=0
230  PRINT "### MANUAL CONTROL IS NECESSARY ###&J"
240  PRINT "ESITMATED FREE FALL IMPACT TIME 60 SECONDS."
250  PRINT "SET RETRO-ROCKET BURN RATE EVERY 10 SECONDS."
260  PRINT "TO ANY VALUE BETWEEN 0 LBS/SEC (FREE FALL) AND...&J"
270  PRINT " 200 LBS/SEC SEC"," MI+FT","FT/SEC"," LB FUEL"
280  A=60
290  V=1
300  M=32500
310  N=16000
320  G=0.001
330  Z=1.8
340  PRINT L,INT(A);INT(5280*(A-INT(A))),5280*V,M-N;
350  INPUT "---=>"K
355  PRINT 
360  IF K<=200 THEN 400
370  PRINT " TOO HIGH A BURN RATE, HOW DOES IT FEEL TO BE"
380  PRINT " SQUASHED. TRY AGAIN WITH SOMETHING REASONABLE"
390  GOTO 350
400  IF K>=0 THEN 440
410  PRINT " HAVE YOU GOT A MATTER TRANSMUTER ABOARD?"
420  PRINT "WHAT DO YOU THINK THIS IS,  A GAME??,,TRY AGAIN"
430  GOTO 350
440  T=10
450  IF M-N<0.001 THEN 560
460  IF T<0.001 THEN 340
470  S=T
480  IF M>=N+S*K THEN 500
490  S=(M-N)/K
500  GOSUB 1050
510  IF I<=0 THEN 910
520  IF V<=0 THEN 540
530  IF J<0 THEN 970
540  GOSUB 850
550  GOTO 450
560  PRINT "RAN OUT OF FUEL AT ";L;" SECONDS."
570  S=(-V+SQR(V*V+2*A*G))/G
580  V=V+G*S
590  L=L+S
600  W=3600*V
610  PRINT "ON THE MOON AT ";L;" SEC.- IMPACT VEL. ";W;" MPH."
620  IF M-N<0 THEN 640
630  PRINT "FUEL LEFT: ";M-N;" LBS."
640  IF W>1.2 THEN 710
650  PRINT "PERFECT LANDING!!!!!!!!!!!"
660  PRINT " DO YOU WANT TO PLAY AGAIN, INPUT  YES=1 ";
670  INPUT I9
680  L=0
690  IF I9=1 THEN 270
700  GOTO 1090
710  IF W>10 THEN 750
720  PRINT "GOOD LANDING.  COULD HAVE BEEN BETTER"
730  GOTO 660
740  GOTO 1090
750  IF W>60 THEN 800
760  PRINT "CRAFT DAMAGE.  YOU'RE STRANDED THERE UNTIL"
770  PRINT " A RESCUE MISSION ARRIVES"
780  GOTO 660
790  GOTO 1090
800  PRINT "SORRY BUT THERE WERE NO SURVIVORS. YOU BLEW IT."
810  PRINT "IN FACT, YOU BLASTED A NEW LUNAR CRATER "
820  PRINT ((W*100)*3)/63.4;" FT. DEEP."
830  GOTO 660
840  GOTO 1090
850  L=L+S
860  T=T-S
870  M=M-S*K
880  A=I
890  V=J
900  RETURN 
910  IF S<0.05 THEN 600
920  D=V+SQR(V*V+2*A*(G-Z*K/M))
930  S=2*A/D
940  GOSUB 1050
950  GOSUB 850
960  GOTO 910
970  W=(1-M*G/(Z*K))/2
980  S=M*V/(Z*K*(W+SQR(W*W+V/Z)))+0.05
990  GOSUB 1050
1000 IF I<=0 THEN 910
1010 GOSUB 850
1020 IF J>0 THEN 450
1030 IF V>0 THEN 970
1040 GOTO 450
1050 Q=S*K/M
1060 J=V+G*S-Z*Q*(1+Q*(0.5+Q*(1/3+Q*(0.25+Q/5))))
1070 I=A-G*S*S/2-V*S+Z*S*Q*(0.5+Q*(1/6+Q*(1/12+Q/20)))
1080 RETURN 
1090 END