10 REM ANTIA.ECB
  100 REM ...by EAGAN site MTC Enginner Ralph Hopkins  6-20-75
  110 REM =======  Last corrected  02-22-81       R.E.H.
  120 LET Z=RND(0): PRINT "&K&J"
  130 DIM A(7),B(6),C(6),D(6),E(7),G(2),K(6),S(6)
  140 DIM C$(20),D$(38)
  150 LET P(1)=0: LET P(2)=0: LET P(3)=0: LET P=1: LET B$=CHR(7)
  160 LET C$="SOL Computor"
  170 LET D$="**************************************"
  180 PRINT ,D$
  190 PRINT ,"**";TAB(50);"**"
  200 PRINT ,"**         ANTI-AIRCRAFT GAME       **"
  210 PRINT ,"**";TAB(50);"**"
  220 PRINT ,D$;"&J&J"
  240 DATA 17000,1,4,2,2,110,130,1,13,130,200
  250 DATA 1.2,20,180,75,1.4,7.5,250,80,1.4,8
  260 DATA 140,120,1,6,12,150,100,1.8,10
  270 READ G(2),B(1),B(2),B(3),B(4)
  280 FOR X=1 TO 6
  290   READ C(X)
  300   READ D(X)
  310   READ K(X)
  320   READ V(X)
  330 NEXT X
  340 PRINT "   You are in COMMAND of a U.S. Army M-42"
  350 PRINT " ANTIAIRCRAFT TANK.    YOUR MISSION.....Should you"
  360 PRINT " decide to accept.............."
  370 PRINT
  380 PRINT "----Type in a  'S' to skip instructions---> ";
  390 INPUT (1,0)I$: LET I$=I$+"S"
  400 PRINT
  410 IF I$(1,1)="S" THEN 540
  420 PRINT ".........WILL BE TO SHOOT DOWN THE ENEMY AIRCRAFT"
  430 PRINT " SIGHTED APPROACHING YOU NOW."
  440 PRINT "        EVERY TIME YOU SHOOT...IS ONE TURN."
  450 PRINT
  460 PRINT " THE MISSION OF THE ENEMY PLANE IS TO BOMB YOU !"
  470 PRINT TAB(5);"SHOULD HE SUCCEED........."
  480 PRINT TAB(9);"YOU AND THIS COMPLEX WILL  ***BLOW UP !!!***"
  500 PRINT "&J----TYPE IN A  'R'  WHEN READY----";
  510 INPUT (1,0)I$
  530 PRINT " EXIT THE GAME by trying to fire -1 shells&J"
  540 PRINT
  550 PRINT "Your M-42 TANK has TWIN 40mm guns with a"
  560 PRINT " MAXIMUM RANGE and ALTITUDE of ";
  570 LET G(1)=INT(RND(0)*20+500): LET G(2)=17000
  580 PRINT %C;G(2);" feet."
  590 PRINT ,"The maximum firing rate is ";%C;G(1)
  600 LET N=INT(RND(0)*6+9)*500
  605 LET M=7: GOSUB 3000
  610 PRINT %C;N;" rounds of ammunition.&J"
  650 LET E=INT(RND(0)*6+1)
  660 LET A(1)=INT(RND(0)*140+3)*100
  670 LET A(2)=INT(RND(0)*90+1)*100
  680 LET A(3)=INT(RND(0)*190+6)*10
  690 LET A(4)=INT(RND(0)*90+10)*100
  700 LET A(5)=INT(RND(0)*175+5)*100
  710 LET A(6)=INT(RND(0)*120+40)*100
  720 LET I=0: LET T=0
  730 LET B(5)=INT(RND(0)*6+6)
  740 LET B(6)=INT(RND(0)*10+10)
  820 LET S(1)=INT(RND(0)*30+200)
  830 LET S(2)=INT(RND(0)*30+260)
  840 LET S(3)=INT(RND(0)*20+325)
  850 LET S(4)=INT(RND(0)*25+625)
  860 LET S(5)=INT(RND(0)*43+250)
  870 LET S(6)=INT(RND(0)*25+225)
  900 PRINT "&J----TYPE any letter when ready ---=>";
  910 INPUT (1,0)I$
  990 LET R=17000+S(E)*2
 1000 REM === SET UP COMPLETE: GUN LIM., ENEMY CHOSEN,
 1010 REM === PLANE ATTACK ALT., BOMB LDS, DEFENSE FACTORS
 1020 REM === PLANE INFO,   HIT CONSTANTS, MAX + MIN SPEEDS
 1030 REM === RANDOM MESSAGES, AND AMMO AVAILABLE
 1040 PRINT "&K&J";TAB(15);"ANTI-AIRCRAFT GAME NUMBER ";P
 1050 LET R=R-S(E)*5
 1060 IF R<10000 THEN 1100
 1070 PRINT "   Your RADAR linked ";C$;
 1080 PRINT " reports an ENEMY PLANE"
 1090 GOTO 1110
 1100 PRINT "Your ";C$;" has identified a ";: GOSUB 3200
 1110 PRINT "   approaching at an altitude of ";%C;A(E);" feet."
 1120 PRINT %C;R;" is his range in feet.  His air-speed is ";S(E)
 1130 PRINT
 1140 IF RND(0)>.0574 THEN 1690
 1150 GOTO 1160
 1160 LET F=INT(RND(0)*13+1)
 1170 PRINT : PRINT : PRINT
 1180 IF F>7 THEN 1200
 1190 ON F GOTO 1210,1240,1260,1280,1320,1360,1390
 1200 ON F-7 GOTO 1430,1460,1480,1520,1550
 1210 PRINT "A BIRD JUST SHITTED ON YOUR GUNS AND YOUR ";
 1215 LET M=9: GOSUB 3000
 1220 PRINT "WHILE YOU CLEAN IT OFF!"
 1230 GOTO 1650
 1240 PRINT M$(7);" TO VISIT THE JOHN AND FLUSH DOWN ";
 1245 LET M=9: GOSUB 3000
 1250 GOTO 1620
 1260 PRINT "YOU LIGHT UP FOR A SMOKE BREAK AND BURN UP ";
 1270 LET M=9: GOSUB 3000: GOTO 1620
 1280 PRINT "You have SUPER GOOD CAMOFLAGE and some"
 1290 PRINT "NUTTY GARDNER ASSHOLE JUST WATTERED YOU'ALL"
 1300 PRINT "      YOUR HOSED OUT OF YOUR ";
 1310 LET M=9: GOSUB 3000: GOTO 1650
 1320 PRINT "THE WIND JUST BLEW A TWIG DOWN YOUR GUNBARREL WITH"
 1330 PRINT "LEAVES, NEST, EGGS AND A SURPRISED BIRD."
 1340 PRINT " YANK IT OUT AND GET YANKED OFF FOR";
 1350 LET M=9: GOSUB 3000: GOTO 1650
 1360 PRINT "You have a SURPRISE INSPECTION by your C.O."
 1370 PRINT "NOW ARE'NT  YOU SURPRISED OUT OF";M$(10)
 1380 GOTO 1640
 1390 PRINT "YOU SAW A RAT .........."
 1400 PRINT "....AND SHOT THE LITTLE HAIRY BASTARD PLUS"
 1410 LET M=9: GOSUB 3000: GOTO 1650
 1430 PRINT "A LITTLE PICKPOCKET JUST RIPPED YOU OFF"
 1440 PRINT "FOR YOUR MONEY, CREDIT CARDS AND ";
 1450 LET M=9: GOSUB 3000: GOTO 1650
 1460 PRINT "BREAK TIME!!  WHICH ALSO BREAKS YOU UP FOR  ";
 1470 LET M=9: GOSUB 3000: GOTO 1620
 1480 PRINT "A KID HIT YOU IN THE ROCKS WITH HIS SLINGSHOT."
 1490 PRINT "..SO WHILE THE MEDIC  PUTS IT IN A SLING,..."
 1500 PRINT "...YOU ARE HURTING FOR THIS";
 1510 LET M=9: GOSUB 3000: GOTO 1650
 1520 PRINT "YOU FELL ASLEEP AND DREAMED YOU DID'NT LOSE THESE"
 1530 LET M=10: GOSUB 3000: GOTO 1640
 1550 PRINT "You have a QUICK BEER and SUCK UP YOUR ";
 1560 LET M=9: GOSUB 3000: GOTO 1620
 1570 PRINT "    HI  ZIGGY !!!  ";
 1575 LET M=11: GOSUB 3000
 1580 PRINT "JUST CUZ U ARE SO VERY LUCKY TODAY, You have LOST"
 1590 PRINT "***   THREE MOTHER CHUNKIN TURNS !!!  ***"
 1600 LET R=R-S(5)*10
 1610 GOTO 1660
 1620 PRINT : PRINT
 1630 GOTO 1660
 1640 LET R=R-S(E)*5
 1650 PRINT
 1660 PRINT "ENTER  # of shells to fire at the ENEMY PLANE ";
 1670 INPUT (3,0)I
 1680 GOTO 1040
 1690 IF N<=0 OR G(1)<=0 THEN 2200
 1700 IF I<=0 THEN 2620
 1710 LET O=(A(E)+R*4)/400
 1720 IF RND(0)<.93 THEN 1740
 1730 LET O=O*5
 1740 LET H=0
 1750 LET Q=I
 1760 IF I<=G(1) THEN 1780
 1770 LET I=G(1)
 1780 IF I<N THEN 1800
 1790 LET I=N
 1800 LET L=K(E)/O
 1810 FOR Y=1 TO I
 1820   IF RND(0)<L THEN  LET H=H+1
 1830 NEXT Y
 1840 LET T=T+H
 1850 LET N=N-I
 1860 LET D(E)=D(E)-H
 1870 PRINT " Your ";C$;" reports ";H;" HITS out of ";I
 1880 PRINT "You have ";N;" shells left to shoot with."
 1890 PRINT : PRINT
 1900 IF B(E)<=0 OR D(E)>=V(E) THEN 1960
 1910 LET Z=INT(RND(0)*B(E)+1)
 1920 LET B(E)=B(E)-Z
 1930 PRINT TAB(10);"### FORCED PREMATURE BOMB DROP ###"
 1940 PRINT TAB(20);"HE LOST ";Z
 1950 GOTO 1970
 1960 PRINT
 1970 LET J=2*(G(1)+Q)/100000
 1980 IF RND(0)>J THEN 2030
 1990 LET G(1)=G(1)/2
 2000 PRINT TAB(10);"***  GUN JAM  ***"
 2010 PRINT TAB(6);"YOUR MAX FIRING RATE IS NOW ";G(1)
 2020 GOTO 2040
 2030 PRINT
 2040 IF D(E)>=V(E)*6 THEN 2060
 2050 LET A(E)=A(E)-S(E)
 2060 IF D(E)>=V(E)*5 THEN 2080
 2070 LET A(E)=A(E)-S(E)
 2080 IF D(E)>=V(E)*4 THEN 2100
 2090 LET S(E)=S(E)-35
 2100 IF D(E)>=V(E)*3 THEN 2120
 2110 LET A(E)=A(E)-S(E)
 2120 IF D(E)>=V(E)*2 THEN 2140
 2130 LET S(E)=S(E)-35
 2140 LET W=0: LET X=0
 2150 IF D(E)>0 OR A(E)>=100 OR C(E)<=S(E) THEN 2170
 2160 LET W=1
 2170 IF W=1 THEN 2290
 2180 IF B(E)>0 THEN 2200
 2190 LET W=2
 2200 IF R>S(E) THEN 2610
 2210 IF W=2 THEN 2290
 2220 FOR Y=1 TO B(E)
 2230   IF RND(0)<.28 THEN  LET X=X+1
 2240 NEXT Y
 2250 IF X<>0 THEN 2270
 2260 LET W=2
 2270 IF X<=0 THEN 2290
 2280 LET W=3
 2290 PRINT "GAME OVER!  TYPE IN -C-   FOR THE RESULTS. ";
 2300 INPUT (1,0)I$
 2310 PRINT
 2320 PRINT ,D$
 2330 PRINT ,"**";TAB(50);"**"
 2340 ON W GOTO 2350,2380,2410
 2350 PRINT ,"**     OH WOW!!!   FAR OUT MAN!!!   **"
 2360 PRINT ,"**        YOU REALLY WON !!!!!!!!   **"
 2370 GOTO 2430
 2380 PRINT ,"**       YOUR BOTH IMPOTENT !!      **"
 2390 PRINT ,"**       IT S  A  DRAW ! ! ! !      **"
 2400 GOTO 2430
 2410 PRINT ,"**            HI  ZIGGY  !          **"
 2420 PRINT ,"**            YOU LOSE  !  !        **"
 2430 PRINT ,"**";TAB(50);"**"
 2440 PRINT ,D$
 2450 PRINT
 2460 PRINT ,"You have ";T;" HITS on the ENEMY PLANE. "
 2470 PRINT
 2480 IF W<>1 THEN 2510
 2490 PRINT ,M$(E)
 2500 GOTO 2520
 2510 PRINT ,X;" BOMBS LANDED ON YOU OUT OF ";B(E)
 2520 PRINT "  PLAY AGAIN ???  ---=>";
 2530 INPUT (1,0)I$: LET I$=I$+"Y"
 2540 LET P(W)=P(W)+1
 2550 LET P=P+1
 2560 IF I$(1,1)="Y" THEN 540
 2565 IF I$(1,1)="y" THEN 540
 2570 PRINT "YOU PLAYED  ";P-1;" GAMES - TOTAL."
 2580 PRINT "YOUR WIN, TIE, LOSS SCORE IS ";P(1),P(2),P(3)
 2590 PRINT "YOUALL COME BACK NOW!"
 2600 GOTO 5000
 2610 IF N<=0 OR G(1)<=0 THEN 1040
 2620 PRINT "ENTER number of shells to fire  OR  '0' to pass.";
 2630 IF N<=0 THEN 1040
 2640 INPUT (3,0)I
 2650 IF R<0 THEN 2140
 2660 IF I<0 THEN 2570
 2670 GOTO 1040
 2680 REM .A(1-6)=RANDOM ATTACK ALTITUDE EACH PLANE
 2690 REM .B(1-6)= #  OF BOMBS CARRIED BY EACH TYPE OF PLANE
 2700 REM .C=CRASH OR MINIMUM SPEED OF EACH TYPE OF PLANE
 2710 REM .D(1-6)=DEFENSE STRENGHT LEFT ON PLANE (AFTER HITS)
 2720 REM .E=WHICH OF 6 ENEMY PLANES  PICKED  FOR THIS GAME
 2730 REM .F=PICK 1-13 RAND. MISFORTUNES 2 HAPPEN ANYTIME
 2740 REM .G(1+2)=GUN"S MAX FIRING RATE  &  GUN MAX RANG
 2750 REM .H=NUMBER OF HITS MADE OF PLANE ATTACKING
 2760 REM .I=NUMBER OF SHELLS (INPUTED) TO FIRE AT PLANE
 2770 REM .J=ODDS OF A GUN JAM
 2780 REM .K(1-6)=ODDS OF HITTING   CONSTANT
 2790 REM .L
 2800 REM .M=ONE OF 17 LOSER INSULT MESSAGES
 2810 REM .N= # OF SHELLS -TOTAL- THAT YOU HAVE TO SHOOT WITH
 2820 REM .O=ODDS OF A ONE-SHELL HIT ON THE PLANE
 2830 REM .P=GAMES-PLAYED  COUNTER
 2840 REM .Q=ORIGINAL 'I' INPUTED ( #  OF SHELLS TO FIRE)
 2850 REM .R=PRESENT RANGE OF THE ATTACKING AIRCRAFT
 2860 REM .S(1-12)=MAX/MIN SPEED LIM. OF EACH  PLANE
 2870 REM .T = TOTAL HITS ON THE ENEMY PLANE
 2880 REM .U
 2890 REM .V=PLANE"S ORIGINAL DEFENSIVE VALUE
 2900 REM .W(1-3)=WIN, DRAW, LOSE INDICATORS
 2910 REM .X=NUMBER OF BOMBS THAT HIT YOU !!!
 2920 REM .Y=1 FOR COUNTING SHELL HITS ON PLANE
 2930 REM .Z=  #  OF BOMBS U PREMATURLY FORCED PLANE TO LOSE
 2940 REM .B$=Computor name
 2950 REM .I$="B"  TO GO BACK TO RE-READ INSTRUCTIONS
 2980 REM .I$=For inputs
 3000 REM ...Messages
 3010 IF M=1 THEN  PRINT "You stuck it to the STUKA!!!"
 3020 IF M=2 THEN  PRINT "You got that RUSSIAN IL-2 BASTARD!!!"
 3030 IF M=4 THEN  PRINT "That shoots the HELL out of that MIG"
 3040 IF M=5 THEN  PRINT "That JUNKER JU 88A is now JUNK!!"
 3050 IF M=6 THEN  PRINT "That HE 111H is a FLAMING BALL of SHIT !!!"
 3080 IF M=9 THEN  PRINT "   *** ONE TURN *** "
 3090 IF M=10 THEN  PRINT " ### TWO GODDAM TURNS !!! ### "
 3100 IF M=11 THEN  PRINT " SUCH A DEAL WE HAVE FOR YOU! "
 3190 RETURN
 3200 REM ...Enemy aircraft names
 3210 IF E=1 THEN  PRINT "GERMAN JU 87B STUKA DIVE BOMBER"
 3220 IF E=2 THEN  PRINT "RUSSIAN IL-2 ONE-PROP HEAVY-ARMOUR BOMBER"
 3230 IF E=3 THEN  PRINT "JAP ZERO FIGHTER WITH 2 550 LB. BOMBS"
 3240 IF E=4 THEN  PRINT "RUSSIAN MIG-15 JET WITH 2 1000 LB. BOMBS"
 3250 IF E=5 THEN  PRINT "GERMAN JU 88A TWIN-ENGINE FIGHTER-BOMBER"
 3260 IF E=6 THEN  PRINT "GERMAN HE 111H TWIN-ENGINE BOMBER"
 3290 RETURN
 5000 END