10 REM ... SLOTS.ECB ......Ralph Hopkins      8-10-80
   20 LET K$="&K": PRINT K$: LET E$=" each."
   30 DIM A(22),B(22),C(22),D(15),E(15),O(9),P(9)
   40 DIM R(45),U(9),W(45),D$(121),M$(33),S$(39),Z$(37)
   50 DIM G(5),H(5),M(5),N(5),Q(5)
   60 REM ...A(20) = Wheel 1   B(20) = Wheel 2   C(20) = Wheel 3
   70 REM ...D(15) = Denomination of the machine
   80 REM ...E(15) = Exchange rate of coins
   90 REM ...O(9) = Expected odds        P(9) = Payoff rate
  100 REM ...W(45) = Count symbol's wins  R(45) = % returned
  110 REM ...U(9) Expected return
  120 REM ...I = Players bet      M = Players money
  130 REM ...Q = Menu pick        M(5) = # of coins won
  140 REM ...P,N(5) = Payoff      T = Players machine type
  150 REM ...Q(5) = # of payoffs  H(5) = # of lever pulls
  160 REM ...G(5) = # coins played   V = count coins won
  170 REM ...W = # of ways 2 win  N = # of coins to play with
  180 REM ...A,B,C = Wheel Symb   X,Y,Z = Wheel position
  190 LET S$=S$+"88-(O)/b\<#>(M)==={7}{*}b/=7/=*/=M/O7/O"
  200 FOR Z=1 TO 33: LET M$=M$+CHR(5): NEXT Z
  210 LET T=1: LET A$="  ": LET C$="1": GOSUB 3120
  220 GOSUB 2450: CURSOR 1,9: PRINT "C O M P U T O R";
  230 CURSOR 3,12: PRINT "S L O T S";
  240 CURSOR 9,35: PRINT "Wecome to Computor Slots.";
  250 CURSOR 13,35: PRINT "Do you want a description";
  260 INPUT (1,0)I$: LET I$=I$+"N"
  270 IF I$(1,1)="N" THEN 760 ELSE  PRINT K$
  280 PRINT "[ DESCRIPTION OF MACHINES ]": PRINT
  290 PRINT "   The machines in this CASINO are known as the"
  300 PRINT "3 reel Programers Bell or the 21 Bell 3 Wheel"
  310 PRINT "or the Alantic City model.  There are models in"
  320 PRINT "single window or triple window.  Single windows"
  330 PRINT "use only 1 coin.  Triple windows take 1 to 5"
  340 PRINT "Coins and win 1 to 5 ways.   Machines come in"
  350 PRINT "penny to dollar denominations."
  360 PRINT "   If you have over $600, you will be shown some"
  370 PRINT "special slot machines that take *GOLD* or SILVER"
  380 PRINT "pieces which are automatically purchased when"
  390 PRINT "that machine is selected.   Of course not every"
  400 PRINT "CASINO has this elite provision.": PRINT
  410 INPUT (1,0)"Enter any letter to see more ---=>",I$
  420 PRINT K$;"     PROGRAMERS BELL machine symbols:": PRINT
  430 PRINT "Cherry = 88-";TAB(20);"Orange = (O)",
  440 PRINT "Bell = /b\": PRINT "Lemon  = <#>";TAB(20);
  450 PRINT "Melon  = (M)","Bar  = ===": PRINT
  460 PRINT "     21 Bell 3 wheel machine symbols:": PRINT
  470 PRINT "Cherry = 88-";TAB(20);"Orange = (O)",
  480 PRINT "Bell = /b\": PRINT "Lemon  = <#>";TAB(20);
  490 PRINT "Melon  = (M)","Bar  = ==="
  500 PRINT "Seven  = {7}";TAB(20);"Plum   = {*}"
  510 PRINT ,"b/=  is a Bell or a Bar"
  520 PRINT ,"*/=  is a Plum or a Bar"
  530 PRINT ,"7/=  is a Seven or a Bar"
  540 PRINT ,"M/O  is a Melon or an Orange"
  550 PRINT ,"7/O  is a Seven or an Orange"
  560 INPUT (1,0)"Enter any letter to see more ---=>",I$
  570 PRINT K$;"     Alantic City machine symbols:": PRINT
  580 PRINT "Cherry = 88-";TAB(20);"Orange = (O)",
  590 PRINT "Bell = /b\": PRINT "Lemon  = <#>";TAB(20);
  600 PRINT "Plum   = {*}","Bar  = ===": PRINT : PRINT
  610 PRINT "All machines have an AUTOMATIC lever pulling"
  620 PRINT "capability that can be turned on or off."
  630 PRINT : PRINT
  640 INPUT (1,0)"Enter any letter to see more ---=>",I$
  650 PRINT K$;"Triple window winning patterns:": PRINT
  660 PRINT " 1 coin   2 coins   3 coins   4 coins   5 coins"
  670 PRINT
  680 PRINT "  X X X    * * *     X X X     * X X    X X *"
  690 PRINT "  * * *    X X X     X X X     X * X    X * X"
  700 PRINT "  X X X    X X X     * * *     X X *    * X X"
  710 PRINT : PRINT
  720 PRINT "One coin always uses the center row for wins."
  730 PRINT "The  * * *  pattern shows how each additional"
  740 PRINT "coin adds to the win possibilities.  You can"
  750 PRINT "get double and even triple wins with 5 coins."
  760 PRINT : REM ...set-up...
  770 INPUT "How much money do you have ---=>",M
  780 IF M<=0 THEN  PRINT "Credit is not allowed here."
  790 IF M<3.51E6 THEN 820 ELSE  PRINT
  800 PRINT "* S O R R Y * ,    No ARABS are allowed here."
  810 GOTO 770
  820 IF M>1E4 THEN  PRINT "It must be nice to be filthy rich!"
  830 RESTORE 840: REM ...D(15) Denominations
  840 DATA .25,.5,1,.1,.05,.01,1,1,2.5,3,5,10,20,50,0
  850 FOR Z=1 TO 15: READ D(Z): NEXT Z
  860 REM ...E(15) Coin exchange rates
  870 DATA .25,.5,1,.1,.05,.01,15,300,175,1500,200,350,650,5E3,0
  880 FOR Z=1 TO 15: READ E(Z): NEXT Z
  890 LET Q=15
  900 PRINT K$: REM ...start play...
  910 LET A=INT(RND(0)*20)+2: LET B=INT(RND(0)*20)+2
  920 LET C=INT(RND(0)*20)+2
  930 LET M=M+E(Q)*N: LET N=0: LET B$="B"
  940 PRINT TAB(12);"AVAILABLE SLOT MACHINES": PRINT
  950 PRINT "(0) Quit play"
  960 PRINT "(1) Programers Bell  single window"
  970 PRINT "(2) Programers Bell  triple window"
  980 PRINT "(3) Twenty-one Bell  triple window"
  990 PRINT "(4) Atlantic City style  3  window"
 1000 PRINT "(5) ... Reserved for a future machine ..."
 1010 PRINT "(6) Enable  AUTOMATIC lever pulling"
 1020 PRINT "(7) Disable AUTO lever pulling and FAST spin"
 1030 PRINT "(8) Enable  FAST wheel spinning"
 1040 PRINT "(9) See statistics of the last machine played."
 1050 PRINT
 1060 INPUT (1,0)"Pick your machine type ---=>",I
 1070 IF I=0 THEN 4260
 1080 IF I=9 THEN  GOSUB 4000
 1090 IF I=9 THEN 1060
 1100 IF I<>6 THEN 1120
 1110 LET A$(1,1)="A": LET B$="B"
 1120 IF I<>7 THEN 1140
 1130 LET A$="  ": LET B$=" "
 1140 IF I=8 THEN  LET A$(2,2)="F"
 1150 IF I<1 OR I>4 THEN 900 ELSE  LET T=I
 1160 GOSUB 3120
 1170 PRINT K$;TAB(7);
 1180 GOSUB 2650
 1190 PRINT "  AVAILABLE DENOMIATIONS": PRINT
 1200 LET M$="": IF T>2 THEN 1220
 1210 FOR Z=1 TO 33: LET M$=M$+CHR(5): NEXT Z
 1220 IF T<>3 THEN 1240
 1230 FOR Z=1 TO 33: LET M$=M$+CHR(16): NEXT Z
 1240 IF T<>4 THEN 1260
 1250 FOR Z=1 TO 33: LET M$=M$+CHR(28): NEXT Z
 1260 PRINT "(0) Quit";TAB(25);"(1) Quarter"
 1270 PRINT "(2) Half Dollar";TAB(25);"(3) Anthony Dollar"
 1280 IF M<5 THEN  PRINT "(4) Dime";
 1290 IF M<2.1 THEN  PRINT TAB(25);"(5) Nickle"
 1300 IF M<1.1 THEN  PRINT "(6) Penny" ELSE  PRINT
 1310 IF E(7)*3>M THEN 1330
 1320 PRINT "( 7) SILVER dollar";TAB(30);%$C6I;E(7);" each."
 1330 FOR Z=8 TO 14
 1340   IF 3*E(Z)>M THEN  PRINT
 1350   IF 3*E(Z)>M THEN 1380
 1360   PRINT "(";%2I;Z;") *GOLD* ";%$6F2;D(Z);" piece";
 1370   PRINT TAB(30);%$C7I;E(Z);" each."
 1380 NEXT Z
 1390 CURSOR 13,15: PRINT "<<< You have ";%$C;M;" >>>"
 1400 INPUT (2,0)"Pick your denomination ---=>",Q
 1410 IF Q=0 THEN 4260
 1420 IF Q<1 OR Q>14 THEN 900 ELSE  PRINT
 1430 LET D=D(Q): LET N=INT(M/E(Q)): LET M=M-(N*E(Q))
 1440 PRINT K$: REM ...Parameters complete
 1450 GOSUB 2450: GOSUB 2710: REM ...Display the machine
 1460 CURSOR 0,38: GOSUB 2650
 1470 CURSOR 1,33: PRINT "SLOT MACHINE denomination is";
 1480 CURSOR 2,35: IF Q>7 THEN  PRINT "*GOLD* ";
 1490 IF D=.01 THEN  PRINT "    PENNIES";
 1500 IF D=.05 THEN  PRINT "    NICKLES";
 1510 IF D=.10 THEN  PRINT "       DIMES";
 1520 IF D=.25 THEN  PRINT "     QUARTERS";
 1530 IF D=.5 THEN  PRINT "  HALF DOLLERS";
 1540 IF D=1 AND Q=3 THEN  PRINT "Anthony ";
 1550 IF D=1 AND Q=7 THEN  PRINT "SILVER ";
 1560 IF D=1 THEN  PRINT " DOLLERS";
 1570 IF D=2.5 THEN  PRINT "1/4 EAGLES ($2.50)";
 1580 IF D=3 THEN  PRINT " THREE DOLLER PIECES";
 1590 IF D=5 THEN  PRINT "HALF EAGLES ($5)";
 1600 IF D=10 THEN  PRINT "EAGLES ($10)";
 1610 IF D=20 THEN  PRINT "DOUBLE EAGLES ($20)";
 1620 IF D=50 THEN  PRINT "FIFTY DOLLAR PIECES";
 1630 CURSOR 4,40: PRINT "Coins you have";
 1640 CURSOR 5,43: PRINT %C;N;" ";
 1650 CURSOR 6,35: PRINT "(O)";
 1660 CURSOR 7,35: PRINT "//";
 1670 CURSOR 8,33: PRINT "\//";
 1680 CURSOR 9,33: PRINT "// ";
 1690 CURSOR 10,35: PRINT "   ";
 1700 CURSOR 11,35: PRINT "   ";: CURSOR 9,40
 1710 IF M>0 THEN  PRINT "$ left over:";%$C9F2;M;
 1720 CURSOR 9,40: IF G(T)=0 THEN 1740
 1730 PRINT "Payoff rate:";%8F2;(M(T)/G(T))*100;" %";
 1740 CURSOR 10,40: PRINT "                       ";
 1750 IF G(T)<=0 THEN 1770 ELSE  CURSOR 10,40
 1760 PRINT "for ";%C;G(T);" coins";
 1770 CURSOR 13,35: PRINT "Enter 'Q' to quit machine";
 1780 CURSOR 14,35
 1790 IF T=1 THEN  PRINT "(RETURN) key pulls lever";
 1800 IF T>1 THEN  PRINT "Enter from 0 to 5 coins.";
 1810 IF B$="A" THEN  INPUT (1,10)I$ ELSE  INPUT (1,0)I$
 1820 LET I$=I$+C$: LET P=0
 1830 IF I$(1,1)="Q" THEN 900
 1840 IF I$(1,1)="0" THEN 900
 1850 IF B$="B" THEN  LET C$=I$(1,1)
 1860 IF T>1 THEN  LET I=ASC(I$(1,1))-48 ELSE  LET I=1
 1870 LET P=0: IF A$(1,1)="A" THEN  LET B$="A"
 1880 IF I<1 OR I>5 THEN 900
 1890 IF M+N<=0 THEN 4260
 1900 IF A$(1,1)="A" THEN  IF I>N THEN  LET I=1
 1910 IF I>N OR N=0 THEN 900 ELSE  LET N=N-I
 1920 CURSOR 6,35: PRINT "   ";
 1930 CURSOR 7,35: PRINT "   ";
 1940 CURSOR 8,33: PRINT "\\ ";
 1950 CURSOR 9,33: PRINT "/\\";
 1960 CURSOR 10,35: PRINT "\\";
 1970 CURSOR 11,35: PRINT "(O)";
 1980 CURSOR 7,40: PRINT "                      ";
 1990 LET W=I: LET H(T)=H(T)+1: LET G(T)=G(T)+I
 2000 CURSOR 12,39: PRINT "(";%C;H(T);" ) lever pulls";
 2010 CURSOR 5,43: PRINT %C;N;"      ";
 2020 LET A1=INT(RND(0)*15)+15: REM ...Number of wheel spins
 2030 LET B1=INT(RND(0)*15)+5+A1
 2040 LET C1=INT(RND(0)*10)+A1+B1+5
 2050 IF A1=0 THEN 2070
 2060 LET A=A+1: LET A1=A1-1: IF A>21 THEN  LET A=2
 2070 IF B1=0 THEN 2090
 2080 LET B=B+1: LET B1=B1-1: IF B>21 THEN  LET B=2
 2090 IF C1=0 THEN 2110
 2100 LET C=C+1: LET C1=C1-1: IF C>21 THEN  LET C=2
 2110 IF A$(2,2)<>"F" THEN 2140
 2120 LET A=INT(RND(0)*20)+2: LET B=INT(RND(0)*20)+2
 2130 LET C=INT(RND(0)*20)+2: GOTO 2260
 2140 IF T=1 THEN 2180
 2150 LET X=A(A+1)*3: LET Y=B(B+1)*3: LET Z=C(C+1)*3
 2160 CURSOR 3,9
 2170 PRINT S$(X-2,X);" : ";S$(Y-2,Y);" : ";S$(Z-2,Z);
 2180 LET X=A(A)*3: LET Y=B(B)*3: LET Z=C(C)*3
 2190 CURSOR 2,9
 2200 PRINT S$(X-2,X);" : ";S$(Y-2,Y);" : ";S$(Z-2,Z);
 2210 IF T=1 THEN 2250
 2220 LET X=A(A-1)*3: LET Y=B(B-1)*3: LET Z=C(C-1)*3
 2230 CURSOR 1,9
 2240 PRINT S$(X-2,X);" : ";S$(Y-2,Y);" : ";S$(Z-2,Z);
 2250 IF A1+B1+C1>0 THEN 2050
 2260 IF A$(2,2)="F" THEN  GOSUB 2710
 2270 LET X=A(A): LET Y=B(B): LET Z=C(C): REM ...Spinning done
 2280 ON T GOSUB 3270,3270,3500,3800
 2290 IF W<2 THEN 2320
 2300 LET X=A(A-1): LET Y=B(B-1): LET Z=C(C-1)
 2310 ON T GOSUB 3270,3270,3500,3800
 2320 IF W<3 THEN 2350
 2330 LET X=A(A+1): LET Y=B(B+1): LET Z=C(C+1)
 2340 ON T GOSUB 3270,3270,3500,3800
 2350 IF W<4 THEN 2380
 2360 LET X=A(A-1): LET Y=B(B): LET Z=C(C+1)
 2370 ON T GOSUB 3270,3270,3500,3800
 2380 IF W<5 THEN 2410
 2390 LET X=A(A+1): LET Y=B(B): LET Z=C(C-1)
 2400 ON T GOSUB 3270,3270,3500,3800
 2410 IF P=0 THEN 2430 ELSE  LET M(T)=M(T)+P
 2420 CURSOR 7,40: PRINT "< You won ";P;" coins >";
 2430 LET N=N+P
 2440 GOTO 1640
 2450 REM ...Machine display
 2460 PRINT "   ";M$(3,29)
 2470 IF T=3 THEN  LET M$(1,1)="|" ELSE  LET M$(1,1)="("
 2480 IF T>3 THEN  LET M$(1,1)="<"
 2490 IF T=3 THEN  LET M$(33,33)="|" ELSE  LET M$(33,33)=")"
 2500 IF T>3 THEN  LET M$(33,33)=">"
 2510 PRINT "  ";M$(1,2);
 2520 IF T=1 THEN  PRINT TAB(28);M$(32,33) ELSE  GOSUB 2700
 2530 PRINT "  ";M$(1,2);: GOSUB 2700
 2540 PRINT "  ";M$(1,2);
 2550 IF T=1 THEN  PRINT TAB(28);M$(32,33) ELSE  GOSUB 2700
 2560 PRINT " ";M$(1,2);"---------------------------";M$(32,33)
 2570 PRINT M$(1,2);"-----------------------------";M$(32,33)
 2580 FOR Z=1 TO 9
 2590   PRINT M$(1,2);D$(Z*12-11,Z*12+1);": Pay ";
 2600   PRINT %3I;P(Z);" coins ";M$(32,33)
 2610 NEXT Z
 2620 PRINT M$;
 2630 IF T>2 THEN  CURSOR 14,15: PRINT "               ";
 2640 RETURN
 2650 IF T<3 THEN  PRINT "<Programmer Bell>";
 2660 IF T=3 THEN  PRINT "(Twenty-one Bell)";
 2670 IF T=4 THEN  PRINT "{Alantic City style}";
 2680 REM ...NAME OF NEW MACHINE
 2690 RETURN
 2700 PRINT "   |     |     |     |   ";M$(32,33): RETURN
 2710 REM ...Display STARTING wheel symbols
 2720 FOR K=-1 TO 1
 2730   IF T>1 THEN 2750
 2740   IF K<>0 THEN 2780
 2750   LET X=A(A+K)*3: LET Y=B(B+K)*3: LET Z=C(C+K)*3
 2760   CURSOR 2+K,9: PRINT S$(X-2,X);" | ";S$(Y-2,Y);
 2770   CURSOR 2+K,21: PRINT S$(Z-2,Z);
 2780 NEXT K
 2790 RETURN
 2800 REM ...Set up a Programmers Bell machine
 2810 DATA " 88- Any Any 88- 88- Any (O) (O) ==="
 2820 DATA " /b\ /b\ (O) <#> <#> <#> (M) (M) ==="
 2830 DATA " (O) (O) (O) (M) (M) (M) === === === "
 2840 DATA 2,5,6,8,10,15,18,20,200
 2850 DATA 10.5,4.5,.25,2.1,.3,.04,1.75,.11,.03
 2860 DATA 20.17,21.61,1.44,16.14,2.88,.54,30.26,2.16,4.8
 2870 REM ...Reel #1, symbol #5: changed cherry to bar
 2880 DATA 2,4,2,5,6,3,4,5,3,4,1,2,3,1,6,2,5,1,3,2,2,4
 2890 DATA 3,1,2,3,1,2,3,1,4,4,1,2,3,6,3,1,2,3,5,1,3,1
 2900 DATA 2,3,4,5,2,5,4,3,6,4,2,3,5,2,2,3,4,2,3,2,2,3
 2910 REM ...Set up a 21 Bell 3 wheel machine
 2920 DATA " 88- Any Any 88- 88- Any (O) (O) O/="
 2930 DATA " {*} {*} */= /b\ /b\ b/= (M) (M) M/="
 2940 DATA " === === === {7} {7} {7}             "
 2950 DATA 2,5,10,14,18,100,100,200,0
 2960 DATA 7,3,1.56,1.05,.56,.15,.07,.01,0
 2970 DATA 14.82,15.88,16.54,15.56,10.72,15.88,7.94,2.65,0
 2980 DATA 2,5,8,1,8,2,7,9,2,1,6,8,2,8,5,8,2,8,6,8,2,5
 2990 DATA 1,8,1,13,1,3,11,3,1,2,3,12,8,3,1,6,2,1,3,12,1,8
 3000 DATA 3,2,8,3,2,4,3,12,3,8,4,3,8,3,10,4,3,12,3,4,3,2
 3010 REM ...Set up an Atlantic City style machine
 3020 DATA " 88- Any Any 88- 88- Any {*} {*} {*}"
 3030 DATA " (O) (O) (O) (O) (O) === /b\ /b\ /b\"
 3040 DATA " /b\ /b\ === === === ===             "
 3050 DATA 2,5,14,20,20,40,40,100,0
 3060 DATA 20,6,.6,.45,.23,.23,.15,.15,0
 3070 DATA 28,30,8.5,9,4.5,9,6,5,0
 3080 DATA 4,1,1,4,8,8,4,8,6,4,6,2,2,1,2,1,8,3,4,3,4,1
 3090 DATA 4,1,4,1,3,1,3,3,8,6,8,8,1,1,1,4,2,2,4,2,4,1
 3100 DATA 4,3,4,2,4,8,4,8,6,4,6,2,4,2,2,8,8,3,4,3,4,3
 3110 REM ...Set up a .....FUTURE........ machine
 3120 IF T<3 THEN  RESTORE 2800
 3130 IF T=3 THEN  RESTORE 2910
 3140 IF T=4 THEN  RESTORE 3010
 3150 IF T=5 THEN  RESTORE 3110
 3160 LET D$=""
 3170 FOR Z=1 TO 3
 3180   READ Z$: LET D$=D$+Z$
 3190 NEXT Z
 3200 FOR Z=1 TO 9: READ P(Z): NEXT Z
 3210 FOR Z=1 TO 9: READ O(Z): NEXT Z
 3220 FOR Z=1 TO 9: READ U(Z): NEXT Z
 3230 FOR Z=1 TO 22: READ A(Z): NEXT Z
 3240 FOR Z=1 TO 22: READ B(Z): NEXT Z
 3250 FOR Z=1 TO 22: READ C(Z): NEXT Z
 3260 RETURN
 3270 LET V=0: LET J=T*9-9: REM ...WIN CHECK : Decode the wheel
 3280 REM ...Programmers Bell machines
 3290 ON X GOTO 3300,3330,3370,3390,3410,3450
 3300 IF Y=1 THEN  LET V=V+P(2) ELSE 3320
 3310 LET W(J+2)=W(J+2)+1: GOTO 3470: REM ...88- 88- Any
 3320 LET V=V+P(1): LET W(J+1)=W(J+1)+1: GOTO 3470
 3330 IF Y=2 AND Z=6 THEN  LET V=V+P(3) ELSE 3350
 3340 LET W(J+3)=W(J+3)+1: GOTO 3470: REM ...(O) (O) ===
 3350 IF Y=2 AND Z=2 THEN  LET V=V+P(7) ELSE 3470
 3360 LET W(J+7)=W(J+7)+1: GOTO 3470: REM ...(O) (O) (O)
 3370 IF Y=3 AND Z=2 THEN  LET V=V+P(4) ELSE 3470
 3380 LET W(J+4)=W(J+4)+1: GOTO 3470: REM .../.\ /.\ (O)
 3390 IF Y=4 AND Z=4 THEN  LET V=V+P(5) ELSE 3470
 3400 LET W(J+5)=W(J+5)+1: GOTO 3470: REM ...<#> <#> <#>
 3410 IF Y=5 AND Z=6 THEN  LET V=V+P(6) ELSE 3430
 3420 LET W(J+6)=W(J+6)+1: GOTO 3470: REM ...(W) (W) ===
 3430 IF Y=5 AND Z=5 THEN  LET V=V+P(8) ELSE 3470
 3440 LET W(J+8)=W(J+8)+1: GOTO 3470: REM ...(W) (W) (W)
 3450 IF Y=6 AND Z=6 THEN  LET V=V+P(9) ELSE 3470
 3460 LET W(J+9)=W(J+9)+1: REM ...=== === ===
 3470 IF V>0 THEN  LET Q(T)=Q(T)+1
 3480 LET P=P+V
 3490 RETURN
 3500 LET V=0: LET J=18: REM ...WIN CHECK : Decode the wheel
 3510 REM ...21 Bell 3 wheel
 3520 ON X GOTO 3530,3570,3750,3750,3670,3700,3730,3610,3640
 3530 IF Y=1 THEN  LET V=V+P(2) ELSE 3550
 3540 LET W(J+2)=W(J+2)+1: GOTO 3750: REM ...88- 88- Any
 3550 LET V=V+P(1): LET W(J+1)=W(J+1)+1: GOTO 3750
 3560 LET W(J+1)=W(J+1)+1: GOTO 3750: REM ...88- Any Any
 3570 IF Y=2 OR Y>11 THEN 3580 ELSE 3750: REM ...Oranges
 3580 IF Z=2 OR Z=12 THEN 3600
 3590 IF Z<>10 THEN 3750
 3600 LET V=V+P(3): LET W(J+3)=W(J+3)+1: GOTO 3750
 3610 IF Y=8 OR Y=11 THEN 3620 ELSE 3750: REM ...Plums
 3620 IF Z=8 OR Z=10 THEN  LET V=V+P(4) ELSE 3750
 3630 LET W(J+4)=W(J+4)+1: GOTO 3750
 3640 IF Y<>3 THEN 3700: REM ...Bells
 3650 IF Z=3 OR Z=10 THEN  LET V=V+P(5) ELSE 3750
 3660 LET W(J+5)=W(J+5)+1: GOTO 3750
 3670 IF Y<>12 THEN 3750: REM ...Melons
 3680 IF Z=12 OR Z=10 THEN  LET V=V+P(J) ELSE 3750
 3690 LET W(J+6)=W(J+6)+1: GOTO 3750
 3700 IF Y=6 OR Y=11 THEN 3710 ELSE 3750: REM ...Bars
 3710 IF Z=10 THEN  LET V=V+P(J) ELSE 3750
 3720 LET W(J+7)=W(J+7)+1: GOTO 3750
 3730 IF Y=13 AND Z=10 THEN  LET V=V+P(8) ELSE 3750
 3740 LET W(J+8)=W(J+8)+1
 3750 IF V>0 THEN  LET Q(T)=Q(T)+1
 3760 LET P=P+V
 3770 RETURN
 3780 REM
 3790 REM
 3800 LET V=0: LET J=27: REM ...WIN CHECK : Decode the wheel
 3810 REM ...Alantic City style machines
 3820 ON X GOTO 3830,3880,3920,3980,3980,3960,3980,3860
 3830 IF Y=1 THEN  LET V=V+P(2) ELSE 3850
 3840 LET W(J+2)=W(J+2)+1: GOTO 3980: REM ...88- 88- Any
 3850 LET V=V+P(1): LET W(J+1)=W(J+1)+1: GOTO 3980
 3860 IF Y=8 AND Z=8 THEN  LET V=V+P(3) ELSE 3980
 3870 LET W(J+3)=W(J+3)+1: GOTO 3470: REM ...{*} {*} {*}
 3880 IF Y=2 AND Z=2 THEN  LET V=V+P(4) ELSE 3900
 3890 LET W(J+4)=W(J+4)+1: GOTO 3980: REM ...(O) (O) (O)
 3900 IF Y=2 AND Z=6 THEN  LET V=V+P(5) ELSE 3980
 3910 LET W(J+5)=W(J+5)+1: GOTO 3980: REM ...(O) (O) ===
 3920 IF Y=3 AND Z=3 THEN  LET V=V+P(6) ELSE 3940
 3930 LET W(J+6)=W(J+6)+1: GOTO 3980: REM .../b\ /b\ /b\
 3940 IF Y=3 AND Z=6 THEN  LET V=V+P(7) ELSE 3980
 3950 LET W(J+7)=W(J+7)+1: GOTO 3980: REM .../b\ /b\ ===
 3960 IF Y=6 AND Z=6 THEN  LET V=V+P(8) ELSE 3980
 3970 LET W(J+8)=W(J+8)+1: REM ...=== === ===
 3980 IF V>0 THEN  LET Q(T)=Q(T)+1
 3990 LET P=P+V: RETURN
 4000 PRINT K$: CURSOR 1,1: REM ...See statistics
 4010 PRINT " Payoffs :";%C;Q(T);"      Lever pulls:";%C;H(T);
 4020 IF G(T)=0 THEN 4040
 4030 PRINT TAB(42);"PAYOFF ratio:";%6F2;100*(Q(T)/G(T));" %";
 4040 CURSOR 2,1
 4050 PRINT "Coins won:";%C;M(T);"     Coins used :";%C;G(T);
 4060 IF G(T)=0 THEN 4080
 4070 PRINT TAB(42);"PAYOFF rate:";%7F2;100*(M(T)/G(T));" %";
 4080 CURSOR 3,3: PRINT "Payoff chance:";TAB(22);
 4090 GOSUB 2650
 4100 PRINT TAB(45);"% of Money return";
 4110 CURSOR 4,1: PRINT "% Expect  Actual%   ";
 4120 PRINT "COIN PAYOFF BREAKDOWN:";TAB(45);"% Expect";
 4130 PRINT TAB(55);"% Return";
 4140 FOR Z=1 TO 9
 4150   LET Y=T*9-9: CURSOR Z+4,1
 4160   IF O(Z)>0 THEN  PRINT %5F2;O(Z);" %  ";
 4170   IF W(Z+Y)>0 THEN  PRINT %6F2;100*W(Z+Y)/G(T);" %";
 4180   PRINT TAB(20);D$(Z*12-11,Z*12+1);
 4190   IF W(Z+Y)>0 THEN  PRINT %C9I;W(Z+Y);
 4200   IF U(Z)>0 THEN  PRINT TAB(46);%5F2;U(Z);" %  ";
 4210   IF W(Z+Y)>0 THEN  PRINT %6F2;100*W(Z+Y)*P(Z)/M(T);" %";
 4220 NEXT Z
 4230 IF Q=11 THEN  CURSOR 15,1 ELSE  CURSOR 14,1
 4240 IF Q=0 OR N+M=0 THEN  PRINT "You leave with ";%$C;M;
 4250 RETURN
 4260 GOSUB 4000
 4270 GOTO 4520
 4280 REM
 4290 REM
 4300 FOR Z=1 TO 9
 4310   PRINT D$(Z*12-11,Z*12+1);": Pay ";
 4320   PRINT %3I;P(Z);" coins ";
 4330   INPUT " 3 WAYS ",A1(Z),B1(Z),C1(Z)
 4340 NEXT Z
 4350 PRINT K$: LET W1=0,C1=0
 4360 FOR Z=1 TO 9
 4370   LET W2(Z)=A1(Z)*B1(Z)*C1(Z),W1=W2(Z)+W1
 4380   LET C2(Z)=A1(Z)*B1(Z)*C1(Z)*P(Z),C1=C1+C2(Z)
 4390 NEXT Z
 4400 FOR Z=1 TO 9
 4410   PRINT D$(Z*12-11,Z*12+1);":";
 4420   PRINT %3I;P(Z);
 4430   PRINT %2I;A1(Z);"X";B1(Z);"X";C1(Z);"=";%4I;W2(Z);
 4440   PRINT %7F2;W2(Z)/80;100*(W2(Z)/W1);":";
 4450   PRINT %7I;C2(Z);%7F2;(C2(Z)/C1)*100
 4460 NEXT Z
 4470 PRINT
 4480 PRINT "TOTAL WAYS =";W1,"TOTAL COINS=";C1
 4490 PRINT "WIN%=";%6F2;C1/80," PAYOFF%=";W1/80
 4500 INPUT ">",X$
 4510 GOTO 4300
 4520 END