10 REM ACEYD.ECB
  100 REM ...ACEY-DEUCEY - written 3/24/73 by ANDREA BARSH
  110 REM ...and  DUFF KURLAND (UHMC COMPUTER CENTER, NYU)  
  120 PRINT "&K": REM ...Revised 03-03-81  R.E.H.
  130 PRINT TAB(10);"***  A C E Y - D U E C E Y  ***&J&J"
  140 DIM C(13),C$(13),N$(10),Q(60)
  150 LET Q=0
  160 LET C$="A23456789TJQK"
  200 LET G=INT(RND(0)*3)+1
  210 PRINT " WHAT'S YOUR NAME ---=>";
  220 INPUT N$
  230 PRINT 
  240 IF LEN(N$)=0 THEN  LET N$="Player"
  250 LET I=LEN(I$)
  310 INPUT (1,0)" DO YOU NEED INSTRUCTIONS ---=>",I$
  320 LET I$=I$+"N"
  330 PRINT 
  340 IF I$(1,1)="N" THEN 480
  350 IF I$(1,1)="n" THEN 480
  360 PRINT "&K"
  370 PRINT "    You are dealt 2 cards, and you bet on"
  380 PRINT " the chances of drawing a THIRD card; the"
  390 PRINT " value of which is BETWEEN (but not EQUAL TO)"
  400 PRINT " the FIRST TWO CARDS.  If ONE of your first"
  410 PRINT " two cards is an ACE, then you must declare"
  420 PRINT " whether it is to be counted as 'LOW'"
  430 PRINT " (below a 2) or 'HIGH' (higher than a KING)."
  440 PRINT " GAME ENDS when POT is EXHAUSTED ..."
  450 PRINT TAB(10);"...... OR EITHER PLAYER IS BROKE."
  480 PRINT 
  490 PRINT " MIN. BET: 1% of STAKE, UNLESS you (or the pot)"
  500 PRINT " DON'T HAVE THAT MUCH."
  510 PRINT 
  520 PRINT " ANTE IS 20% - HOW MUCH BREAD DID YOU BRING"
  530 PRINT " WITH YOU TONIGHT ---=>";
  540 INPUT S
  550 LET S=INT(S)
  560 IF S>=5 THEN 590
  570 PRINT " GET OUTA HERE, PUNK.  IT'S PAST YER BEDTIME."
  580 GOTO 2340
  590 LET D=S
  600 LET U=INT(S/100)
  610 IF S>=10000 THEN 640
  620 PRINT " OKAY, I'LL MATCH THAT AMOUNT."
  630 GOTO 650
  640 PRINT " NO SWEAT, GOT YOU COVERED."
  650 LET P=INT(S/5)
  660 LET S=S-P
  670 LET M=S
  680 LET P=P*2
  690 FOR I=1 TO 13
  700   LET C(I)=4
  710 NEXT I
  720 LET L=52
  730 GOSUB 1990
  740 LET R1=R
  750 GOSUB 1990
  760 LET R2=R
  770 PRINT 
  780 PRINT " POT CONTAINS ";%$C12F2;P
  790 PRINT " You have ";%$C12F2;S;" and I have ";M
  800 PRINT " Your cards are: ";C$(R1,R1);" and ";C$(R2,R2)
  810 IF R1=R2 AND R1=1 THEN 1350
  820 IF R1>1 AND R2>1 THEN 880
  830 GOSUB 1380
  840 IF R2=1 THEN 870
  850 LET R1=R
  860 GOTO 880
  870 LET R2=R
  880 PRINT " Your bet ---=>";
  890 INPUT B: PRINT 
  900 LET B=INT(B)
  910 IF B<=S THEN 950
  920 PRINT " YOU DON'T HAVE THAT MUCH MONEY,......"
  930 PRINT " ....... AND I DON'T ACCEPT IOU'S."
  940 GOTO 880
  950 IF B>=U OR S<U OR P<U THEN 980
  960 PRINT " MINIMUM BET IS ";%$C5F2;U
  970 GOTO 880
  980 IF B>0 THEN 1010
  990 PRINT " COME ON, SPORT, AT LEAST A DOLLAR!"
 1000 GOTO 880
 1010 IF B<=P THEN 1040
 1020 PRINT " ONLY ";%$C9F2;P;" IN THE POT, DUMMY."
 1030 GOTO 880
 1040 GOSUB 1990
 1050 LET R3=R
 1060 PRINT " YOU DREW: ";C$(R3,R3);
 1070 IF R1<R3 AND R3<R2 THEN 1290
 1080 IF R2<R3 AND R3<R1 THEN 1290
 1090 LET P=P+B
 1100 LET S=S-B
 1110 PRINT "  - YOU LOSE, ";N$;"."
 1120 IF S>0 THEN 1480
 1130 PRINT " CLEANED YA OUT, HUH?"
 1140 PRINT 
 1150 IF S=M THEN 1230
 1160 IF S>M THEN 1200
 1170 LET M=M+P
 1180 PRINT " I WON ";%$C9F2;M-D;" AND YOU LOST ";D-S
 1190 GOTO 1240
 1200 LET S=S+P
 1210 PRINT " YOU WON ";%$C9F2;S-D;" AND I LOST ";D-M
 1220 GOTO 1240
 1230 PRINT " WE CAME OUT EVEN!"
 1240 PRINT 
 1250 PRINT " YA WANNA TRY AGAIN, ";N$;
 1260 INPUT (1,0)" ---=>",I$: LET I$=I$+"Y"
 1270 IF I$(1,1)="N" THEN 2330
 1280 IF I$(1,1)="n" THEN 2330 ELSE 510
 1290 LET S=S+B
 1300 LET P=P-B
 1310 PRINT "  - YOU WIN, KID!"
 1320 IF P>0 THEN 1480
 1330 PRINT " YOU WENT THE POT, TOO!"
 1340 GOTO 1140
 1350 PRINT " I ASSUME YOU WANT ONE OF THEM HIGH, AND ONE LOW."
 1360 LET R2=14
 1370 GOTO 880
 1380 PRINT " DO YOU WANT THAT ACE TO BE HIGH OR LOW ---=>";
 1390 INPUT (1,0)A$: LET A$=A$+"Y"
 1400 IF A$(1,1)<>"Y" THEN 1430
 1410 PRINT " IF WE WERE IN TEXAS, YOU'D BE SHOT FOR THAT."
 1420 GOTO 1380
 1430 LET R=1
 1440 IF A$(1,1)="L" THEN 1470
 1450 IF A$(1,1)="H" THEN 1460 ELSE 1380
 1460 LET R=14
 1470 RETURN 
 1480 PRINT 
 1490 GOSUB 1990
 1500 LET R1=R
 1510 GOSUB 1990
 1520 LET R2=R
 1530 LET Y$=" "
 1540 IF ABS(R2-R1)<2 AND R1>1 AND R2>1 THEN 1550 ELSE 1560
 1550 LET Y$=" (YECCH!) "
 1560 PRINT " My CARDS are: ";C$(R1,R1);" and ";C$(R2,R2);Y$
 1570 IF R1>R2 THEN  GOSUB 2290
 1580 IF R1=R2 AND R1=1 THEN 1930
 1590 IF R1=1 THEN  GOSUB 2150
 1600 LET W=0
 1610 FOR I=2 TO 13
 1620   IF I>R1 AND I<R2 THEN 1630 ELSE 1640
 1630   LET W=W+C(I)
 1640 NEXT I
 1650 LET W=W+C(I)
 1660 LET B=INT(P*(W/L))
 1670 IF B<=M THEN 1690
 1680 LET B=INT(M*(W/L))
 1690 IF B<>0 THEN 1710
 1700 LET B=1
 1710 IF B<U AND M>=U AND P>=U THEN 1720 ELSE 1730
 1720 LET B=U
 1730 PRINT " I BET ";%$C9F2;B
 1740 GOSUB 1990
 1750 LET R3=R
 1760 PRINT " I drew: ";C$(R3,R3);
 1770 IF R1<R3 AND R3<R2 THEN 1870
 1780 LET P=P+B
 1790 LET M=M-B
 1800 IF R3<8 THEN 1820
 1810 PRINT "  - OH, DRAT!"
 1820 IF R3>7 THEN 1840
 1830 PRINT " - I LOSE THAT ONE."
 1840 IF M>0 THEN 730
 1850 PRINT " I'M BROKE."
 1860 GOTO 1140
 1870 LET P=P-B
 1880 LET M=M+B
 1890 PRINT "  - AH! SUCCESS!"
 1900 IF P>0 THEN 730
 1910 PRINT " I CLEANED OUT THE POT. BEAT THAT, KID."
 1920 GOTO 1140
 1930 PRINT " I'LL CALL ONE HIGH AND ONE LOW."
 1940 LET R2=14
 1950 LET B=M
 1960 IF P>M THEN 1730
 1970 LET B=P
 1980 GOTO 1730
 1990 IF L<=1 THEN 2070
 2000 FOR I=1 TO G
 2010   LET R=INT(RND(0)*13)+1
 2020 NEXT I
 2030 IF C(R)=0 THEN 2000
 2040 LET C(R)=C(R)-1
 2050 LET L=L-1
 2060 RETURN 
 2070 PRINT 
 2080 PRINT " RESHUFFLING THE CARDS."
 2090 PRINT 
 2100 FOR I=1 TO 13
 2110   LET C(I)=4
 2120 NEXT I
 2130 LET L=52
 2140 GOTO 2000
 2150 LET V=0
 2160 LET W=0
 2170 FOR I=2 TO 13
 2180   IF I>=R2 THEN 2190
 2190   IF I<=R2 THEN 2210
 2200   LET W=W+C(I)
 2210 NEXT I
 2220 LET V=V+C(I)
 2230 IF V<=W THEN 2250
 2240 LET R1=14
 2250 PRINT " I'LL CALL THAT ACE ";
 2260 IF R1=1 THEN  PRINT " LOW." ELSE  PRINT " HIGH."
 2270 IF R1>R2 THEN  LET R1=R2
 2280 RETURN 
 2290 LET R9=R1
 2300 LET R1=R2
 2310 LET R2=R9
 2320 RETURN 
 2330 PRINT " WELL, IT'S BEEN REAL.  SEE YA AROUND, ";N$;"."
 2340 END