10 REM CBOOK.ECB
   20 REM ..CHECK-BOOK  Source EAGAN                   R.E.H.
   30 PRINT "&K&J&J"
   40 DIM A$(600),C$(1),F$(6),I$(1),Z$(6)
   60 PRINT ,"#  C H E C K - B O O K  #&J&J&J"
   70 FOR X=1 TO 100: LET A$=A$+"      ": NEXT X
   80 PRINT TAB(9);"THIS IS A CHECK-BOOK BALANCING PROGRAM"
   90 FOR X=1 TO 4: PRINT : NEXT X
  100 PRINT "DO YOU NEED INSTRUCTIONS ---=>";
  110 INPUT (1,0)I$: LET I$=I$+"N"
  120 IF I$(1,1)="N" THEN 190
  125 IF I$(1,1)="n" THEN 190 ELSE  PRINT "&K&J"
  130 PRINT "THIS IS A CHECK-BOOK BALANCING PROGRAM.&J"
  140 PRINT "You can enter up to 100 checks or deposits."
  150 PRINT "The entries are in two parts:  A check number"
  160 PRINT "(up to 6 digits) or 'DEP' for deposit"
  170 PRINT "AND the amount of the transaction.&J"
  175 PRINT ,"EXAMPLE of the inputs:&J"
  180 PRINT ": 1st enter transaction type ---=>?"
  185 PRINT ": 2nd enter the check amount ---=>?"
  190 PRINT
  192 PRINT ,"<*> We are ready to begin <*>"
  200 INPUT "ENTER CURRENT BALANCE ---=>",B(1)
  210 LET B(2)=B(1): LET G=1: PRINT
  212 PRINT "Automatic check numbering is provided if you"
  213 PRINT "enter a starting check number other than 0"
  214 PRINT "<*> NOTE: You can enter a check 6 letter name."
  215 PRINT "Enter 'SC' for service charge for 1st entries.&J"
  216 INPUT "ENTER starting check number ---=>",N0
  217 IF N0=0 THEN  LET A0=0 ELSE  LET A0=N0
  220 PRINT "&JHOW MANY ENTRIES WILL YOU MAKE";
  230 INPUT (2,0)" ---=>",X
  235 PRINT
  240 FOR I=G TO X
  245   IF N0=0 THEN  PRINT %3I;I; ELSE  PRINT %4I;A0;
  250   INPUT (6,0)": 1st enter transaction type ---=>",Z$
  252   IF LEN(Z$)=0 THEN  LET Z$="Check#"
  255   LET Z$=Z$+"      ": LET I0=6*I
  257   IF Z$(1,3)="DEP" THEN  LET A0=A0+0 ELSE  LET A0=A0+1
  260   PRINT "      2nd enter ";
  262   IF Z$(1,3)="DEP" THEN  PRINT "deposit "; ELSE  PRINT "the check";
  263   INPUT " amount ---=>",A(I)
  265   LET A$(I0-5,I0)=Z$(1,6): PRINT
  270   IF A$(I0-5,I0-3)<>"END" THEN 310
  280   LET Y=I-1
  290   LET I=X
  300   GOTO 340
  310   IF A$(I0-5,I0-3)="DEP" THEN 330
  320   LET A(I)=-1*ABS(A(I))
  330   LET Y=I
  340 NEXT I
  350 PRINT "&K": LET A0=N0
  360 FOR I=1 TO Y
  370   LET B(2)=B(2)+A(I),I0=I*6
  380   REM PRINT IN IMAGE"%%  ": I;
  385   PRINT %2I;I;": ";
  390   IF A$(I0-5,I0-3)="DEP" THEN 420
  400   REM PRINT IN IMAGE"%%%%%% $%%%%.%%": A$(I),A(I)
  405   PRINT A$(I0-5,I0);
  406   IF N0>0 THEN  PRINT %4I;A0;: LET A0=A0+1
  407   PRINT " $";%9F2;A(I)
  408   IF A$(I0-5,I0-4)="SC" THEN  LET A0=A0-1: REM ..Sevice charge
  410   GOTO 430
  420   REM PRINT IN IMAGE"%%%%%%            $%%%%.%%": A$(I),A(I)
  425   PRINT A$(I0-5,I0);TAB(25);"$";%9F2;A(I)
  430 NEXT I
  440 PRINT
  450 REM PRINT IN IMAGE"   BALANCE                          $%%%%.%%":B(2)
  455 PRINT "   BALANCE";TAB(40);"$";%C10F2;B(2)
  460 PRINT
  470 PRINT
  480 PRINT "A - Add entry   C - Continue    E - End program"
  490 PRINT "D - Delete entry  R - Replace entry   S - Start over"
  500 INPUT (1,0)"L - List checks ---=>",C$: LET C$=C$+"C"
  510 IF C$(1,1)="E" THEN 930
  520 IF C$(1,1)="C" THEN 640
  530 IF C$(1,1)="S" THEN 190
  540 IF C$(1,1)="D" THEN 830
  550 IF C$(1,1)="A" THEN 660
  555 IF C$(1,1)="L" THEN 350
  560 PRINT "WHICH ENTRY DO YOU WISH TO CHANGE";
  570 INPUT (2,0)C: LET C0=C*6
  580 INPUT (6,0)"Enter transaction type ---=>",Z$
  585 INPUT "Now enter the amount   ---=>",A(C)
  590 LET Z$=Z$+"      "
  595 LET A$(C0-5,C0)=Z$(1,6)
  600 LET B(2)=B(1)
  610 IF A$(C0-5,C0-2)="DEP" THEN 360
  620 LET A(C)=-1*ABS(A(C))
  630 GOTO 360
  640 LET B(1)=B(2)
  642 PRINT "HOW MANY ENTRIES WILL YOU MAKE";
  644 INPUT Z
  646 LET X=X+Z
  648 LET G=Y+1
  650 GOTO 240
  660 PRINT "WHERE DO YOU WANT TO ADD";
  670 INPUT E
  680 IF E<1 THEN 480
  690 IF E>Y THEN  LET E=Y+1
  700 PRINT "ENTER TYPE/NO. AND AMOUNT";
  710 INPUT " ---=>",F$,F(1): LET F$=F$+"      "
  720 IF F$(1,3)="DEP" THEN 740
  730 LET F(1)=-1*ABS(F(1))
  740 FOR I=Y+1 TO E STEP -1
  750   LET I0=I*6,I1=(I-1)*6,A$(I0-5,I0)=A$(I1-5,I1)
  760   LET A(I)=A(I-1)
  770 NEXT I
  780 LET A$(E*6-5,E*6)=F$(1,6)
  790 LET A(E)=F(1)
  800 LET B(2)=B(1)
  810 LET Y=Y+1
  820 GOTO 350
  830 PRINT "WHICH LINE DO YOU WISH TO DELETE";
  840 INPUT (2,0)" ---=>",E
  850 IF E<0 OR E>Y THEN 480
  860 FOR I=E TO Y
  870   LET I0=I*6,I1=(I-1)*6,A$(I0-5,I0)=A$(I1-5,I1)
  880   LET A(I)=A(I+1)
  890 NEXT I
  900 LET B(2)=B(1)
  910 LET Y=Y-1
  920 GOTO 350
  930 END