10 REM FUNDS.ECB
   90 DIM E$(18)
  100 PRINT "&K";: CLEAR
  101 SET DS=0
  105 ERRSET 13000
  120 PRINT : PRINT "ENTER THE NUMBER OF ONE OF THE FOLLOWING PROGRAMS:"
  130 PRINT
  140 PRINT "   1 - PRESENT VALUE OF A FUTURE SUM"
  150 PRINT "   2 - SIMPLE INTEREST FOR DAYS"
  160 PRINT "   3 - FUTURE VALUE OF A PRESENT SUM"
  170 PRINT "   4 - AMORTIZATI0N SCHEDULE"
  175 PRINT "   5 - INTEREST RATE - COMPOUND INTEREST"
  176 PRINT "   6 - INTEREST RATE - INSTALLMENT LOAN"
  177 PRINT "   7 - DAYS BETWEEN DATES"
  178 PRINT "   8 - TERM OF AN INSTALLMENT LOAN"
  179 PRINT "   9 - PRESENT VALUE OF A SERIES OF PAYMENTS"
  180 PRINT "  10 - REAL ESTATE CAPITAL INVESTMENT"
  189 PRINT : INPUT "ENTER PROGRAM NUMBER:  ",F
  190 IF F<>ABS(INT(F)) OR F>10 THEN  GOTO 100
  195 ON F GOTO 1000,2000,3000,4000,5000,6000,7000,8000,9000,10000
  200 GOTO 100
 1000 LET F=0: LET R=0: LET M=0: LET N=0: PRINT "&K"
 1010 PRINT : PRINT "THIS PROGRAM CALCULATES THE PRESENT VALUE OF"
 1020 PRINT "A FUTURE SUM, DISCOUNTING IT FOR A PARTICULAR"
 1030 PRINT "INTEREST RATE, COMPOUNDED AS INSTRUCTED."
 1040 PRINT : INPUT "STATE THE FUTURE SUM, IN DOLLARS ",F
 1050 INPUT "STATE THE ANNUAL INTEREST RATE, IN % ",R
 1060 INPUT "STATE THE NUMBER OF PERIODS IN ONE YEAR ",M
 1070 INPUT "STATE THE NUMBER OF PERIODS TO BE CALCULATED ",N
 1080 LET I=R/M: LET I=I/100
 1090 LET T=1+I: LET A=T
 1095 IF N=1 THEN  GOTO 1110
 1100 FOR X=1 TO (N-1): LET S=A*T: LET A=S: NEXT X
 1120 LET P=F/A: PRINT "&K": PRINT : PRINT : PRINT
 1130 PRINT " A FUTURE SUM OF $";F;" FOR";N;" PERIODS,"
 1140 PRINT " WHERE THERE ARE";M;" PERIODS PER YEAR AT"
 1150 PRINT R;"% PER YEAR IS WORTH, IN TODAY'S DOLLARS:"
 1160 PRINT : PRINT TAB(30);"$";P
 1170 PRINT : INPUT "PRESS ENTER TO RETURN. ",A$
 1180 GOTO 100
 1190 END
 2000 LET P=0: LET D=0: LET R=0
 2010 PRINT "&K": PRINT : PRINT "THIS ROUTINE CALCULATES SIMPLE INTEREST ON"
 2020 PRINT "DOLLARS HELD IN DEPOSIT FOR A SPECIFIED PERIOD"
 2030 PRINT "USING A SPECIFIED PERCENTAGE OF INTEREST.": PRINT
 2040 INPUT "HOW LARGE IS THE DEPOSIT (IN DOLLARS)",P
 2050 INPUT "HOW LONG WILL YOU LEAVE IT IN (IN DAYS)",D
 2060 INPUT "WHAT INTEREST RATE DO YOU EXPECT (IN %)",R
 2070 PRINT "&K";: PRINT : PRINT : PRINT
 2071 PRINT "FOR A STARTING PRINCIPAL OF $";P;" AT A"
 2080 PRINT "RATE OF";R;"% FOR";D;" DAYS, THE INTEREST"
 2090 PRINT "AMOUNTS TO $";
 2200 LET I=R/100/365*D*P
 2250 IF I>327.68 THEN  GOTO 2300
 2260 LET I=INT(I*100+.5)/100
 2300 PRINT TAB(12);I;" OR $";I/D;" PER DAY.": PRINT : PRINT : PRINT
 2310 INPUT "PRESS ENTER TO RETURN.",A$: GOTO 100
 2400 END
 3000 PRINT "&K": LET P=0: LET R=0: LET M=0: LET N=0
 3001 PRINT ," FUTURE VALUE OF A PRESENT SUM": PRINT : PRINT
 3010 PRINT : INPUT "ENTER PRESENT SUM, IN DOLLARS: ",P
 3020 PRINT : INPUT "ENTER ANNUAL INTEREST RATE, IN % ",R
 3030 PRINT : INPUT "ENTER NUMBER OF PERIODS IN ONE YEAR ",M
 3040 PRINT : INPUT "ENTER NUMBER OF PERIODS TO MATURITY ",N
 3050 LET I=R/M: LET I=I/100: LET T=I+1: LET A=T
 3055 IF N=1 THEN  THEN  GOTO 3070
 3060 FOR K=1 TO (N-1): LET S=A*T: LET A=S: NEXT K
 3070 LET F=P*A: PRINT "&K": PRINT : PRINT : PRINT
 3080 PRINT "FOR A PRESENT SUM OF $";P;" AT AN ANNUAL"
 3090 PRINT "INTEREST RATE OF";R;"%, FOR";N;" PERIODS, WHERE"
 3100 PRINT "THERE ARE";M;" PERIODS PER YEAR:"
 3110 PRINT : PRINT "THE FUTURE VALUE IS $";F
 3120 PRINT "THE INCREASE IS $";F-P;", OR";(F/P)*100-100;"%"
 3200 CURSOR 14,15: INPUT "PRESS ENTER TO RETURN TO MENU.",A$
 3210 GOTO 100
 3220 END
 4000 LET C=0: LET P=0: LET L=0: LET R=0: LET M=0: PRINT "&K"
 4001 PRINT ,"AMORTIZATION SCHEDULE": PRINT : PRINT
 4010 INPUT " PRINCIPAL, DOLLARS AND CENTS ",P
 4020 INPUT " # OF PERIODS, IN MONTHS ",L
 4030 INPUT " ANNUAL INTEREST RATE, IN % ",R
 4035 INPUT " PAYMENT, IF KNOWN, (ZERO) IF NOT:  $",M
 4040 LET I=R/1200
 4050 LET T=1-1/(1+I)^L: LET K=P
 4070 IF M<>0 THEN  GOTO 4090
 4080 LET M=P*I/T
 4090 GOSUB 4200
 4100 FOR Z=1 TO L
 4110   IF C<12 THEN  GOTO 4118
 4113   PRINT " YEAR OF LOAN: ";INT(Z-1)/12;
 4114   PRINT "    $";K;" FOR";L;" MONTHS AT";R;"%"
 4115   PRINT "PRESS 'ENTER' TO CONTINUE  - '1' TO RETURN TO MENU";
 4116   INPUT C$: IF C$="1" THEN  GOTO 100
 4117   LET C=0: GOSUB 4200
 4118   LET A=P*I
 4120   LET A=INT(A*100+.5)/100
 4125   LET M=INT(M*100+.5)/100
 4130   LET B=M-A: LET P=P-B
 4132   LET B=INT(B*100+.5)/100
 4135   LET P=INT(P*100+.5)/100
 4140   PRINT Z;: PRINT TAB(10);P;: PRINT TAB(20);M;
 4150   PRINT TAB(30);B;: PRINT TAB(40);A
 4160 LET C=C+1: NEXT Z
 4170 PRINT : INPUT "PRESS ENTER TO RETURN TO MENU.",A$: GOTO 100
 4180 END
 4200 PRINT "&K";
 4250 PRINT "PAYMENT   REM AINING  MONTHLY   PRINCIPAL INTEREST"
 4260 PRINT "NUMBER    PRINCIPAL  PAYMENT   PAYMENT   PAYMENT"
 4270 RETURN
 5000 PRINT "&K";: PRINT ,"INTEREST RATE - COMPOUND INTEREST": PRINT : PRINT
 5001 LET F=0
 5030 INPUT "STATE THE FUTURE VALUE, IN $",F1
 5035 IF F=2 THEN  GOTO 5090
 5040 INPUT "STATE THE PRESENT VALUE, IN $",P1
 5045 IF F=1 THEN  GOTO 5090
 5050 INPUT "STATE THE NUMBER OF INTEREST PERIODS PER YEAR ",P2
 5055 IF F=3 THEN  GOTO 5090
 5060 PRINT "STATE THE LENGTH OF TIME OF THE TOTAL FOR WHICH"
 5070 PRINT "INTEREST IS TO BE FIGURED, USING THE FOLLOWING"
 5080 INPUT "FORMAT (YY,MM,DD) ",Y,M,D
 5090 LET P3=Y*P2+M*P2/12+D*P2/365
 5100 LET I=((F1/P1)^(1/P3)-1)*100*P2
 5110 LET F=0
 5120 PRINT "&K";: PRINT : PRINT
 5121 PRINT "FOR A FUTURE SUM OF $";F1;" WITH A PRESENT VALUE"
 5130 PRINT "OF $";P1;" WHERE THERE ARE";P2;" PERIODS PER YEAR,"
 5140 PRINT "OVER";Y;" YEARS,";M;" MONTHS AND";D;" DAYS, THE"
 5150 PRINT "ANNUAL INTEREST RATE IS ";%6F2;I;" %"
 5160 PRINT : PRINT "WHAT DO YOU WANT TO DO?"
 5170 PRINT "   1 - CHANGE PRESENT VALUE"
 5180 PRINT "   2 - CHANGE FUTURE VALUE"
 5190 PRINT "   3 - CHANGE PERIODS PER YEAR"
 5200 PRINT "   4 - CHANGE TIME RANGE"
 5210 PRINT "   5 - RERUN ENTIRE PROGRAM"
 5220 PRINT "   6 - RETURN TO MENU"
 5230 PRINT : INPUT "ENTER THE NUMBER OF YOUR CHOICE: ",F
 5240 IF F<1 OR F>6 THEN  GOTO 5120
 5250 LET F=INT(F): ON F GOTO 5040,5030,5050,5060,5000,100
 5999 END
 6000 LET F=0: PRINT "&K";: PRINT ,"INTEREST RATE - INSTALLMENT LOAN"
 6001 CLEAR
 6010 ERRSET 13000
 6020 PRINT : INPUT "STATE THE PRESENT VALUE (AMOUNT), IN $ ",P1
 6025 IF F=1 THEN  GOTO 6070
 6030 INPUT "STATE THE NUMBER OF TERMS PER YEAR ",N1
 6035 IF F=3 THEN  GOTO 6070
 6040 INPUT "STATE THE NUMBER OF PERIODS OF THE LOAN ",N
 6045 IF F=2 THEN  GOTO 6070
 6050 INPUT "STATE THE AMOUNT OF EACH PAYMENT, IN $",P
 6055 IF F=4 THEN  GOTO 6070
 6060 PRINT "&K";: PRINT : PRINT ,"THIS IS AN ITERATIVE PROCESS - STAND BY"
 6070 LET I=.008
 6080 LET I1=P/P1*((1+I)^N-1)/(1+I)^N
 6090 IF ABS(I-I1)<.000001 THEN  GOTO 6140
 6100 LET I=I1
 6110 GOTO 6080
 6140 LET I=I1*N1*100
 6150 PRINT "&K";: PRINT ,"INTEREST RATE - INSTALLMENT LOAN": PRINT
 6160 PRINT "FOR A LOAN WITH A PRESENT VALUE OF $";P1
 6170 PRINT "AND";N;" PAYMENTS OF $";P;", WHERE THERE"
 6180 PRINT "ARE";N1;" PAYMENTS PER YEAR, THE ANNUAL"
 6190 PRINT "INTEREST RATE IS ";
 6200 PRINT %6F3;I;" %"
 6210 LET F=0: PRINT
 6220 PRINT "DO YOU WANT TO:"
 6230 PRINT "   1 - CHANGE LOAN VALUE"
 6240 PRINT "   2 - CHANGE NUMBER OF INTEREST PERIODS"
 6250 PRINT "   3 - CHANGE PERIODS PER YEAR"
 6260 PRINT "   4 - CHANGE PAYMENT AMOUNT"
 6270 PRINT "   5 - RERUN ENTIRE PROGRAM"
 6280 PRINT "   6 - RETURN TO MENU"
 6290 PRINT : INPUT "ENTER THE NUMBER OF YOUR CHOICE: ",F
 6300 IF F<1 OR F>6 THEN  GOTO 6290
 6310 ON F GOTO 6020,6040,6030,6050,6000,100
 6320 LET F=INT(F): GOTO 100
 6999 END
 7000 PRINT "&K";: LET C2=0: PRINT ,"DAYS BETWEEN DATES": PRINT
 7040 PRINT "USING THE FORMAT  (MM,DD,YYYY)"
 7050 INPUT "ENTER THE FIRST DATE ",M,D,Y: GOSUB 7200
 7055 LET N=M: LET F=D: LET Z=Y: LET E=T
 7057 IF C2=1 THEN  GOTO 7070
 7060 INPUT "ENTER THE SECOND DATE ",M,D,Y: GOSUB 7200
 7065 LET P=M: LET G=D: LET W=Y: LET L=T
 7070 IF E>L THEN  PRINT "CHECK THE DATES.  TRY AGAIN": GOTO 7050
 7080 LET O=L-E: PRINT "&K";: PRINT
 7090 PRINT "THE LENGTH IN DAYS FROM: ";N;"/";F;"/";Z
 7100 PRINT TAB(21);"TO: ";P;"/";G;"/";W
 7110 PRINT TAB(21);"IS: ";O;" DAYS."
 7120 LET C2=0: PRINT : PRINT : PRINT "DO YOU WISH TO:"
 7130 PRINT "   1 - CHANGE EARLY DATE"
 7140 PRINT "   2 - CHANGE LATEST DATE"
 7150 PRINT "   3 - RERUN ENTIRE PROGRAM"
 7160 PRINT "   4 - RETURN TO MENU"
 7170 CURSOR 14,14: INPUT "ENTER THE NUMBER OF YOUR CHOICE: ",C2
 7180 IF (C2<>INT(C2)) OR C2>4 THEN  GOTO 7170
 7185 IF C2<=0 THEN  GOTO 7170
 7190 ON C2 GOTO 7050,7060,7000,100
 7200 LET Y4=Y-1: LET T=365*Y4+INT(Y4/4)-INT(Y4/100)+INT(Y4/400)
 7210 LET C4=30*(M-1)+INT((M-1)/3)+D
 7220 IF M=2 OR M=9 OR M>10 THEN  LET C4=C4+1: GOTO 7240
 7230 IF M>2 AND M<8 AND M<>6 THEN  LET C4=C4-1
 7240 IF M<3 OR Y<>4*INT(Y/4) THEN  GOTO 7260
 7250 IF Y=400*INT(Y/400) OR Y<>100*INT(Y/100) THEN  LET C4=C4+1
 7260 LET T=T+C4: RETURN
 8000 PRINT "&K";: PRINT : PRINT
 8002 PRINT "THIS PROGRAM WILL DETERMINE THE LENGTH OF TIME NEEDED"
 8020 PRINT "TO PAY AN INSTALLMENT LOAN.  PLEASE PROVIDE THE "
 8030 PRINT "FOLLOWING INFORMATI0N."
 8050 PRINT : INPUT "WHAT WAS THE ORIGINAL AMOUNT OF THE LOAN: $ ",O1
 8055 IF F=1 THEN  GOTO 8090
 8060 INPUT "HOW MUCH IS THE PAYMENT: $",P4
 8065 IF F=2 THEN  GOTO 8090
 8070 INPUT "HOW MANY PAYMENTS PER YEAR? ",P2
 8075 IF F=3 THEN  GOTO 8090
 8080 INPUT "WHAT IS THE ANNUAL INTEREST RATE? ",I3
 8090 PRINT "&K": LET I2=O1*I3/100/P2
 8095 IF P4<=I2 THEN  PRINT "ERROR!  THE PMT. IS < INT. TRY AGAIN": GOTO 8050
 8100 LET Y=-(LOG(1-(O1*(I3/100))/(P2*P4))/(LOG(1+(I3/100)/P2)*P2))
 8105 LET N2=Y*P2
 8110 PRINT "FOR AN ORIGINAL LOAN AMOUNT OF $";O1;" PAYABLE"
 8120 PRINT "AT";I3;"% WITH";P2;" PAYMENTS PER YEAR, THE NUMBER OF"
 8130 PRINT "$";P4;" PAYMENTS NECESSARY TO PAY THE LOAN IS";N2
 8140 PRINT "OR";Y;" YEARS."
 8150 PRINT : PRINT "WHAT DO YOU WANT TO DO:"
 8160 PRINT "    1 - CHANGE ORIGINAL LOAN AMOUNT"
 8170 PRINT "    2 - CHANGE AMOUNT OF PAYMENT"
 8180 PRINT "    3 - CHANGE PAYMENTS PER YEAR"
 8190 PRINT "    4 - CHANGE ANNUAL INTEREST RATE"
 8200 PRINT "    5 - RERUN ENTIRE PROGRAM"
 8210 PRINT "    6 - RETURN TO MENU"
 8230 CURSOR 14,12: INPUT "ENTER THE NUMBER OF YOUR CHOICE: ",F
 8250 IF F<>ABS(INT(F)) OR F>6 THEN  GOTO 8230
 8260 ON F GOTO 8050,8060,8070,8080,8000,100
 9000 PRINT "&K": PRINT
 9001 PRINT "THIS PROGRAM DETERMINES THE PRESENT VALUE OF A SERIES"
 9030 PRINT "OF PAYMENTS.  IT IS NORMALLY USED TO DETERMINE THE AMOUNT"
 9040 PRINT "REMAINING ON A LOAN.  YOU MUST KNOW THE AMOUNT OF THE"
 9050 PRINT "REGULAR PAYMENT, THE NUMBER OF PAYMENTS REM AINING,"
 9060 PRINT "THE NUMBER OF PAYMENTS PER YEAR AND THE INTEREST RATE."
 9080 PRINT : INPUT "HOW MUCH IS THE REGULAR PAYMENT $",P4
 9085 IF F=1 THEN  GOTO 9120
 9090 INPUT "HOW MANY PAYMENTS REM AIN       ",N2
 9095 IF F=2 THEN  GOTO 9120
 9100 INPUT "HOW MANY PAYMENTS PER YEAR     ",P2
 9105 IF F=3 THEN  GOTO 9120
 9110 INPUT "WHAT IS THE ANNUAL INTEREST RATE(%)? ",I3
 9120 LET I=I3/100: LET T1=1+(I/P2): LET T1=T1^N2: LET T1=1/T1: LET T1=1-T1
 9121 PRINT "&K";
 9130 LET P6=P4*P2*T1/I
 9140 PRINT "FOR";N2;" PAYMENTS OF $";P4;" WHERE THERE ARE";P2
 9150 PRINT "PAYMENTS PER YEAR AT AN ANNUAL INTEREST RATE OF";I3;"%"
 9160 PRINT "THE ORIGINAL PRINCIPAL (OR THE VALUE OF THE REM AINING"
 9170 PRINT "PAYMENTS) IS $";P6
 9180 PRINT : PRINT : PRINT "WHAT DO YOU WANT TO DO:"
 9190 PRINT "    1 - CHANGE PAYMENT AMOUNT"
 9200 PRINT "    2 - CHANGE NUMBER OF PAYMENTS"
 9210 PRINT "    3 - CHANGE PAYMENTS PER YEAR"
 9220 PRINT "    4 - CHANGE ANNUAL INTEREST RATE"
 9230 PRINT "    5 - RERUN ENTIRE PROGRAM"
 9240 PRINT "    6 - RETURN TO MENU"
 9245 CURSOR 14,12: INPUT "ENTER THE NUMBER OF YOUR CHOICE: ",F
 9250 IF F<>ABS(INT(F)) OR F>6 THEN  GOTO 9245
 9260 ON F GOTO 9080,9090,9100,9110,9000,100
 9270 END
