10 REM EIGHT.ECB
   20 REM ...EIGHT (MEN)...Source ??? Via EAGAN Aug. 77 REH
   30 REM ======= VARIBLES USED: A B G H I K z A$  J$  R$
   40 PRINT "&K&J&J"
  100 REM ARKABLE PROGRAM WRITTEN BY RJC 4-10-69
  110 REM ...VERSION 3 4/18/69 ...Last mod 3-05-81 R.E.H.
  120 LET A$=" "
  130 DIM Z$(9),Y$(9)
  140 PRINT "     88888    E I G H T  M E N    88888"
  150 PRINT : PRINT
  160 PRINT "Do you know how to play ? ( Y or N ) ---=>";
  170 INPUT (1,0)R$: LET R$=R$+"Y": PRINT
  180 ON FNA(Z) GOTO 490,210,190
  190 PRINT : PRINT "ANSWER EITHER Y or N   (Yes or No)"
  200 GOTO 150
  210 PRINT A$,"POSITION NUMBERING-"
  220 PRINT A$,"123456789"
  230 PRINT A$,"****OXXXX"
  240 PRINT
  250 PRINT A$,"OBJECT-"
  260 PRINT "To REVERSE the position of the *'s and the x'S."
  270 PRINT "The O is an empty space."
  280 PRINT
  290 PRINT "===== TYPE IN A -C- TO CONTINUE =====";
  300 INPUT (1,0)R$: PRINT "&K"
  310 PRINT A$,"PUZZLE-"
  320 PRINT "THE CENTER HOLE IS VACANT, AND FOUR MEN"
  330 PRINT "OF EACH KIND ARE ON EACH SIDE OF THE HOLE."
  340 PRINT "  YOU MOVE BY EITHER JUMPING TO THE NEXT HOLE"
  350 PRINT "OR JUMPING OVER ONE MAN."
  360 PRINT "   BACKWARD MOVES ARE NOT PERMITTED."
  370 PRINT "A SAMPLE MOVE WOULD BE 4,5 OR 3,5 "
  380 PRINT "AND YOU PLAY AGAINST YOURSELF."
  390 PRINT
  400 PRINT "===== TYPE IN A -C- TO CONTINUE =====";
  410 INPUT (1,0)R$
  420 PRINT
  430 PRINT " === UNIVAC JUST KEEPS YOU HONEST ! ==="
  440 PRINT
  450 PRINT A$,"TO CONCEDE AT ANY TIME---TYPE 9,9"
  460 PRINT
  470 PRINT A$,A$,"GOOD LUCK"
  480 PRINT : REM ...RESTART entry
  490 LET Z$="****OXXXX"
  500 LET Y$="XXXXO****"
  580 PRINT : PRINT TAB(9);"123456789": REM ...PLAYS THE GAME
  590 PRINT TAB(9);Z$: PRINT
  600 PRINT "    Your move ---=>";
  610 INPUT A,B
  620 REM ...CHECKS FOR VALID MOVE
  630 IF A=B THEN 860
  640 IF A+B>17 THEN 830
  650 IF Z$(B,B)<>"O" THEN 830
  660 IF Z$(A,A)="X" THEN 710
  670 IF A>B THEN 830
  680 IF B-A>2 THEN 830
  690 LET Z$(B,B)="*"
  700 GOTO 740
  710 IF B>A THEN 830
  720 IF A-B>2 THEN 830
  730 LET Z$(B,B)="X"
  740 LET Z$(A,A)="O"
  750 REM ...CHECKS FOR A WIN
  760 FOR I=1 TO 9
  770   IF Z$(I,I)<>Y$(I,I) THEN  EXIT 580
  780 NEXT I
  790 PRINT TAB(9);Z$: PRINT
  800 PRINT "      ******* YOU DID IT *******!!!!!"
  810 LET H=H+1
  820 GOTO 880
  830 PRINT "INVALID MOVE"
  840 LET K=K+1
  850 GOTO 600
  860 PRINT "YOU CONCEDE"
  870 LET G=G+1
  880 PRINT "Do you want to try again ---=>";
  890 INPUT (1,0)R$: LET R$=R$+"Y": PRINT
  900 ON FNA(Z) GOTO 490,1000,910
  910 PRINT "JUST A YES OR NO PLEASE"
  920 GOTO 890
  930 DEF FNA(Z)
  940 LET Z=1
  950 IF R$(1,1)="Y" THEN 990
  955 IF R$(1,1)="y" THEN 990
  960 LET Z=2
  970 IF R$(1,1)="N" THEN 990
  975 IF R$(1,1)="n" THEN 990
  980 LET Z=3
  990 RETURN (Z)
  995 FNEND
 1000 IF H>0 THEN 1100
 1010 PRINT "YOU HAVEN'T SOLVED THE PUZZLE YET"
 1020 PRINT " SO LET'S PLAY AGAIN ANYWAY"
 1030 PRINT "WHAT DO YOU SAY ---=>";
 1040 INPUT (1,0)R$: LET R$=R$+"Y"
 1050 ON FNA(Z) GOTO 140,1090,1070
 1060 PRINT
 1070 PRINT "A YES OR NO WILL DO"
 1080 GOTO 1030
 1090 PRINT "QUITTER"
 1100 PRINT "Your SCORE is ";H;" Wins,  ";G;" Losses"
 1110 PRINT "  and ";K;" INVALID MOVES !!!"
 1120 PRINT "GOODBYE"
 1140 END