10 REM ....NIM.ECB ..FROM MERITSS : SCS0001  12-19-77
   20 REM .... THIS PROGRAM DEVELOPED BY CHARLES NISTLER
  100 PRINT "&K&J&J&J"
  110 PRINT TAB(15);"-=<[   N I M   ]>=-&J&J"
  120 PRINT "DO YOU WANT INSTRUCTIONS ( Y OR N ) ---=>";
  130 INPUT C$
  140 IF C$="N" THEN 230
  150 PRINT "**********************INSTRUCTIONS*************************"
  160 PRINT "THIS IS THE GAME NIM.  YOU WILL BE ASKED TO ENTER A"
  170 PRINT "NUMBER BETWEEN 10 AND 50 INCLUSIVE.  THEN YOU MAY TAKE"
  180 PRINT "AWAY AN AMOUNT BETWEEN 1& 5.  THE OBJECT BEING TO FORCE"
  190 PRINT "THE COMPUTER TO TAKE THE LAST '1' AND PREVENT YOURSELF"
  200 PRINT "FROM HAVING TO TAKE THE LAST ONE."
  210 PRINT "***********************************************************"
  220 PRINT
  230 PRINT "DO YOU WANT A GRAPHIC ILLUSTRATION OF THE ";
  240 PRINT "NUMBER OF 1'S LEFT";
  250 INPUT D$
  260 LET T=0
  270 PRINT "ENTER A NUMBER BETWEEN 10 AND 50 AND THEN PUSH(RETURN)."
  280 LET Y=49
  290 INPUT X
  300 IF X<10 THEN 320
  310 IF X<51 THEN 350
  320 PRINT "TRY AGAIN"
  330 INPUT X
  340 GOTO 300
  350 PRINT "HOW MANY DO YOU TAKE";
  360 INPUT A
  370 IF A<=0 THEN 390
  380 IF A<6 THEN 410
  390 PRINT " WATTS AMATTA, CANNA YOU NO A FOLLOW DIRECTIONS?"
  400 GOTO 350
  410 IF A>=X THEN 390
  420 LET X=X-A
  430 IF X<>1 THEN 460
  440 PRINT "CONGRATULATIONS YOU'VE WON"
  450 GOTO 640
  460 PRINT X;" ARE LEFT",
  470 IF X>Y THEN 500
  480 LET Y=Y-6
  490 GOTO 470
  500 LET Z=X-Y
  510 IF Z=6 THEN 680
  520 PRINT " AND THE COMPUTER TAKES ";Z
  530 LET X=X-Z
  540 IF X=1 THEN 630
  550 PRINT "THERE ARE NOW ONLY ";X;" LEFT"
  560 LET T=0
  570 IF D$="N" THEN 620
  580 PRINT "1 ";
  590 LET T=T+1
  600 IF T=X THEN 620
  610 GOTO 580
  620 GOTO 350
  630 PRINT "YOU MUST TAKE THE LAST '1' TO BAD BUT YOU LOST"
  640 PRINT "DO YOU WANT TO PLAY AGAIN ( Y OR N ) ---=>";
  650 INPUT B$
  660 IF B$="Y" THEN 230
  670 GOTO 700
  680 LET Z=Z-3
  690 GOTO 520
  700 PRINT "THANK YOU FOR PLAYING NIM."
  710 END