10   REM POKER.BS5
100  REM ===== MIKE VIRNIG---AUTHOR
110  PRINT 
120  PRINT "WELCOME TO   ***  P O K E R  ***"
130  PRINT 
140  PRINT 
150  PRINT "YOU HAVE 10,000.00 DOLLARS."
160  PRINT 
170  DIM C(52),K(52),M(5),N(5)
180  DIM Z(52),S(52)
190  T=10000
200  T9=100000
210  B9=(INT(RND(0)*9)+4)*1000
300  C=0
310  PRINT "YOUR HAND"
320  PRINT 
330  FOR I=1 TO 52
340     C(I)=RND(0)
350     K(I)=I
360  NEXT I
365  PRINT TAB(15);"....NOW BEING DEALT..."
367  REM .LINE 380 WAS "J=1 TO 51" --- CHANGED to speed up game
370  FOR I=2 TO 52
380     FOR J=I TO 51
390        IF C(I)<C(J) THEN 420
400        P7=C(J): C(J)=C(I): C(I)=P7
410        P7=K(J): K(J)=K(I): K(I)=P7
420     NEXT J
430  NEXT I
435  PRINT "-----------------------------------------------&J"
440  FOR I=1 TO 5
450     N(I)=INT((K(I)-1)/13)
460     M(I)=K(I)-(N(I)*13)
470     P8=N(I)
480     P9=M(I)
490     GOSUB 1700: GOSUB 1900
500  NEXT I
510  C=C+1
520  GOSUB 700
530  V(C)=V: P5=1
540  IF C=1 THEN GOSUB 1440
545  IF P5=0 THEN 640
550  FOR I=1 TO 5
560     K(I)=K(I+5)
570  NEXT I
580  IF C=1 THEN PRINT "MY HAND......"
590  PRINT 
600  IF C<2 THEN 440
610  IF V(1)>V(2) THEN PRINT "YOU WIN..."
620  IF V(2)>V(1) THEN PRINT "COMPUTER WINS"
630  IF V(1)=V(2) THEN PRINT "DRAW."
640  PRINT 
650  GOSUB 1580
660  SET S=40
670  PRINT "&J NEW HAND > > > > > > > > - - -&J"
680  SET S=0
690  GOTO 300
700  REM ============= SUBROUTINE EVALUATES HANDS  
710  PRINT 
720  V=0
730  FOR K=1 TO 52
740     Z(K)=0
750     S(K)=0
760  NEXT K
770  FOR L=2 TO 5
780     FOR K=1 TO 4
790        IF M(L)<M(K) THEN 810
800        P7=M(K): M(K)=M(L): M(L)=P7
810     NEXT K
820  NEXT L
830  FOR L=1 TO 13
840     FOR K=1 TO 5
850        IF M(K)=L THEN S(L)=S(L)+1
860     NEXT K
870     Z(L)=L
880  NEXT L
890  FOR L=2 TO 13
900     FOR K=1 TO 12
910        IF S(L)<S(K) THEN 940
920        P7=S(L): S(L)=S(K): S(K)=P7
930        P7=Z(L): Z(L)=Z(K): Z(K)=P7
940     NEXT K
950  NEXT L
960  E=0
970  FOR K=1 TO 4
980     IF M(K)<>M(K+1)+1 THEN 1030
990  NEXT K
1000 PRINT "STRAIGHT"
1010 V=5000+M(1)
1020 E=1
1030 FOR K=1 TO 5
1040    FOR L=1 TO 5
1050       IF N(K)<>N(L) THEN 1110
1060    NEXT L
1070 NEXT K
1080 PRINT "FLUSH"
1090 V=V+6000
1100 RETURN 
1110 IF E=1 THEN RETURN 
1120 IF S(1)<>4 THEN 1170
1130 P9=Z(1)
1140 PRINT "FOUR ";: GOSUB 1700: PRINT "S"
1150 V=7000+(Z(1)*10)
1160 RETURN 
1170 IF S(1)<>3 THEN 1250
1180 IF S(2)<>2 THEN 1210
1190 PRINT "FULL HOUSE"
1200 RETURN 
1210 P9=Z(1)
1220 PRINT "THREE ";: GOSUB 1700: PRINT "S"
1230 IF Z(2)>Z(3) THEN P5=Z(2): P6=Z(3)
1232 IF Z(2)<Z(3) THEN P6=Z(2): P5=Z(3)
1235 V=4000+(Z(1)*10)+(P5/10)+(P6/1000)
1240 RETURN 
1250 IF S(1)<>2 THEN 1400
1260 IF S(2)<>2 THEN 1300
1270 PRINT "TWO PAIR"
1280 IF Z(1)>Z(2) THEN P5=Z(1): P6=Z(2)
1282 IF Z(1)<Z(2) THEN P6=Z(1): P5=Z(2)
1285 V=3000+(P5*10)+(P6/10)+(Z(3)/1000)
1290 RETURN 
1300 PRINT "ONE PAIR"
1310 FOR K=3 TO 5
1320    FOR L=2 TO 4
1330       IF Z(K)<Z(L) THEN 1350
1340       P7=Z(K): Z(K)=Z(L): Z(L)=P7
1350    NEXT 
1360 NEXT K
1370 LET V=2000+(Z(1)*10)+Z(2)
1380 V=V+(V/10)+(Z(3)/1000)+(Z(4)/100000)+(Z(5)/10000000)
1390 RETURN 
1400 P9=M(1)
1410 GOSUB 1700: PRINT "  IS THE   &[&E&@ HIGH CARD &[&E&@"
1420 V=(M(1)*100)+M(2)+(M(3)/100)+(M(4)/10000)+(M(5)/1000000)
1430 RETURN 
1440 PRINT 
1450 PRINT " PLEASE PLACE YOUR BET. ";
1460 INPUT B
1470 IF B<1 THEN 1560
1480 IF B>T THEN 1520
1490 IF B<>INT(B) THEN 1540
1500 GOSUB 2000
1510 RETURN 
1520 PRINT "YOU ONLY HAVE ";T;" DOLLARS"
1530 GOTO 1440
1540 PRINT "PLEASE USE AN INTEGER."
1550 GOTO 1440
1560 PRINT "PLEASE USE A POSITIVE NUMBER."
1570 GOTO 1440
1580 IF V(1)>V(2) THEN T=T+B
1590 IF V(2)>V(1) THEN T=T-B
1595 IF P5=0 THEN T=T-B
1600 PRINT "YOU HAVE ";T;" DOLLARS"
1610 IF T<=0 THEN PRINT "YOU ARE BROKE !"
1620 IF T<=0 THEN 3000
1630 IF T<T9 THEN 1690
1640 PRINT "&K&[&B&D&[&A&S### THAT'S IT !!! ###&J&J"
1650 PRINT "&[&A&K###  I   Q U I T  !!!  ###&J&J"
1660 PRINT "  DO YOU KNOW....that with all MY $";T;" DOLLARS"
1670 PRINT "...YOU can buy a house.  I'M going to be SOLD!"
1680 GOTO 3000
1690 RETURN 
1700 IF P9=1 THEN PRINT "   DEUCE";
1710 IF P9=2 THEN PRINT "   THREE";
1720 IF P9=3 THEN PRINT "   FOUR";
1730 IF P9=4 THEN PRINT "   FIVE";
1740 IF P9=5 THEN PRINT "   SIX";
1750 IF P9=6 THEN PRINT "   SEVEN";
1760 IF P9=7 THEN PRINT "   EIGHT";
1770 IF P9=8 THEN PRINT "   NINE";
1775 IF P9=9 THEN PRINT "   TEN";
1780 IF P9=10 THEN PRINT "&[&E&X  JACK";
1790 IF P9=11 THEN PRINT "&[&E&N  QUEEN";
1800 IF P9=12 THEN PRINT "&[&E&J  KING";
1810 IF P9=13 THEN PRINT "&[&E&E  ACE";
1820 RETURN 
1900 PRINT "&[&A&S";
1905 IF P8=0 THEN PRINT "OF  &[&E&Z?  HEARTS  &[&E&Z?"
1910 IF P8=1 THEN PRINT "OF <&[&E&Y> DIAMONDS <&[&E&Y>"
1920 IF P8=2 THEN PRINT "OF .@.  CLUBS   .@."
1930 IF P8=3 THEN PRINT "OF  &[&E&G   SPADES   &[&E&G"
1940 RETURN 
2000 PRINT 
2010 IF B<101 THEN RETURN 
2020 IF B<T9 THEN 2100
2030 P6=INT(RND(0)*5)+1: P5=0
2040 IF P6=1 THEN PRINT " ### NO WAY ! ###&JI allready owe the bank.&J""
2050 IF P6=2 THEN PRINT " ### WRONG ! ###&JI'm not made of GOLD"
2060 IF P6=3 THEN PRINT " ### I'M NOT DUMB ENOUGH FOR THAT BET ###&J"
2070 IF P6=4 THEN PRINT " ### HA-HA-HA ! ###&J"
2080 IF P6=5 THEN PRINT " #  I think I'll just quietly FOLD #&J"
2090 RETURN 
2100 IF B<1001 THEN 2300
2110 P6=INT(RND(0)*18)+1: IF RND(0)>.8 THEN 2300
2120 IF P6=1 THEN PRINT "Hmmmmm....&J"
2130 IF P6=2 THEN PRINT "Well...ahh...&J"
2140 IF P6=3 THEN PRINT "Just maybe...you have something&J"
2150 IF P6=4 THEN PRINT "Don't know if I like this....&J"
2160 IF P6=5 THEN PRINT "I don't think I really like this.&J"
2170 IF P6=6 THEN PRINT "Do you have *FIVE* aces ??&J"
2180 IF P6=7 THEN PRINT "Tis time I teach you a lesson!"
2190 IF P6=8 THEN PRINT "I can't believe I dealt myself this."
2200 IF P6=9 THEN PRINT "### YOUR BLUFFING !!! ###"
2210 IF P6=10 THEN PRINT "### YOU DARING DUMMY !!! ###&J"
2220 IF P6=11 THEN PRINT "### SMILE NOW ###&J(....when you lose)&J"
2230 IF P6=13 THEN PRINT "### STUPID BET! ###&J"
2235 IF P6=13 THEN PRINT "(Unless you have a flush)&J"
2240 IF P6=12 THEN PRINT "# IT'S YOUR MONEY! #&J"
2250 IF P6=14 THEN PRINT "# IT'S TOO LATE TO RECONSIDER #&J"
2260 IF P6=15 THEN PRINT "This could be interesting....&J"
2270 IF P6=16 THEN PRINT "This could be BAD....&J"
2280 IF P6=17 THEN PRINT "You better keep up with me..."
2285 IF P6=17 THEN PRINT "because I AM the JONES'ES!"
2290 IF P6=18 THEN PRINT "Looks like do or die..."
2300 P7=(B/10000)+RND(0): P6=INT(RND(0)*9)+1
2310 IF RND(0)>P7 THEN P5=0: V(2)=0: GOTO 2400
2320 IF P6=1 THEN PRINT "# ODDS ARE IN MY FAVOR #&J"
2330 IF P6=2 THEN PRINT "# YOU CAN'T POSSIBLY WIN! #&J"
2340 IF P6=3 THEN PRINT "# Say BYE to your money! #&J"
2350 IF P6=4 THEN PRINT "### I CALL YOUR BLUFF ###&J"
2360 IF P6=5 THEN PRINT "### COMPUTERS ALWAYS WIN! ###&J"
2370 IF P6=6 THEN PRINT "And to think you'd blow ";B;" to see ";
2380 IF P6=7 THEN PRINT "### FOOLS AND THEIR MONEY ARE PARTED ###"
2390 IF P6=8 THEN PRINT "### I HOPE YOUR CREDIT IS GOOD ###"
2395 IF P6=9 THEN PRINT "### WELL...HERE GOES ! ###&J"
2398 RETURN 
2400 IF P6=1 THEN PRINT "# I've really got JUNK for a hand #&J"
2410 IF P6=2 THEN PRINT "### JUST CAN'T RISK THIS ###&J"
2420 IF P6=3 THEN PRINT "### TOO RISKY FOR ME ###&J"
2430 IF P6=4 THEN PRINT "### 3 of a kind is a gamble for me ###&J"
2440 IF P6=5 THEN PRINT "### NO DICE ! ###&J"
2450 IF P6=6 THEN PRINT "I... I'll...";
2460 IF P6=7 THEN PRINT "Here are my cards...";
2470 IF P6=8 THEN PRINT "Perhaps....no,";
2480 IF P6=9 THEN PRINT "Such a deal I have for you..."
2490 PRINT " <###> I FOLD ! <###>&J"
2495 RETURN 
3000 END