10 REM HAM.ECB
  100 PRINT "&K": REM ================ LAST MOD.  8/8/77  R.E.H.
  110 PRINT TAB(10);"HHHHHHHHHHHHHHHHHHHHHHHHHHH"
  120 PRINT TAB(10);"HHH                     HHH"
  130 PRINT TAB(10);"HHH   H A M U R A B I   HHH"
  140 PRINT TAB(10);"HHH                     HHH"
  150 PRINT TAB(10);"HHHHHHHHHHHHHHHHHHHHHHHHHHH"
  160 PRINT
  170 REM .... RANDOMIZE
  180 LET U=RND(0)
  190 LET U=INT(.3*P+RND(0)*.4*P)
  200 LET P1=0
  210 LET I1=0
  220 LET P=INT(50+100*RND(0))
  230 PRINT "HAMURABI SAYS: Welcome, New Village Manager."
  240 PRINT "Your population is";P;" people."
  250 LET A=INT(950+RND(0)*100)
  260 PRINT "You own";A;" acres."
  270 LET S=INT(2500+1E3*RND(0))
  280 PRINT "You have";S;" bushels of grain in store.": PRINT
  290 PRINT "HAMURABI SAYS:"
  300 LET P1=P1+1
  310 LET Y=INT(20+8*RND(0))
  320 PRINT "Land is trading at";Y;" bushels per acre."
  330 PRINT "How many acres of land do you wish to buy ---=>";
  340 INPUT Q
  350 IF Q<0 THEN 1260
  360 IF Q=0 THEN 430
  370 IF Y*Q-S<=0 THEN 400
  380 GOSUB 1200
  390 GOTO 330
  400 LET S=S-Y*Q
  410 LET A=A+Q
  420 GOTO 520
  430 PRINT "to sell ---=>";
  440 INPUT Q
  450 IF Q<0 THEN 1260
  460 IF Q=0 THEN 530
  470 IF Q<=A THEN 500
  480 GOSUB 1220
  490 GOTO 430
  500 LET A=A-Q
  510 LET S=S+Y*Q
  520 PRINT " You now have";A;" acres and";S;" bushels.": PRINT
  530 PRINT " Bushels to use as food ---=>";
  540 INPUT F
  550 IF F<=0 THEN 1260 ELSE  PRINT
  560 IF F<=S THEN 580
  570 GOTO 530
  580 LET S=S-F
  590 PRINT "How many acres do you wish to plant ---=>";
  600 INPUT T
  610 IF T<0 THEN 1260
  620 IF T<=A THEN 650
  630 GOSUB 1220
  640 GOTO 590
  650 IF T/2<=S THEN 680
  660 GOSUB 1200
  670 GOTO 590
  680 IF T-10*P-1<=0 THEN 720
  690 GOSUB 1240
  700 GOTO 590
  710 LET S=S-INT(T/2)
  720 LET H=INT(8*RND(0)+1.5)
  730 LET D=0
  740 LET I1=I1+1
  750 PRINT "&K": PRINT "HAMURABI SAYS: At end of year";I1
  760 IF INT(F/20)>=P THEN 800
  770 LET D=ABS(INT(F/20)-P)
  780 PRINT D;" STARVED"
  790 REM
  800 LET R=INT(.6*S*RND(0))
  810 LET G=INT(P*10-T)*50
  820 LET R=R-G
  830 IF R<0 THEN 850
  840 GOTO 860
  850 LET R=0
  860 IF D=P THEN 1260
  870 LET G1=RND(0)*G/1000
  880 LET G2=RND(0)*S/P/200
  890 LET I=INT(G1+G2+RND(0)*A/P/5)
  900 IF D>0 THEN 920
  910 GOTO 930
  920 LET I=0
  930 LET C=INT(.01*P+RND(0)*P/25)
  940 LET U=INT(.02*P+RND(0)*P/17)
  950 LET X=RND(0)
  960 IF X<.92 THEN 1040
  970 IF P1<8 THEN 1040
  980 LET U=INT(.3*P+RND(0)*.4*P)
  990 PRINT "*****PLAGUE*****"
 1000 LET I=0
 1010 LET P1=0
 1020 LET B=INT(B*.4)
 1030 GOTO 1050
 1040 LET B=INT(.04*P+RND(0)*P/20)
 1050 LET P=INT(P+I+B-D-C-U)
 1060 LET S=S-R+INT(H*T)
 1070 IF P<0 THEN 1090
 1080 GOTO 1100
 1090 LET P=0
 1100 PRINT " There were";C;" ACCIDENTAL deaths and";U
 1110 PRINT " deaths from DISEASE, ";B;" BIRTHS and";I;" moved in"
 1120 PRINT " The population is now";P: PRINT
 1130 IF P=0 THEN 1260
 1140 IF T=0 THEN 1170
 1150 PRINT "We harvested";H;" bushels per acre."
 1160 IF R=0 THEN 1180
 1170 PRINT "RATS ate";R;" bushels.": PRINT
 1180 PRINT "You now have";A;" acres and";S;" bushels in store."
 1190 GOTO 290
 1200 PRINT "But you have only";S;" bushels in store.": PRINT
 1210 RETURN
 1220 PRINT "But you have ONLY";A;" acres.": PRINT
 1230 RETURN
 1240 PRINT "But you have ONLY";P;" people.": PRINT
 1250 RETURN
 1260 PRINT : PRINT "HAMURABI SAYS: *****PURGE*****"
 1270 PRINT "YOU HAVE BEEN REPLACED BY A MILITARY JUNTA"
 1280 PRINT "GOOD BYE"
 1290 END