10 REM ... KING.ECB ...FROM MERITSS : SCS0001  12-15-77
   20 REM .....EXPERIMENTAL-TO BE ALTERED AND SIMPLIFIED
  100 PRINT "&K&J&J"
  110 PRINT TAB(15);".:':.   K I N G   .:':.&J&J"
  120 READ P,S,H,E,Y,A,I
  130 DATA 95,2800,3000,200,3,1000,5
  140 LET D=0
  150 PRINT D;" DIED"
  160 PRINT I;" PEOPLE CAME."
  170 LET P=P+I
  180 PRINT "THE POPULATION IS ";P
  190 PRINT
  200 PRINT "THE CITY OWNS ";A;" ACRES."
  210 PRINT
  230 IF H<1 THEN 1140
  240 PRINT "WE HARVESTED ";Y;" BUSHELS PER ACRE."
  250 LET C=1
  260 PRINT "THE HARVEST WAS ";H;" BUSHELS."
  270 PRINT E;" BUSHELS WERE DESTROYED. YOU HAVE"
  280 PRINT S;" BUSHELS IN STORE."
  285 PRINT
  290 GOSUB 1162
  300 LET Y=C+17
  310 PRINT "THIS YEAR LAND IS ";Y;" BUSHELS PER ACRE."
  315 PRINT
  320 LET C=1
  330 PRINT "ACRES TO BUY?"
  340 INPUT Q
  345 PRINT
  350 IF Q<0 THEN 1170
  360 IF Q=0 THEN 490
  370 IF Y*Q<S THEN 630
  380 IF Y*Q=S THEN 430
  390 IF C<0 THEN 1170
  400 LET C=C-1
  410 PRINT "YOU HAVE ONLY ";S;" BUSHELS IN STORE."
  415 PRINT
  420 GOTO 330
  430 LET A=A+Q
  440 LET S=S-Y*Q
  450 LET C=0
  460 PRINT "NO GRAIN LEFT."
  465 PRINT
  470 LET D=0
  480 GOTO 850
  490 PRINT "ACRES TO SELL?"
  500 INPUT Q
  505 PRINT
  510 IF Q<0 THEN 1170
  520 IF Q=0 THEN 570
  530 LET Q=-Q
  540 IF A+Q<0 THEN 590
  550 LET A=A+Q
  560 LET S=S-Y*Q
  570 LET C=0
  580 GOTO 660
  590 IF C<0 THEN 1170
  600 LET C=C-1
  610 PRINT "YOU HAVE ONLY ";A;" ACRES."
  615 PRINT
  620 GOTO 490
  630 LET A=A+Q
  640 LET S=S-Y*Q
  650 LET C=0
  660 PRINT "HOW MANY BUSHELS AS FOOD?"
  670 INPUT Q
  675 PRINT
  680 IF Q<0 THEN 1170
  690 IF Q<S THEN 730
  700 IF Q=S THEN 1090
  710 PRINT "YOU HAVE ONLY ";S;" BUSHELS IN STORE."
  715 PRINT
  720 GOTO 660
  730 LET S=S-Q
  740 LET C=1
  750 PRINT "ACRES TO PLANT?"
  760 INPUT D
  765 PRINT
  770 IF D<0 THEN 1170
  780 IF A<D THEN 1010
  790 IF INT(D/2)>=S+1 THEN 1050
  800 IF D<((10*P)+1) THEN 850
  810 IF C<0 THEN 1170
  820 LET C=C-1
  830 PRINT "YOU HAVE ONLY ";P;" PEOPLE."
  835 PRINT
  840 GOTO 750
  850 LET S=S-INT(D/2)
  860 GOSUB 1162
  870 LET Y=C
  880 LET H=D*Y
  890 GOSUB 1162
  900 LET E=0
  910 IF INT(C/2)<C/2 THEN 930
  920 LET E=S/C
  930 LET S=S-E+H
  940 GOSUB 1162
  950 LET I=INT(C*(20*A+S)/P/100+1)
  960 LET C=INT(Q/20)
  970 IF P<C THEN 140
  980 LET D=P-C
  990 LET P=C
 1000 GOTO 150
 1010 IF C<0 THEN 1170
 1020 LET C=C-1
 1030 PRINT "YOU HAVE ONLY ";A;" ACRES."
 1035 PRINT
 1040 GOTO 750
 1050 IF C<0 THEN 1170
 1060 LET C=C-1
 1070 PRINT "YOU HAVE ONLY ";S;" BUSHELS IN STORE."
 1075 PRINT
 1080 GOTO 750
 1090 LET S=S-Q
 1100 LET C=1
 1110 PRINT "NO GRAIN LEFT."
 1115 PRINT
 1120 LET D=0
 1130 GOTO 850
 1140 PRINT "0 BUSHELS WERE DESTROYED. YOU HAVE"
 1150 PRINT S;" BUSHELS IN STORE."
 1155 PRINT
 1160 GOTO 290
 1162 LET X=RND(0)
 1164 IF X<.45 THEN 1162
 1166 IF X>.96 THEN 1162
 1168 LET C=INT(5*ABS(X))+1
 1169 RETURN
 1170 PRINT "I'VE HAD ENOUGH..... I QUIT"
 1190 STOP
 1200 END