10 REM CRAPS.ECB adapted for SOL-20
  100 REM ... 4 CRAP/DICE GAMES (COMBINED)    RALPH HOPKINS  01-15-79
  110 REM ......        ' LAST CHANGE  01-02-79
  120 DIM X(3,3),Y(3,3),M$(50)
  130 DATA "Y","YES","N","NO"," /-------\"," \-------/"
  140 DATA "**** TYPE IN ANY LETTER TO SEE MORE **** ---=>"
  150 PRINT "&K"
  160 READ Y$,Y1$,Y2$,Y3$,T1$,T2$,M$
  170 FOR X=1 TO 3: PRINT : NEXT X
  180 PRINT TAB(15);"***********************"
  190 PRINT TAB(14);"*** CRAP & DICE GAMES ***"
  200 PRINT TAB(15);"***********************"
  210 PRINT
  220 PRINT " 1 ...  CRAPS            (ORIGINAL NAME)"
  230 PRINT " 2 ...  CRAPS2           (   '       ' )"
  240 PRINT " 3 ...  DICE             (   '       ' )"
  250 PRINT " 4 ...  D-CRAPS          (DARTMOUTH-CRAPS)"
  260 PRINT
  270 PRINT
  280 PRINT "*** PICK A GAME  (1-4)  ---=>";
  290 INPUT (1,200)X
  300 PRINT
  310 LET X=INT(X)
  320 IF X<1 OR X>4 THEN 170 ELSE  PRINT
  330 ON X GOTO 1000,3000,5000,7000
  340 REM
  350 REM
 1000 PRINT "&K": REM ==== LAST MOD.    8/30/81   R.E.H.
 1010 PRINT
 1020 PRINT TAB(10);"$ $ $   C R A P S  $ $ $"
 1030 PRINT
 1035 PRINT "    You lose CRAPS on the 1st throw by throwing a"
 1036 PRINT "2, 3, or 12.   You win by throwing a 7 or 11."
 1037 PRINT "Any other number thrown on the 1st throw is your POINT."
 1038 PRINT "If your throw your point on any following throw, you"
 1039 PRINT "win.  But if you throw a 7 or 11, then you lose."
 1040 PRINT "&J    After ENTERING your name, HIT the"
 1050 PRINT " black (RETURN) key to roll the DICE."
 1080 PRINT
 1090 PRINT TAB(10);"*****GOOD LUCK******"
 1100 PRINT
 1110 PRINT "WHAT IS YOUR NAME PLEASE ?";
 1120 INPUT Q$
 1130 PRINT
 1140 PRINT
 1150 PRINT "WELL ";Q$;" HOW MUCH WILL YOU WAGER,IN DOLLARS?"
 1160 INPUT "---=>",W
 1170 LET D=0
 1180 PRINT : REM ......S T A R T.......
 1190 LET A=INT(10*RND(0))
 1200 IF A<1 OR A>6 THEN 1190
 1210 LET B=INT(10*RND(0))
 1220 IF B<1 OR B>6 THEN 1210
 1230 FOR X=1 TO 3
 1235   FOR Y=1 TO 3: LET X(X,Y)=0: LET Y(X,Y)=0: NEXT Y
 1240 NEXT X
 1250 IF A<>1 THEN 1270
 1260 LET X(2,2)=1
 1270 IF A<>2 THEN 1290
 1280 LET X(1,1)=2: LET X(3,3)=2
 1290 IF A<>3 THEN 1310
 1300 LET X(1,1)=3: LET X(3,3)=3: LET X(2,2)=3
 1310 IF A<>4 THEN 1330
 1320 LET X(1,1)=4,X(3,3)=4,X(3,1)=4,X(1,3)=4
 1330 IF A<>5 THEN 1350
 1340 LET X(1,1)=5,X(3,3)=5,X(3,1)=5,X(1,3)=5,X(2,2)=5
 1350 IF A<>6 THEN 1370
 1360 LET X(1,1)=6: LET X(3,3)=6: LET X(3,1)=6
 1365 LET X(1,3)=6: LET X(2,1)=6: LET X(2,3)=6
 1370 IF B<>1 THEN 1390
 1380 LET Y(2,2)=1
 1390 IF B<>2 THEN 1410
 1400 LET Y(1,1)=2: LET Y(3,3)=2
 1410 IF B<>3 THEN 1430
 1420 LET Y(1,1)=3: LET Y(3,3)=3: LET Y(2,2)=3
 1430 IF B<>4 THEN 1450
 1440 LET Y(1,1)=4: LET Y(3,3)=4: LET Y(3,1)=4: LET Y(1,3)=4
 1450 IF B<>5 THEN 1470
 1460 LET Y(1,1)=5: LET Y(3,3)=5: LET Y(3,1)=5
 1465 LET Y(1,3)=5: LET Y(2,2)=5
 1470 IF B<>6 THEN 1487
 1480 LET Y(1,1)=6: LET Y(3,3)=6: LET Y(3,1)=6
 1485 LET Y(1,3)=6: LET Y(2,1)=6: LET Y(2,3)=6
 1487 PRINT : PRINT T1$
 1490 FOR Z=1 TO 3
 1491   PRINT " : ";
 1492   FOR Z1=1 TO 3
 1494     IF X(Z,Z1)=0 THEN  PRINT "  "; ELSE  PRINT "* ";
 1495   NEXT Z1
 1496   PRINT ":"
 1497 NEXT Z
 1498 PRINT T2$
 1500 PRINT "            [";A+B;" ]   is your total."
 1505 PRINT T1$
 1510 FOR Z=1 TO 3
 1511   PRINT " : ";
 1512   FOR Z1=1 TO 3
 1513     IF Y(Z,Z1)=0 THEN  PRINT "  "; ELSE  PRINT "* ";
 1514   NEXT Z1
 1515   PRINT ":"
 1516 NEXT Z
 1517 PRINT T2$
 1520 LET D=D+1
 1530 LET C=A+B
 1540 IF D<>1 THEN 1560
 1550 LET H=C
 1560 IF C=7 AND D>1 THEN 1640
 1570 IF C=7 AND D=1 OR C=11 AND D=1 THEN 1710
 1580 IF C=2 AND D=1 OR C=3 AND D=1 OR C=12 AND D=1 THEN 1640
 1590 IF H=C AND D>1 THEN 1790
 1600 PRINT H;" IS YOUR POINT...YOU ROLLED A ";C
 1610 PRINT " ........Try again ";Q$;
 1615 PRINT TAB(35);"Hit the (RETURN) key ";
 1620 INPUT (1,0)"---=>",L$
 1630 IF L$<>"/" THEN 1180
 1640 PRINT TAB(10);" **** CRAPPED OUT!!!! ****"
 1650 LET T=T-W
 1670 PRINT " WANT TO TRY AGAIN? ";Q$;" (Y or N) ---=>";
 1680 INPUT (1,0)C$
 1690 IF C$=Y$ THEN 1150
 1700 IF C$=Y2$ THEN 1830
 1710 PRINT C;" LUCKY THROW !"
 1720 PRINT
 1730 PRINT " ... WANT TO TRY AGAIN  ";Q$;"? (Y OR N)"
 1740 LET T=T+W
 1750 GOSUB 1810
 1760 INPUT (1,0)"---=>",D$
 1770 IF D$=Y$ THEN 1150
 1780 IF D$=Y2$ THEN 1830 ELSE 8000
 1790 PRINT "    YOU MADE YOUR POINT !!!!"
 1800 GOTO 1710
 1810 PRINT "Balance is now ";T;" dollars ";
 1820 RETURN
 1830 PRINT
 1840 PRINT TAB(10);"YOU LEAVE WITH $ ";T;" DOLLARS."
 1850 PRINT
 1860 PRINT TAB(13);"COME BACK SOON...."
 1870 PRINT
 1880 IF T<-500 THEN 1890 ELSE 1900
 1890 PRINT TAB(15);"** YOU BIG **"
 1900 IF T>0 THEN 1920
 1910 PRINT TAB(10);"****** S U C K E R ******"
 1920 GOTO 8000
 1930 REM
 3000 REM ======== LAST MODIFIED  8/30/81   R.E.H.
 3010 PRINT "&K"
 3020 PRINT "        C *** R *** A *** P *** S      "
 3030 PRINT
 3040 PRINT " The object is to WIN the as much MONEY as you can."
 3050 PRINT " RULES ARE TAKEN FROM THE BOOK OF HOYLE"
 3060 PRINT
 3070 PRINT "   YOU ARE NOW ENTERING THE CASINO UNIVAC 1110"
 3080 PRINT " LOCATED IN DOWNTOWN LAS VEGAS. "
 3090 PRINT "     YOUVE JUST WON $25000 FROM THE READERS"
 3100 PRINT " DIGEST SWEEPSTAKES."
 3110 PRINT
 3120 PRINT M$;
 3130 INPUT (1,0)I$
 3140 PRINT
 3150 PRINT "      YOU ARE FEELING FREE AND EASY AND..."
 3160 PRINT " YOU'RE KEEN EYES LOCATE A CRAP TABLE !!"
 3170 PRINT " THE GREEN FELT LOOKS VERY INVITING....."
 3180 PRINT
 3190 PRINT "   YOU SEE A GIRL IN A PLAYBOY BUNNY OUTFIT,"
 3200 PRINT " AND........,"
 3210 PRINT "  SHE DECIDES TO START A CONVERSATION WITH YOU"
 3220 PRINT
 3230 PRINT M$;
 3240 INPUT (1,0)I$
 3250 PRINT
 3260 PRINT " HI THERE ...... ,"
 3270 PRINT "    I AM THE ONE AND ONLY MISS TELETYPE."
 3280 PRINT "......I'M SINGLE...and..LONELY...!"
 3290 PRINT "  I'M ALSO THE DIRTIEST DICE THROWER"
 3300 PRINT " THIS SIDE OF IBM."
 3310 PRINT
 3320 PRINT " Please enter your name ---=>";
 3330 INPUT T$
 3340 PRINT " HOW ABOUT IT ";T$
 3350 PRINT " WANT TO TRY YOUR LUCK ? "
 3360 PRINT " YES, NO  (INPUT: Y=YES  N=NO) ---=>";
 3370 INPUT (1,0)R$
 3380 IF R$=Y$ THEN 3400
 3390 IF R$=Y2$ THEN 4590
 3400 PRINT " HERES YOUR SELECTION OF DICE"
 3410 PRINT
 3420 PRINT
 3430 PRINT TAB(15);"1. BUNNY BLUE"
 3440 PRINT TAB(15);"2. GROSS GREEN"
 3450 PRINT TAB(15);"3. UNIVAC YELLOW"
 3460 PRINT
 3470 LET X=25000
 3480 PRINT " PLEASE INPUT ONLY ONE HONEY";
 3490 INPUT (1,0)F
 3500 IF F=1 THEN 3530
 3510 IF F=2 THEN 3550
 3520 IF F=3 THEN 3570
 3530 PRINT " I SEE YOURE THE SEXY TYPE"
 3540 GOTO 3590
 3550 PRINT " I SEE YOURE  A REALLY  BIG SPENDER"
 3560 GOTO 3590
 3570 PRINT
 3580 PRINT " SO YOU'RE THE CONSERVATIVE TYPE"
 3590 PRINT
 3600 PRINT " NOW YOU HAVE YOUR OWN COLORED DICE..."
 3610 PRINT "    YOU ARE SITTING NEXT TO A PLAYBOY BUNNY !"
 3620 PRINT
 3630 PRINT M$;
 3640 INPUT (1,0)I$
 3650 PRINT
 3660 PRINT "MISS TELETYPE SAYS, BETS PLEASE"
 3670 PRINT
 3680 PRINT " AND HOW MUCH IS OUR READERS DIGEST WINNER..."
 3690 PRINT " ......  GOING TO WAGER  ??? "
 3700 PRINT
 3710 PRINT "                  WAGER NOW"
 3720 PRINT " YOU HAVE ONLY GOT A MAXIMUM OF ";X
 3730 INPUT "---=>",A
 3740 IF A>X THEN 3720
 3750 IF A<0 THEN 4940
 3760 IF A<=100 THEN 3790
 3770 IF A>=1000 THEN 3850
 3780 IF 1000<A THEN 3850
 3790 PRINT " BOY WHAT A CHEAP SCATE"
 3800 GOTO 3860
 3810 PRINT " THATS A GOOD HONEST BET"
 3820 GOTO 3860
 3830 PRINT " NOW YOU ARE IN BUSSINESS LOVER"
 3840 GOTO 3860
 3850 PRINT " WHAT A SPENDER, LOVER, AND REALLY KOOL PERSON"
 3860 LET W=0
 3870 LET W=W+1
 3880 PRINT " YOURE NOW SHAKING YOUR DICE "
 3890 PRINT
 3900 PRINT " You blow on them for luck..."
 3910 PRINT
 3920 PRINT " YOU ROLL THEM"
 3930 LET R=INT(RND(0)*10)+1
 3940 IF R>6 THEN 3930
 3950 LET Z=INT(RND(0)*10)+1
 3960 IF Z>6 THEN 3950
 3970 PRINT " YOU'RE THROW WAS ";R+Z
 3980 PRINT
 3990 PRINT
 4000 IF W=1 THEN 4050
 4010 IF R+Z=11 THEN 4160
 4020 IF R+Z=7 THEN 4160
 4030 IF R+Z=F THEN 4180
 4040 GOTO 4120
 4050 IF R+Z=7 THEN 4140
 4060 LET F=R+Z
 4070 IF R+Z=11 THEN 4140
 4080 IF R+Z=2 THEN 4160
 4090 IF R+Z=12 THEN 4160
 4100 IF R+Z=3 THEN 4160
 4110 GOTO 4120
 4120 PRINT " MUST SHAKE AGAIN ,YOU HAVE NEITHER WON NOR LOST"
 4130 GOTO 4520
 4140 PRINT "YOU HAVE JUST DOUBLED YOUR BET"
 4150 GOTO 4200
 4160 PRINT "YOU HAVE LOST WHAT YOU HAVE BET"
 4170 GOTO 4330
 4180 PRINT "YOU HAVE JUST DOUBLED YOUR BET"
 4190 GOTO 4220
 4200 PRINT " YOU HAVE WON  ";2*A
 4210 GOTO 4240
 4220 PRINT "YOU HAVE WON ";A
 4230 GOTO 4300
 4240 LET X=X+(2*A)
 4250 PRINT " YOUR TOTAL TO NOW IS ";X
 4260 IF X<0 THEN 4380
 4270 GOTO 4400
 4280 PRINT " YOU HAVE JUST WON ";A
 4290 LET X=X+A
 4300 PRINT " YOUR TOTAL TO NOW IS ";X
 4310 IF X<0 THEN 4380
 4320 GOTO 4360
 4330 PRINT " YOU LOST  ";A
 4340 LET X=X-A
 4350 PRINT " YOUR TOTAL TO NOW IS ";X
 4360 IF X<0 THEN 4380
 4370 GOTO 4400
 4380 PRINT " YOU OWE MISS TELETYPE ";X
 4390 GOTO 4900
 4400 PRINT
 4410 IF X<0 THEN 4380
 4420 PRINT
 4430 PRINT "DO YOU WANT TO TRY AGAIN  "
 4440 PRINT
 4450 PRINT "YES ************** OR ************* NO"
 4460 PRINT
 4470 PRINT "---=>";
 4480 INPUT (1,0)P$
 4490 IF X<0 THEN 4380
 4500 IF P$=Y$ THEN 3710
 4510 IF P$=Y2$ THEN 4910
 4520 IF W>6 THEN 4570
 4530 IF W=6 THEN 4590
 4540 IF W=4 THEN 4880
 4550 IF W=5 THEN 4610
 4560 GOTO 4640
 4570 PRINT " THIS IS THE TIME FOR A KILLING  ";T$
 4580 GOTO 4640
 4590 PRINT " THE ODDS ARE GETTING BETTER YET"
 4600 GOTO 4640
 4610 PRINT "   The odds are comin in your favor baby...."
 4620 PRINT " ........BET A LITTLE MORE........"
 4630 PRINT
 4640 PRINT " Do you wish to increase your bet ";T$;"?"
 4650 PRINT " You need not if you think it wise."
 4660 PRINT
 4670 PRINT "****** YES ********** NO ******* I QUIT ******"
 4680 INPUT (1,0)"---=>",D$
 4690 IF D$=Y$ THEN 4720
 4700 IF D$="I QUIT" THEN 4910
 4710 IF D$=Y2$ THEN 3870
 4720 IF X-A>0 THEN 4770
 4730 IF X-A<0 THEN 4750
 4740 IF X-A=0 THEN 4790
 4750 PRINT " LISTEN BABY --- YOU OWE ME......";X
 4760 PRINT
 4770 PRINT " HOW MUCH DO YOU WISH TO UP YOUR WAGER BY ";T$
 4780 GOTO 4820
 4790 PRINT " YOU HAVE NO MORE MONEY TO BET WITH....."
 4800 PRINT "       SO YOU MUST HOPE FOR THE BEST."
 4810 GOTO 3870
 4820 PRINT
 4830 PRINT " YOU'VE GOT THIS MUCH TO BET WITH ";X-A
 4840 PRINT " INPUT THE AMOUNT NEXT LINE ";T$
 4850 INPUT "   ---=>",Z
 4860 LET A=A+Z
 4870 GOTO 3870
 4880 PRINT " DO OR DIE SPEND IT RIGHT NOW ";T$
 4890 GOTO 4770
 4900 PRINT " CREDIT NOT GOOD IN THIS CASINO"
 4910 PRINT "YOU'RE TOTAL IS  ";X
 4920 PRINT " THANK YOU FOR PLAYING IN THE CASINO UNIVAC 1110"
 4930 GOTO 4960
 4940 PRINT " YOU MUST BET A POSITIVE VALUE"
 4950 GOTO 3720
 4960 GOTO 8000
 4970 REM
 5000 REM ==== LAST MOD.  7/25/77   R.E.H.
 5010 PRINT
 5020 PRINT TAB(10);"* * *   D I C E  * * *"
 5030 PRINT
 5040 LET N=0
 5050 PRINT " THIS IS A SERIOUS GAME OF CRAPS"
 5060 PRINT " ...... AND WE PLAY FOR KEEPS!"
 5070 PRINT "VEGAS RULES - CRAPS ARE 2,3 AND 12"
 5080 PRINT "IF YOU WISH TO STOP - JUST BET ZERO DOLLARS!"
 5090 LET Z=5*(INT(RND(0)*10)+11)
 5100 PRINT "YOU ARE CLEARED FOR ";Z;" DOLLARS OF CREDIT!"
 5110 IF N-2*INT(N/2)=0 THEN 5150
 5120 LET W=-1
 5130 PRINT "I WILL ROLL FIRST!"
 5140 GOTO 5170
 5150 LET W=1
 5160 PRINT "YOU ROLL FIRST!"
 5170 LET Q=0
 5180 PRINT "HOW MUCH DO YOU BET?";
 5190 INPUT " ---=>",B
 5200 IF B=INT(B) THEN 5230
 5210 PRINT "NO COINS PLEASE - JUST BILLS!"
 5220 GOTO 5180
 5230 IF B=0 THEN 5860
 5240 IF B<Z+1 THEN 5270
 5250 PRINT "DO NOT TRY TO BET MORE THAN YOU HAVE PLEASE!"
 5260 GOTO 5180
 5270 LET D1=INT(RND(0)*6)+1
 5280 LET D2=INT(RND(0)*6)+1
 5290 LET Q=Q+1
 5300 LET S=D1+D2
 5310 PRINT " Throw number ";Q;TAB(20);
 5315 IF W>0 THEN 5340
 5320 PRINT "I ROLL ";D1;" and ";D2
 5330 GOTO 5350
 5340 PRINT "YOU ROLL ";D1;" and ";D2,"(";D1+D2;" )"
 5350 LET C=1
 5360 IF Q>1 THEN 5375 ELSE  LET P=S
 5365 IF (S-2)*(S-3)*(S-12)=0 THEN 5440
 5370 IF (S-7)*(S-11)=0 THEN 5510 ELSE 5380
 5375 IF (S-7)*(S-11)=0 THEN 5440
 5380 IF W>0 THEN 5410
 5390 PRINT "SO MY POINT IS ";P
 5400 GOTO 5420
 5410 PRINT "SO YOUR POINT IS ";P
 5420 IF Q=1 THEN  LET P=S
 5430 GOTO 5270
 5440 PRINT "...AND CRAP OUT!"
 5450 LET C=1
 5460 IF W>0 THEN 5490
 5470 LET Z=Z+B
 5480 GOTO 5570
 5490 LET Z=Z-B
 5500 GOTO 5570
 5510 PRINT "...AND PASS!"
 5520 LET C=1
 5530 IF W>0 THEN 5560
 5540 LET Z=Z-B
 5550 GOTO 5570
 5560 LET Z=Z+B
 5570 IF Z<1 THEN 5840
 5580 PRINT "YOU NOW HAVE ";Z;" DOLLARS!"
 5590 IF C>0 THEN 5610
 5600 PRINT "HAND OVER DICE!"
 5610 LET W=W*C
 5620 LET Q=0
 5630 GOTO 5180
 5640 IF S=7 OR S=11 THEN 5650 ELSE 5720
 5650 PRINT "...AND LOSE!"
 5660 LET C=-1
 5670 IF W>0 THEN 5700
 5680 LET Z=Z+B
 5690 GOTO 5570
 5700 LET Z=Z-B
 5710 GOTO 5570
 5720 IF S=P THEN 5750
 5730 PRINT "...ROLL AGAIN!"
 5740 GOTO 5270
 5750 IF W>0 THEN 5800
 5760 PRINT "...AND MAKE MY POINT!"
 5770 LET C=1
 5780 LET Z=Z-B
 5790 GOTO 5570
 5800 PRINT "...AND MAKE YOUR POINT!"
 5810 LET C=1
 5820 LET Z=Z+B
 5830 GOTO 5570
 5840 PRINT "YOU HAVE RUN OUT OF MONEY ... SORRY ABOUT THAT!"
 5850 GOTO 5880
 5860 PRINT "THANKS FOR THE GAME AND CONGRATULATIONS"
 5870 PRINT "    FOR BEING ABLE TO QUIT WHILE AHEAD!"
 5880 GOTO 8000
 5890 REM
 7000 REM ...NAME -- D-CRAPS     LAST MOD   7/25/77
 7010 REM
 7020 REM ...DESCRIPTION--A SESSION AT THE CRAPS TABLE.
 7030 REM
 7040 REM ...SOURCE--UNKNOWN
 7050 REM
 7060 REM ------TYPE "RUN" AND FOLLOW INSTRUCTIONS.
 7070 REM
 7080 REM
 7090 REM *  *  *  *  *   MAIN PROGRAM  *  *  *  *  *
 7100 REM
 7110 PRINT
 7120 PRINT "WELCOME TO THE DARTMOUTH CRAPS TABLE."
 7130 PRINT
 7140 PRINT "DO YOU WANT INSTRUCTIONS ?"
 7150 PRINT "(ENTER:  Y=YES  N=NO) ---=>";
 7160 INPUT (1,0)Z$
 7170 IF Z$=Y2$ THEN 7280 ELSE  PRINT
 7180 IF Z$=Y$ THEN 7210 ELSE  PRINT
 7190 PRINT "INCORRECT ANSWER.  PLEASE TYPE 'Y' FOR YES OR 'N' FOR NO"
 7200 GOTO 7160
 7210 PRINT " ON THE FIRST THROW 2S,3S AND 12S LOSE,"
 7220 PRINT " 7S AND 11S WIN.  ON LATER THROWS"
 7230 PRINT " 7S AND 11S LOSE, THE ORIGINAL NUMBER WINS,"
 7240 PRINT " AND ANY OTHER RESULT CAUSES ANOTHER THROW."
 7250 PRINT " BETS MAY RANGE FROM .01 TO 10,000."
 7260 PRINT " TYPE -1 TO FIND THE STATE OF YOUR"
 7270 PRINT " WINNINGS OR LOSSES, AND A 0 TO QUIT."
 7280 PRINT
 7290 PRINT " HOW MUCH DO YOU BET ? ---=>";
 7300 INPUT B1
 7310 IF B1<0 THEN 7750
 7320 IF B1=0 THEN 7880
 7330 IF B1<5 THEN 7860
 7340 IF B1>10000 THEN 7730
 7350 LET T7=0
 7360 LET D1=INT(6*RND(0))+1
 7370 LET D2=INT(6*RND(0))+1
 7380 PRINT D1;D2;
 7390 LET T=D1+D2
 7400 IF T7>0 THEN 7430
 7410 IF T=12 THEN 7660
 7420 IF T=2 THEN 7680
 7430 IF T=8 THEN 7470
 7440 IF T=11 THEN 7470
 7450 PRINT " ...A  ";T;
 7460 GOTO 7480
 7470 PRINT " ...AN ";T;
 7480 IF T7>0 THEN 7540
 7490 IF T=3 THEN 7690
 7500 IF T=7 THEN 7620
 7510 IF T=11 THEN 7620
 7520 LET D9=T
 7530 GOTO 7590
 7540 IF T=7 THEN 7690
 7550 IF T=11 THEN 7690
 7560 IF T=D9 THEN 7620
 7570 PRINT
 7580 GOTO 7360
 7590 PRINT " YOUR NUMBER IS ";T
 7600 LET T7=1
 7610 GOTO 7360
 7620 PRINT " YOU WIN"
 7630 LET W=W+B1
 7640 PRINT " YOU WIN ";B1;" DOLLARS."
 7650 GOTO 7280
 7660 PRINT " BOXCARS.....";
 7670 GOTO 7690
 7680 PRINT " SNAKES EYES.....";
 7690 LET W=W-B1
 7700 PRINT ,"*#* You Lose *#*&J"
 7710 PRINT " YOU LOSE ";B1;" DOLLARS."
 7720 GOTO 7280
 7730 PRINT " ARE YOU KIDDING ME? TRY A LITTLE LESS"
 7740 GOTO 7280
 7750 PRINT
 7760 IF W>=0 THEN 7830
 7770 PRINT " YOU ARE BEHIND ";-W;" DOLLARS--TRY SOME MORE ---=>";
 7780 INPUT (1,0)H$
 7790 IF H$=Y2$ THEN 7880 ELSE  PRINT
 7800 IF H$=Y$ THEN 7280 ELSE  PRINT
 7810 PRINT "Incorrect answer.&J Please type yes or no.&J"
 7820 GOTO 7780
 7830 PRINT " YOU ARE AHEAD ";W;" DOLLARS."
 7840 PRINT " -------HOW ABOUT A LITTLE MORE";
 7850 GOTO 7780
 7860 PRINT " YOU ARE A CHEAPSKATE--BUT I WILL PLAY"
 7870 GOTO 7350
 7880 PRINT
 7890 PRINT
 7900 PRINT
 7910 PRINT
 7920 IF W>=0 THEN 7960
 7930 PRINT "  YOU LOST ";-W;" DOLLARS./. TOUGH LIFE"
 7940 PRINT " LET THIS BE A LESSON"
 7950 PRINT
 7960 PRINT " YOU WON ";W;" DOLLARS..."
 7970 PRINT " .............WILL SEND CHECK IMMEDIATELY"
 7980 REM ..........***** THE END *****..........
 7990 REM
 8000 PRINT
 8010 PRINT "*** DO YOU WANT TO TRY A DIFFERENT GAME ?"
 8020 PRINT "(INPUT:  Y=YES  N=NO) ---=>";
 8030 INPUT (1,0)A$
 8040 IF A$=Y$ THEN 170 ELSE  PRINT
 8050 PRINT TAB(15);"+++ THE DICE & CRAPS TABLES ARE CLOSED +++"
 8060 END