10000 CLEAR : PRINT "&K";
10020 ERRSET 13000
10025 PRINT ,"REAL ESTATE CAPITAL INVESTMENT"
10026 PRINT
10100 INPUT "WHAT IS THE PURCHASE PRICE OF THE PROPERTY $",G1
10108 IF X=4 THEN  GOTO 10700
10110 INPUT "WHAT IS THE VACANCY ALLOWANCE (IN %) ",V1
10118 IF X=2 THEN  GOTO 10700
10120 INPUT "HOW MANY UNITS DOES THE PROPERTY HAVE? ",U1
10130 INPUT "HOW MANY SQUARE FEET OF USABLE SPACE? ",S8
10140 INPUT "WHAT IS THE ANTICIPATED GROSS INCOME $",G2
10148 IF X=1 THEN  GOTO 10700
10150 PRINT "WHAT IS THE EXPECTED EXPENSE RATIO, THAT IS, THE"
10151 INPUT "    EXPENSES OVER THE GROSS INCOME, IN %",E2
10155 IF X=3 THEN  GOTO 10700
10160 INPUT "HOW MANY MORTGAGES WILL THERE BE (1 OR 2)? ",M3
10161 PRINT "&K": IF M>2 THEN  GOTO 10160
10164 PRINT "&K": PRINT "FOR INTEREST ONLY OR BALLOON MORTGAGES,"
10165 PRINT "MONTHS = 1000"
10167 REM . DEF INTI
10169 LET M4=0
10170 FOR I=1 TO 2: LET A1(I)=0: LET T2(I)=0: LET R3(I)=0: LET Y1(I)=0
10171 LET C3(I)=0: LET P5(I)=0: NEXT I
10180 FOR I=1 TO M3
10190   PRINT : PRINT "FOR MORTGAGE NUMBER ";I;" GIVE THE FOLLOWING"
10200   INPUT "TOTAL AMOUNT OF THE MORTGAGE $",A1(I)
10210   INPUT "THE TERM, IN MONTHS? ",T2(I)
10220   INPUT "THE INTEREST RATE, IN % ",R3(I)
10230   LET M4=M4+A1(I)
10240 NEXT I
10250 IF X=5 THEN  GOTO 10700
10505 ERRSET 13000
10510 PRINT "&K": PRINT "DESCRIBE DEPRECIATI0N METHODS"
10520 INPUT "ALLOCATI0N TO BUILDING IN % ",D1
10525 INPUT "ALLOCATI0N TO PERSONALTY IN % ",D2
10530 IF D1+D2>=100 THEN  PRINT "TOO MUCH": FOR F3=1 TO 1000: NEXT F3: GOTO 10520
10540 PRINT "WHAT METHOD OF DEPRECIATI0N IS TO BE USED"
10550 PRINT "FOR THE BUILDING.  INPUT SL, DDB, 125%, OR 150% ";
10560 INPUT D4$: IF Y=10 THEN  GOTO 11000
10570 INPUT "TERM OF BUILDING DEPRECIATI0N, IN YRS. ",Y2
10580 PRINT "WHAT METHOD OF DEPRECIATI0N IS TO BE USED"
10590 PRINT "FOR PERSONAL PROPERTY.  INPUT SL, DDB, 125% OR 150%";
10600 INPUT D3$: IF Y=11 THEN  GOTO 11050
10610 INPUT "TERM OF PERSONAL PROPERTY DEP. IN YRS. ",Y3
10700 PRINT "&K": PRINT "","COMPUTER WORKING - STAND BY"
10710 LET V2=V1*G2/100
10715 LET E3=E2*(G2-V2)/100
10720 LET O2=G2-V2-E3
10725 IF M3=0 THEN  GOTO 10920
10730 LET M1=0: LET M2=0: LET P5(1)=0: LET P5(2)=0: LET I4(1)=0: LET I4(2)=0
10740 FOR X=1 TO M3
10742   IF T2(X)=1000 THEN  LET I4(X)=A1(X)*(R3(X)/100): GOTO 10880
10745   LET I(X)=R3(X)/1200
10750   LET T=(I(X)+1)^(-T2(X)): LET T=1-T: LET M5(X)=I(X)*A1(X)/T
10800   LET M5(X)=INT(M5(X)*100+.5)/100
10810   LET I4(X)=0: LET P5(X)=0: LET R4=A1(X)
10820   FOR Z=1 TO 12
10830     LET I5=INT(R4*I(X)*100+.5)/100
10840     LET Q1=M5(X)-I5
10850     LET I4(X)=I4(X)+I5
10860     LET P5(X)=P5(X)+Q1
10865     LET R4=R4-Q1
10870   NEXT Z
10880   LET I4=I4+I4(X): LET P4=P4+P5(X)
10890 NEXT X
10900 LET M1=P5(1)+I4(1): LET M2=P5(2)+I4(2)
10920 LET C3=O2-M1-M2
10930 LET P9=P5(1)+P5(2)
10940 LET A1=A1(1)+A1(2)
10950 LET R2=C3+P9
10960 LET E1=G1-A1
10970 LET R1=R2/E1*100
10990 LET D3=0
11000 IF D4$="DDB" THEN  LET D3=D1*G1/Y2/50: GOTO 11050
11010 IF D4$="SL" THEN  LET D3=D1*G1/Y2/100: GOTO 11050
11020 IF D4$="125%" THEN  LET D3=D1*G1/Y2*.0125: GOTO 11050
11030 IF D4$="150%" THEN  LET D3=D1*G1/Y2*.015: GOTO 11050
11040 PRINT : PRINT "ENTER PROPER DEPRECIATI0N METHOD": LET Y=10: GOTO 10540
11050 IF D3$="DDB" THEN  LET D3=D3+D2/Y3/50: GOTO 11100
11060 IF D3$="SL" THEN  LET D3=D3+D2*G1/Y3/100: GOTO 11100
11070 IF D3$="125%" THEN  LET D3=D3+D2*G1/Y3*.0125: GOTO 11100
11080 IF D3$="150%" THEN  LET D3=D3+D2*G1/Y3*.015: GOTO 11100
11090 PRINT : PRINT "NEED METHOD FOR PERSONAL PROPERTY DEPRECIATI0N"
11091 LET Y=11: GOTO 10580
11100 LET T3=R2-D3
11110 LET P7=G1/U1
11120 LET P8=G1/S8
11130 LET C5=O2/G1*100
11140 LET M6=G1/(G2-V2)
12000 REM .
12010 PRINT "&K";
12020 PRINT "COMPUTED GROSS     ";: PRINT %$C13F2;G2;
12030 PRINT TAB(33);"MTG PMT YR1  #1         #2"
12040 PRINT "VAC ALLOWANCE ";%2I;V1;" % ";
12041 PRINT %$C13F2;V2;
12050 PRINT TAB(33);"PRINCIPAL  ";%$9F2;P5(1);" ";
12051 PRINT %$9F2;P5(2)
12060 PRINT "EXP. RATIO ";: PRINT %5F2;E2;: PRINT " %";: PRINT " ";
12061 PRINT %$C13F2;E3;
12070 PRINT TAB(33);"INTEREST   ";%$C9F2;I4(1);: PRINT " ";
12071 PRINT %$C9F2;I4(2)
12080 PRINT "NET OPER INC.      ";
12081 PRINT %$C13F2;O2;: PRINT TAB(33);"TOTAL      ";
12082 PRINT %$C9F2;M1;" ";%$C9F2;M2
12090 FOR X=1 TO 63: PRINT "+";: NEXT X
12100 REM .   FOR Y=0TO11:SET(64,Y):NEXTY
12110 PRINT "CASH FLOW           ";
12111 PRINT %11F2;C3;
12112 PRINT " ";: PRINT TAB(33);"PURCH PRICE        ";
12113 PRINT %11F2;G1
12120 PRINT "PRIN. PAYMENT       ";: PRINT %11F2;P9;
12130 PRINT TAB(33);"MORTGAGE TOTAL     ";: PRINT %11F2;A1
12140 PRINT "EQU RTN =";%6F2;R1;" %   ";%11F2;R2;
12150 PRINT TAB(33);"EQUITY             ";: PRINT %11F2;E1;
12160 PRINT "DEPRECIATI0N        ";: PRINT %11F2;D3;
12170 PRINT TAB(33);"RTN ON CAP RATE         ";: PRINT %5F2;C5;: PRINT "%"
12180 PRINT "TAXABLE INCOME      ";: PRINT %11F2;T3;
12190 PRINT TAB(33);"MULTIPLIER (X EARNINGS)  ";%5F2;M6
12200 FOR X=1 TO 63: PRINT "+";: NEXT X: REM .  FOR Y=15TO29:SET(64,Y):NEXTY
12210 PRINT "PRICE PER UNIT = ";: PRINT %$C13F2;P7;
12220 PRINT TAB(33);"PRICE / SQ FT =   ";%$C12F2;P8
12230 FOR X=1 TO 63: PRINT "+";: NEXT X
12240 PRINT "DO YOU WISH TO: 1 - SHOW SUMMARY  2 - CHANGE A VALUE  3 - RERUN ";
12250 PRINT "THE PROGRAM  4 - RETURN TO MENU"
12260 INPUT "            ENTER THE NUMBER OF YOUR CHOICE: ",F
12270 IF F<>ABS(INT(F)) OR F>4 THEN  GOTO 12260
12280 ON F GOTO 12300,12400,10000,100
12300 PRINT "&K";: PRINT "PRICE";TAB(33);%$C13F2;G1
12310 PRINT "GROSS INCOME";TAB(33);%$C13F2;G2
12320 PRINT
12321 PRINT "DEPRECIATI0N";TAB(20);"% ALLOC.";TAB(30);"YEARS";TAB(40);"TYPE"
12330 PRINT "BUILDING";TAB(20);D1;TAB(30);Y2;TAB(40);D4$
12340 PRINT "PERSONAL PROP.";TAB(20);D2;TAB(30);Y3;TAB(40);D3$
12345 IF M3=0 THEN  PRINT : PRINT "THERE ARE NO MORTGAGES": GOTO 12360
12350 PRINT
12351 FOR X1=1 TO M3
12352   PRINT "MTG. #";X1;" IS :";%$C13F2;A1(X1);
12353   PRINT " AT ";R3(X1);"% ";
12354   IF T2(X1)=1000 THEN  PRINT "FIRST YEAR INTEREST ONLY": GOTO 12357
12355   PRINT "OVER";T2(X1);" PERIODS."
12357 NEXT X1
12360 PRINT : PRINT "THE BUILDING HAS";U1;" UNITS AND";S8;" SQUARE FEET."
12370 PRINT : PRINT "DO YOU WISH TO  1 - DISPLAY FIRST YEAR  2 - CHANGE"
12380 PRINT "A VALUE  3 - RERUN PROGRAM  4 - RETURN TO MENU ";
12395 INPUT X: LET X=ABS(INT(X)): ON X GOTO 12000,12400,10000,100
12397 GOTO 12370
12400 PRINT "&K"
12410 PRINT : PRINT "DO YOU WISH TO CHANGE: "
12420 PRINT "    1 - COMPUTED GROSS INCOME"
12430 PRINT "    2 - VACANCY ALLOWANCE"
12440 PRINT "    3 - EXPENSE RATIO "
12450 PRINT "    4 - PURCHASE PRICE "
12460 PRINT "    5 - MORTGAGE INFORMATI0N"
12470 PRINT "    6 - DEPRECIATI0N INFORMATI0N"
12480 PRINT : PRINT "ENTER THE NUMBER OF YOUR CHOICE ";: INPUT X
12490 IF X<>ABS(INT(X)) OR F>6 THEN  GOTO 12480
12500 ON X GOTO 10140,10110,10150,10100,10160,10510
12510 GOTO 12480
12520 END
13000 PRINT "&K": PRINT "** ERROR    -  ",ERR(0)
13010 PRINT "THIS USUALLY MEANS THAT A VALUE WAS NOT ENTERED PROPERLY."
13020 PRINT "IT MIGHT ALSO MEAN THAT THE ERROR WAS COMPUTED."
13060 INPUT "PRESS ENTER TO RETURN TO THE MENU.",A$: GOTO 100
13070 END