100 REM ...FURS.ECB ..VERSION: 07/30/77  D.R.  MECC : SHARE
  110 REM ...AUTHOR: MARGE KOSEL/MECC HIBBING,MN
  120 REM ...CORRECTED AND REFORMATTED BY STEVE G. WOODWARD
  130 PRINT "&K&J": REM .... CDC CYBER 70/73-26     BASIC 3.1
  135 DIM B$(28),F(4): REM ...Revised 03-10-81  R.E.H.
  140 PRINT
  150 PRINT TAB(15);"===  F U R S ===": PRINT : PRINT
  160 PRINT TAB(13);"( Fur trading game )": PRINT
  170 PRINT "DO YOU WANT INSTRUCTIONS ---=>";
  180 INPUT (1,0)B$: LET B$=B$+"N": PRINT
  190 IF B$(1,1)="N" THEN 360
  195 IF B$(1,1)="n" THEN 360
  200 IF B$(1,1)="Y" THEN 230
  205 IF B$(1,1)="y" THEN 230
  210 PRINT "PLEASE ANSWER Y or N ---=>";
  220 GOTO 180
  230 PRINT "&K";TAB(15);"+*+  F U R S  +*+&J"
  235 PRINT "YOU ARE THE LEADER OF A FRENCH FUR TRADING EXPEDITION IN"
  240 PRINT "1776 LEAVING FOR LAKE ONTARIO AREA TO SELL FURS AND GET"
  250 PRINT "SUPPLIES FOR THE NEXT YEAR. YOU HAVE A CHOICE OF THE THREE"
  260 PRINT "FORTS AT WHICH YOU MAY TRADE.  THE COST OF SUPPLIES"
  270 PRINT "AND THE AMOUNT YOU RECEIVE FOR YOUR FURS WILL DEPEND ON THE "
  280 PRINT "FORT YOU CHOOSE.  "
  290 PRINT "FORT 1 - IS FORT HOCHELAGA (MONTREAL) AND IS UNDER THE"
  300 PRINT "         PROTECTION OF THE FRENCH ARMY"
  310 PRINT "FORT 2 - IS FORT STADACONA (QUEBEC) AND IS UNDER THE PROTECTION"
  320 PRINT "         OF THE FRENCH ARMY. HOWEVER YOU MUST MAKE A PORTAGE"
  330 PRINT "         AND CROSS THE LACHINE RAPIDS."
  340 PRINT "FORT 3 - IS FORT NEW YORK AND IS UNDER DUTCH CONTROL.  YOU"
  350 PRINT "         MUST CROSS THROUGH IROQUIS LAND."
  355 INPUT (1,0)"<*> Type any letter to see more ---=>",I$
  360 LET I=600
  370 PRINT
  380 PRINT "YOU HAVE ";%$C8F2;I;" in SAVINGS"
  390 PRINT "AND 190 FURS TO START YOU EXPEDITION"
  400 PRINT
  410 PRINT "YOUR  190 FURS ARE DISTRIBUTED AMONG THE FOLLOWING "
  420 PRINT "KINDS OF PELTS:   MINK, BEAVER, ERMINE, AND FOX"
  430 GOSUB 1700
  440 LET B$=" MINK   BEAVER ERMINE FOX   "
  450 PRINT
  460 FOR J=1 TO 4: LET F(J)=0: NEXT J
  480 FOR J=1 TO 4
  490   PRINT "How many";B$(J*7-6,J*7);" pelts do you have";
  500   INPUT " ---=>",F(J)
  510   LET F=F(1)+F(2)+F(3)+F(4)
  520   IF F=190 THEN  EXIT 590
  525   IF F<190 THEN 545
  530   PRINT "YOU MAY NOT HAVE THAT MANY FURS."
  535   PRINT "       DO NOT TRY TO CHEAT.  I can add."
  540   PRINT "  YOU MUST START AGAIN.": EXIT 450
  545 NEXT J
  590 PRINT
  600 PRINT "AT WHICH FORT DO YOU WISH TO SELL YOUR FURS?"
  605 PRINT "Fort 1 - is Fort HOCHELAGA (Montreal)"
  606 PRINT "Fort 2 - is Fort STADACONA (Quebec)"
  607 PRINT "Fort 3 - is Fort NEW YORK"
  610 PRINT "ANSWER  1, 2, OR 3 ---=>";
  620 INPUT (1,0)B
  630 PRINT
  640 LET K(B)=1+K(B)
  650 IF B=1 THEN 690
  660 IF B=2 THEN 750
  670 IF B=3 THEN 810
  680 GOTO 610
  690 IF K(B)>1 THEN 940
  700 PRINT "YOU HAVE CHOSEN THE EASIEST ROUTE.  HOWEVER THE FORT IS "
  710 PRINT "FAR FROM ANY SEAPORT.  THE VALUE YOU RECEIVE FOR YOUR"
  720 PRINT "FURS WILL BE LOW AND THE COST OF SUPPLIES WLL BE HIGHER"
  730 PRINT "THAN AT FORTS STADACONA AND NEW YORK"
  740 GOTO 860
  750 IF K(B)>1 THEN 940
  760 PRINT "YOU HAVE CHOSEN A HARD ROUTE. IT IS, IN COMPARISON,"
  770 PRINT "HARDER THAN THE ROUTE TO HOCHELAGA BUT EASIER THEN "
  780 PRINT "THE ROUTE TO NEW YORK.  YOU WILL RECEIVE AVERAGE VALUE FOR"
  790 PRINT "YOUR FURS AND THE COST OF SUPPLIES WILL BE AVERAGE."
  800 GOTO 940
  810 IF K(B)>1 THEN 1260
  820 PRINT "YOU HAVE CHOSEN THE MOST DIFFICULT ROUTE. AT FORT NEW YORK"
  830 PRINT "YOU WILL RECEIVE THE HIGHEST VALUE FOR YOUR FURS.  THE COST OF"
  840 PRINT "YOUR SUPPLIES WILL BE LOWER THAN ALL THE OTHER FORTS."
  850 GOTO 1260
  860 LET I=I-160
  870 PRINT
  880 LET M1=INT((.2*RND(0)+.7)*100+.5)/100
  890 LET E1=INT((.2*RND(0)+.65)*100+.5)/100
  900 LET B1=INT((.2*RND(0)+.75)*100+.5)/100
  910 LET D1=INT((.2*RND(0)+.80)*100+.5)/100
  920 PRINT "SUPPLIES AT FORT HOCHELAGA COST $150.00"
  930 GOTO 1550
  940 LET I=I-140
  950 PRINT
  960 LET M1=INT((.3*RND(0)+.85)*100+.5)/100
  970 LET E1=INT((.15*RND(0)+.80)*100+.5)/100
  980 LET B1=INT((.2*RND(0)+.90)*100+.5)/100
  990 LET D1=INT((.2*RND(0)+.85)*100+.5)/100
 1000 LET P=INT(10*RND(0))+1
 1010 IF P<=2 THEN 1050
 1020 IF P<=6 THEN 1110
 1030 IF P<=8 THEN 1130
 1040 IF P<=10 THEN 1180
 1050 LET F(2)=0
 1060 PRINT "YOUR BEAVER WERE TOO HEAVY TO CARRY ACROSS THE PORTAGE."
 1070 PRINT "YOU HAD TO LEAVE THE PELTS BUT FOUND THEM STOLEN WHEN YOU"
 1080 PRINT "RETURNED."
 1090 GOSUB 1230
 1100 GOTO 1580
 1110 PRINT "YOU ARRIVED SAFELY AT FORT STADACONA"
 1120 GOTO 1210
 1130 GOSUB 1700
 1140 PRINT "YOUR CANOE UPSET IN THE LACHINE RAPIDS."
 1150 PRINT "You lost all your FURS."
 1160 GOSUB 1230
 1170 GOTO 1610
 1180 LET F(4)=0
 1190 PRINT "YOUR FOX PELTS WERE NOT CURED PROPERLY."
 1200 PRINT "NO ONE WILL BUY THEM. "
 1210 GOSUB 1230
 1220 GOTO 1550
 1230 PRINT "SUPPLIES AT FORT STADACONA COST $125.00"
 1240 PRINT "YOUR TRAVEL EXPENSES TO STADACONA WERE $15.00"
 1250 RETURN
 1260 LET I=I-105
 1270 PRINT
 1280 LET M1=INT((.15*RND(0)+1.05)*100+.5)/100
 1290 LET E1=INT((.15*RND(0)+.95)*100+.5)/100
 1300 LET B1=INT((.25*RND(0)+1.00)*100+.5)/100
 1310 LET D1=INT((.25*RND(0)+1.10)*100+.5)/100
 1320 LET P=INT(10*RND(0))+1
 1330 IF P<=2 THEN 1360
 1340 IF P<=8 THEN 1420
 1350 IF P<=10 THEN 1470
 1360 PRINT "YOU WERE ATTACKED BY A PARTY OF IROQUIS."
 1370 PRINT "ALL PEOPLE IN YOUR TRADING PARTY WERE"
 1380 PRINT "KILLED.  THIS ENDS THE GAME."
 1385 GOTO 1800
 1390 PRINT "YOU WERE LUCKY.  YOU ARRIVED SAFELY."
 1400 PRINT "AT FORT YORK."
 1410 GOTO 1510
 1420 GOSUB 1700
 1430 PRINT "YOU NARROWLY ESCAPED AN IROQUIS RAIDING PARTY."
 1440 PRINT "HOWEVER, YOU HAD TO LEAVE ALL YOUR FURS BEHIND."
 1450 GOSUB 1700
 1460 GOTO 1560
 1470 LET B1=B1/2
 1480 LET M1=M1/2
 1490 PRINT "YOUR MINK AND BEAVER WERE DAMAGED ON YOUR TRIP."
 1500 PRINT "YOU RECEIVE ONLY HALF THE CURRECT PRICE FOR THESE FURS."
 1510 GOSUB 1530
 1520 GOTO 1550
 1530 PRINT "SUPPLIES AT NEW YORK COST $88.00"
 1540 RETURN
 1550 PRINT
 1560 IF F(1)<1 THEN 1580
 1565 PRINT "Your";%4I;F(1);B$(1,7);" sold for";
 1570 PRINT %$7F2;M1;" per pelt for a total of ";M1*F(1)
 1580 IF F(2)<1 THEN 1590
 1582 PRINT "Your";%4I;F(2);B$(8,14);" sold for";
 1585 PRINT %$7F2;B1;" per pelt for a total of ";B1*F(2)
 1590 IF F(3)<1 THEN 1600
 1592 PRINT "Your";%4I;F(3);B$(15,21);" sold for";
 1595 PRINT %$7F2;E1;" per pelt for a total of ";E1*F(3)
 1600 IF F(4)<1 THEN 1610
 1602 PRINT "Your";%4I;F(4);B$(22,28);" sold for";
 1605 PRINT %$7F2;D1;" per pelt for a total of ";D1*F(4)
 1610 LET I=D1*F(4)+B1*F(2)+M1*F(1)+E1*F(3)+I
 1615 IF I=0 THEN  PRINT TAB(9);"+*+ You had no FURS to sell +*+"
 1620 PRINT
 1630 PRINT "You now have";%$C9F2;I;
 1635 PRINT " including your previous savings."
 1640 PRINT "DO YOU WISH TO TRADE FURS AGAIN ---=>";
 1650 INPUT (1,0)I$: LET I$=I$+"Y"
 1660 IF I$(1,1)="Y" THEN 380
 1670 IF I$(1,1)="N" THEN 1760
 1680 PRINT "PLEASE ANSWER  Y  or N ---=>";
 1690 GOTO 1650
 1700 FOR J=1 TO 4
 1710   LET F(J)=0
 1720 NEXT J
 1730 PRINT
 1740 RETURN
 1760 PRINT
 1770 PRINT "YOU ENDED YOU FUR TRADING with ";%$C9F2;I
 1790 PRINT "HOPE YOU ENJOYED YOURSELF."
 1800 END