10 REM GRAF.ECB
  100 REM ===== ORIGINAL VERSION MYSTERIOUSLY APPEARED
  110 REM ===== AT THE U OF A IN LATE 1972 AND HAS
  120 REM ===== REGRETABLY BEEN LOST. EFFORTS CONTINUE
  130 REM ===== BY THE DPP AT UOA TO RECREATE THAT VERSION.
  140 REM ===== THIS VERSION WAS CONVERTED BY MIKE VAN PELT
  150 REM ===== AND IMPLEMENTED FOR YOUR ENJOYMENT COURTESY
  160 REM ===== OF THE DEMONSTRATION PROGRAM PEOPLE AT THE
  170 REM ===== UNIVERSITY OF ALABAMA.      ROLL TIDE!
  180 REM ******* LAST CORRECTED 06/25/77   R.E.H.
  190 DIM K$(20),N$(20)
  200 LET A$=" "
  210 PRINT TAB(15);"#############################"
  220 PRINT TAB(15);"###                       ###"
  230 PRINT TAB(15);"###  G R A F  -  S P E E  ###"
  240 PRINT TAB(15);"###                       ###"
  250 PRINT TAB(15);"#############################"
  260 PRINT A$,A$,A$,A$,A$,A$
  270 PRINT "TYPE IN YOUR FIRST NAME ";
  280 INPUT N$
  290 PRINT
  300 PRINT " DO YOU NEED INSTRUCTIONS  ? ";
  310 INPUT K$
  320 IF K$="NO" THEN 630
  325 IF K$="N" THEN 630
  330 PRINT
  340 PRINT " YOU ARE DER GUNNERY OFFICER ON DER GRAF SPEE"
  350 PRINT " DU BIST IN ENEMMY VATERS,  PUT DER ENEMMY"
  360 PRINT " KANNOT FIRE AT YOU... DU VILL BE INFORMED"
  370 PRINT " OF DER ENEMMYEN APPROXIMATE POZITION"
  380 PRINT "(HISS X UND Y CO-ORDINATES) AT DER BEGINNINK"
  390 PRINT "OF DER GAME... DER TARGET AREA IS 10 UNITS"
  400 PRINT "BY 10 UNITS.  DER EFFEKTIFF AREA OF A HIT"
  410 PRINT "IS ONE SQUARE UNIT.  YOU ARE AT THE LOWER"
  420 PRINT
  430 PRINT "   TYPE IN ANY LETTER WHEN READY----> ";
  440 INPUT I$
  450 PRINT
  460 PRINT " LEFT-HAND KORNER AUF DER TARGET AREA."
  470 PRINT " TO DIRECT FIRE, CHOOZE GUNN ELEVATION FUR"
  480 PRINT " RANGE AND AZIMUTH(DEGREES FROM TRUE NORTH)"
  490 PRINT " FOR DIREKTION, *NOTE* TRUE NORTH IS '0' "
  500 PRINT "    DEGREES,  AND DUE EAST IS 90 DEGREES."
  510 PRINT
  520 PRINT "   TYPE IN ANY LETTER WHEN READY----> ";
  530 INPUT I$
  540 PRINT
  550 PRINT "************* W A R N I N G **************"
  560 PRINT
  570 PRINT " IF YOU DO NOT SINK DER ENEMMY SCHIPP,...."
  580 PRINT " .. YOU VILL BE KAPTURED,  BECAUSE VILE YOU"
  590 PRINT " VER SCHKREWING AROUND, HE RADIOED FUR HELP"
  600 PRINT
  610 LET C=0
  620 LET M=0
  630 REM ==== RANDOMIZE
  640 LET X=INT(1+(10*RND(0)))
  650 LET Y=INT(1+(10*RND(0)))
  660 LET A=X+INT(1.5+RND(0))
  670 LET B=Y+INT(1.5+RND(0))
  680 PRINT "DER ENEMMY SCHIPP IST IN DER AREA OF:"
  690 PRINT "X CO-ORDINATE BETVEEN ";A-2;" AND;";A
  700 PRINT "Y CO-ORDINATE BETVEEN ";B-1;" AND;";B+1
  710 PRINT "INPUT DER ELEVATION OF YOUR GUN,"
  720 PRINT ".....UND ALSO DER AZIMUTH ";
  730 INPUT R,P
  740 LET C=C+1
  750 IF SIN(R*3.14159/180)<0 THEN 810
  760 IF COS(R*3.14159/180)<=0 THEN 790
  770 IF SIN(P*3.14159/180)<0 THEN 840
  775 IF COS(P*3.14159/180)<0 THEN 840
  780 GOTO 930
  790 IF COS(P*3.14159/180)>0 THEN 840
  795 IF SIN(P*3.14159/180)>0 THEN 840
  800 GOTO 930
  810 PRINT "DAT DAS NOT KOMPUTEN!!!!!"
  820 PRINT "TRY AGAIN,YOU ROOD!"
  830 GOTO 710
  840 FOR I=1 TO 5
  850   PRINT
  860 NEXT I
  870 PRINT "DER KLUTZ FIRED THE WRONG WAY!!"
  880 PRINT "INSHTANT KOURT MARTIAL UND REMOVAL"
  885 PRINT "    TO DER RUSSIAN FRONT"
  890 LET M=M+1
  900 PRINT "YOU NOW HAVE ";10-M;" SHOTS."
  910 IF C>10 THEN 1670
  915 GOTO 710
  920 IF C<11 THEN 710
  930 IF R=90 THEN 950
  935 GOTO 1020
  940 IF R=90 THEN 950 ELSE 1020
  950 FOR I=1 TO 5
  960   PRINT
  970 NEXT I
  980 PRINT "DER MORON HAS FIRED SCHTRAIGHT UP!!!!!!!!"
  990 PRINT "       <<<<<<<BOOM>>>>>>>
 1000 PRINT "GAME OVER FOR ALL CONCERNED.   R.I.P."
 1010 GOTO 1670
 1020 IF R=0 THEN 1040
 1030 GOTO 1130
 1040 FOR I=1 TO 5
 1050   PRINT
 1060 NEXT I
 1070 PRINT " IST DU SOME KIND OF WISSENHEIMER,......"
 1080 PRINT " AUFTEMPTING TO KILL FLYING FISCH ??"
 1090 LET M=M+1
 1100 PRINT "YOU NOW HAVE ";10-M;" SHOTS."
 1110 IF C>10 THEN 1670
 1120 GOTO 710
 1130 LET P=P-180*(INT(P/180))
 1140 LET R=R-90*(INT(R/90))
 1150 IF P>0 THEN 1160
 1155 LET P=P+180
 1160 IF P>0 THEN 1170
 1165 LET P=P+180
 1170 IF R>0 THEN 1180
 1175 LET R=R+90
 1180 LET P=P*3.14159/180
 1190 LET R=R*3.14159/180
 1200 LET S=INT(SIN(P)*ABS(SIN(2*R)*15))
 1210 LET T=INT(COS(P)*ABS(SIN(2*R)*15))
 1220 IF S=X THEN 1260
 1230 REM ====== HE MISSED !!
 1240 LET M=M+1
 1250 GOTO 1280
 1260 IF T=Y THEN 1320
 1270 LET M=M+1
 1280 PRINT "YOU MISSED, ";N$;" THAT LEAVES YOU ";10-M;" SHOTS"
 1290 PRINT "YOU HIT THE FOLLOWING CO-ORDINATES:  ";S;T
 1300 IF C=10 THEN 1630
 1310 GOTO 710
 1320 LET C=INT(C)
 1325 IF C=10 THEN 1630
 1330 ON C GOTO 1340,1370,1420,1450,1470,1490,1510,1530,1590
 1340 PRINT "YOU ARE DEADLY,";N$;" I AM YOUR SERVANT, OH ";
 1350 PRINT " MIGHTY ONE!!"
 1360 GOTO 1670
 1370 PRINT " CONGRATULATIONS UPON KOMMAND OF YOUR NEW"
 1380 PRINT " AIRKRAFT KARRIER....KOMMODORE ";N$
 1390 PRINT
 1400 PRINT "KARRY ON."
 1410 GOTO 1670
 1420 PRINT " NOT BAD FOR A LOWLY HUMAN!  US KOMPUTERS"
 1430 PRINT " MAY BE ABLE TO TRAIN YOU YET, ";N$
 1440 GOTO 167
 1450 PRINT "YOU'VE RETAINED YOUR RANKEN AS DER LEUTNANT, ";N$
 1460 GOTO 1670
 1470 PRINT "YOUR AIM VAS BAS ENOUGH TO"
 1475 PRINT "    DEMOTE YOU TO KOOK'S MATE, ";N$
 1480 GOTO 1670
 1490 PRINT "VANT TO TRY YOUR LUCK AGAIN,";N$;" YOU ROOD?"
 1500 GOTO 1670
 1510 PRINT N$;", YOU KOULDN'T HIT DER GERTHINKENMACHINE"
 1515 PRINT TAB(15);".....AT 10 METERS.!"
 1520 GOTO 1670
 1530 PRINT " KAPTURED"
 1540 PRINT "BY DER ENEMMY"
 1550 PRINT
 1560 PRINT
 1570 PRINT "VOULDN'T YOU RATHER PLAY OLD MAIDCHEN"
 1580 GOTO 1670
 1590 PRINT "YOU ARE NOW TAKING OUT DER GARBAGE"
 1600 PRINT "........IN DER ENEMMY PRISON CAMP, ";N$
 1610 PRINT "SERVES YOU RIGHT"
 1620 GOTO 1670
 1630 PRINT " VELL, ";N$;", YOU REALLY SURPRISED ME,"
 1635 PRINT " YOU USED UP YOUR AMMUNITION......."
 1640 PRINT " VITHOUT HITTING ANYTHING BUT SEA URCHINS.";
 1650 PRINT " YOU'RE LUCKY"
 1660 PRINT " DOT YOU ONLY GOT KAPTURED"
 1665 PRINT " ..... INSHTEAD OF BEING GESUNKEN"
 1670 REM ===== THE END    *** GAME OVER ***
 1680 PRINT "DER ENEMMY WAS AT THE X CO-ORDINATE OF ";X
 1690 PRINT "AND Y CO-ORDINAT OF ";Y
 1700 PRINT " DO YOU WANT TO PLAY AGAIN ? ---";N$;
 1710 INPUT I$
 1720 IF I$="Y" THEN 610
 1725 IF I$="YES" THEN 610
 1730 REM ===== VARIBLES USED: A, B, C, I, M, P, R, S
 1740 REM ===== VARIBLES USED: T, X, Y,  A$  I$  K$  N$
 1750 END