10   REM SNARK.BS5
100  PRINT " *** SNARK ***&J CATCH HIM WITH A WELL PLACED CIRCLE&J"
110  PRINT " *** PEOPLE'S COMPUTER COMPANY, MENLO PARK  CA &J&J"
120  REM *** ADAPTED TO CDC BASIC BY KENT T. KEHRBERG
130  PRINT "WANT THE RULES ?"
140  INPUT "(1=YES  0=NO)---=>",A9
150  IF A9=1 THEN 190
160  IF A9=0 THEN 410
170  PRINT "YES OR NO, PLEASE";
180  GOTO 00140
190  REM *** HERE ARE THE RULES
200  PRINT 
210  PRINT "A SNARK IS HIDDING IN A 10 BY 10 GRID LIKE THE ONE SHOWN BELOW:"
220  PRINT 
230  PRINT " Y"
240  FOR Y=9 TO 0 STEP -1
250     PRINT Y;" . . . . . . . . . ."
260  NEXT Y
270  PRINT " X 0 1 2 3 4 5 6 7 8 9 ....TYPE IN A NUMBER ";
275  INPUT "---=>",A9
280  PRINT 
290  PRINT "TRY TO CATCH HIM.  HERE'S HOW ... WHEN I ASK, YOU TYPE"
300  PRINT "THE X,Y COORDINATES OF A GRIDPOINT (IF YOU DON'T KNOW"
310  PRINT "WHAT THAT MEANS, ASK SOMEONE) AND PRESS THE RETURN KEY."
320  PRINT "THEN, WHEN I ASK FOR 'RADIUS', YOU TYPE THE RADIUS"
330  PRINT "OF A CIRCLE CENTERED ON THE GRIDPOINT WHOSE X,Y"
340  PRINT "COORDINATES YOU JUST ENTERED.  I WILL THEN TELL YOU"
350  PRINT "WHETHER THE SNARK IS 'INSIDE' YOUR CIRCLE, 'OUTSIDE' "
360  PRINT "YOUR CIRCLE, OR 'ON' YOUR CIRCLE."
370  PRINT 
380  PRINT "***IMPORTANT***IF YOU THINK YOU KNOW WHERE HE IS"
390  PRINT "HIDING, ENTER 0 (ZERO) AS THE RADIUS. GOOD HUNTING."
400  REM *** HIDE THE SNARK
410  LET X=INT(10*RND(0))
420  LET Y=INT(10*RND(0))
430  PRINT 
440  PRINT "THE SNARK IS HIDING ... START GUESSING."
450  REM *** GUESSING BEGINS 
460  K=1
470  PRINT 
480  PRINT "COORDINATES";
490  INPUT A,B
500  IF A=INT(A) THEN 00520
510  GOTO 00530
520  IF B=INT(B) THEN 00550
530  PRINT "FORGOT TO TELL YOU - COORDINATES MUST BE INTEGERS."
540  GOTO 00470
550  LET D2=(X-A)*(X-A)+(Y-B)*(Y-B)
560  PRINT "RADIUS";
570  INPUT R
580  IF R=INT(R) THEN 00600
590  GOTO 00610
600  IF R>=0 THEN 00640
610  PRINT "WHOOPS.  THE RADIUS MUST BE A WHOLE NUMBER."
620  PRINT 
630  GOTO 00560
640  IF R<>0 THEN 00660
650  IF D2=0 THEN 00770
660  IF D2<R*R THEN 00690
670  IF D2>R*R THEN 00710
680  IF D2=R*R THEN 00730
690  PRINT "SNARK IS INSIDE YOUR CIRCLE."
700  GOTO 00740
710  PRINT "SNARK IS OUTSIDE YOUR CIRCLE."
720  GOTO 00740
730  PRINT "SNARK IS ON YOUR CIRCLE."
740  K=K+1
750  GOTO 00470
760  REM *** WE GOT A WINNER 
770  PRINT 
780  PRINT "YOU CAUGHT HIM IN ";K;" GUESSES."
790  PRINT "GOOD SHOW."
800  PRINT "WANT TO PLAY AGAIN ?"
810  INPUT "(1=YES  0=NO)---=>",A9
820  IF A9=1 THEN 410
830  IF A9=0 THEN 860
840  PRINT "YES OR NO,PLEASE";
850  GOTO 00810
860  END