10 REM ...NAGS.ECB ..from MERITSS : GAME   12-15-77
  100 PRINT "&K&J&J&J       N A G S&J&J"
  110 DIM D(20),V(20)
  120 DIM T(20),Q(20)
  130 GOTO 150
  140 PRINT "NEW DAY AT THE TRACK"
  150 PRINT "VETERANS TYPE 1, BEGINNERS 2 ---=>";
  160 INPUT K1
  170 LET N=PEEK(52643)+K1
  180 PRINT
  190 FOR K=1 TO ABS(N)
  200   LET X=RND(0)
  210 NEXT K
  215 LET H=12
  217 IF K1=1 OR K1=2 THEN 220 ELSE 150
  220 IF K1=1 THEN 350
  230 PRINT "&KTHERE ARE ";H;" HORSES IN THIS RACE"
  320 LET H=12
  330 DATA 3,4,5,8,9,11,20,30
  340 DATA 3,5,12.5,7.5
  350 LET A=100
  360 PRINT "YOU HAVE $";A;TAB(30);
  370 PRINT "YOU MAY BET ANY PART OF IT"
  380 IF D(1)>0 THEN 530
  390 FOR I=1 TO H
  400   READ D(I)
  410 NEXT I
  430 IF K1=1 THEN 1240
  440 PRINT "HORSE   ODDS ON $2 BET PAYS   WIN    PLACE    SHOW"
  450 FOR I=1 TO H
  460   LET I1=(D(I)+1)*2
  470   LET I2=(D(I)/4+1)*2
  480   LET I3=(D(I)/8+1)*2
  490   PRINT I;TAB(6);%Z9F3;D(I);" to  1";
  495   PRINT TAB(27);%Z8F3;I1;I2;I3
  500 NEXT I
  510 IF D(1)>0 THEN 530
  520 LET Z=0
  530 IF Z>3 THEN 1100
  540 LET Z=Z+1
  550 FOR I=1 TO H
  560   LET T(I)=1/D(I)
  570 NEXT I
  610 PRINT "BETS: HORSE, POSITION,WAGER ---=>";
  620 INPUT W,P,B
  625 IF B=0 THEN 1290
  630 IF W>H THEN 610
  640 IF P>3 THEN 610
  650 IF B<=A THEN 670
  660 LET B=A
  670 IF B<0 THEN 610
  680 PRINT
  690 PRINT "RACE RESULTS"
  695 LET M=0
  700 LET M=M+1: REM ....FOR M=1 TO H
  710 LET S=0
  720 FOR I=1 TO H
  730   LET S=S+T(I)
  740 NEXT I
  750 LET G=0
  760 LET R=RND(0)
  765 LET I=0
  770 LET I=I+1: REM ....FOR I=1 TO H
  780 LET G=G+T(I)/S
  790 IF R<G THEN 820
  800 IF I<H THEN 770: REM .....NEXT I
  810 PRINT "PROGRAM BUG"
  820 IF M>3 THEN 840
  830 PRINT M;"= NO.";I
  840 LET Q(M)=I
  850 LET T(I)=0
  860 IF M<H THEN 700: REM ....NEXT M
  870 FOR I=1 TO P
  880   IF Q(I)=W THEN 980
  890 NEXT I
  900 LET I=0
  910 PRINT "YOU LOST YOUR ";B
  920 LET A=A+I-B
  930 IF A>=2 THEN 960
  940 PRINT "YOU LOST TOO MUCH TO BET AGAIN.  GO GET MORE MONEY."
  950 GOTO 140
  960 PRINT "YOU NOW HAVE ";A
  970 GOTO 1010
  980 LET I9=(P-INT(1/P))+1
  985 LET I=(D(Q(I))/2-I9)*B
  990 PRINT "YOU WIN ";I
 1000 GOTO 920
 1010 LET Q1=INT(RND(0)*10)
 1020 IF Q1<>Q(1) THEN 530
 1030 IF W<>Q1 THEN 530
 1040 FOR J=1 TO 25000
 1050 NEXT J
 1060 PRINT "FLASH???????.....YOUR HORSE IS DISQUALIFIED FOR"
 1070 PRINT "CROWDING"
 1080 LET I=-I+B
 1090 GOTO 910
 1100 FOR I=1 TO H
 1110   LET V(I)=RND(0)
 1120 NEXT I
 1125 FOR I5=1 TO H
 1130   FOR I=1 TO H-1
 1140     FOR J=I TO H-1
 1150       IF V(J)<V(J+1) THEN 1220
 1160       LET T1=V(J)
 1170       LET V(J)=V(J+1)
 1180       LET V(J+1)=T1
 1190       LET T2=D(J)
 1200       LET D(J)=D(J+1)
 1210       LET D(J+1)=T2
 1220     NEXT J
 1230   NEXT I
 1235 NEXT I5
 1240 PRINT "*****NEW ODDS*****"
 1250 FOR I=1 TO H
 1260   PRINT I;TAB(6);%Z9F3;D(I);"to 1"
 1270 NEXT I
 1280 GOTO 520
 1290 PRINT
 1300 PRINT "MERITSS Racetrack thanks you for the money."
 1310 PRINT "Enter 'RUN' to play again."
 1320 END