100 REM...CONVERTED FROM MANKATO LIBRARY ON 4/23/75
  110 REM...BY J.STEWART       PROGRAMMER DAVE SKROVE
  115 DIM L(50),T(10)
  120 PRINT "&K&J&J&J": REM...DATE JANUARY 11,1974
  130 PRINT TAB(10);"$$$$$$$$$$$$$$$$$$$$$$"
  140 PRINT TAB(10);"$$$  T A X M A N   $$$"
  150 PRINT TAB(10);"$$$$$$$$$$$$$$$$$$$$$$"
  160 PRINT
  170 PRINT "HI, I AM THE TAXMAN."
  180 PRINT "DO YOU WANT THE REGULATIONS (1=YES,0=NO)";
  190 INPUT R
  200 IF R=1 THEN 1300
  210 GOSUB 1060
  220 GOSUB 290
  230 GOSUB 530
  240 GOSUB 630
  250 GOSUB 720
  260 IF M=1 THEN 220
  270 GOSUB 910
  280 GOTO 1000
  290 PRINT
  300 PRINT "YOU TAKE";
  310 INPUT K
  320 LET K=INT(K)
  330 IF K<=0 THEN 1000
  340 IF K<=N THEN 370
  350 PRINT K;" IS NOT IN THE LIST -- TRY AGAIN."
  360 GOTO 290
  370 IF L(K)=0 THEN 350
  380 IF K>1 THEN 420
  390 PRINT "THERE ARE NO FACTORS OF ";K;" FOR ME."
  400 PRINT "ARE YOU TRYING TO SHORT-CHANGE THE TAXMAN"
  410 GOTO 290
  420 LET M=0
  430 FOR I=1 TO K/2
  440   IF L(I)=0 THEN 490
  450   IF K<>I*INT(K/I) THEN 490
  460   LET M=M+1
  470   LET T(M)=I
  480   LET L(I)=0
  490 NEXT I
  500 IF M=0 THEN 390
  510 LET L(K)=0
  520 RETURN
  530 LET Y=Y+K
  540 PRINT "YOUR TOTAL IS ";Y
  550 PRINT "I GET";
  560 FOR I=1 TO M
  570   PRINT T(I);
  580   LET Z=Z+T(I)
  590 NEXT I
  600 PRINT
  610 PRINT "MY TOTAL IS ";Z
  620 RETURN
  630 PRINT
  640 PRINT "NEW LIST: ";
  650 LET M=0
  660 FOR I=1 TO N
  670   IF L(I)=0 THEN 700
  680   PRINT I;
  690   LET M=1
  700 NEXT I
  710 RETURN
  720 IF M=0 THEN 900
  730 FOR I=N TO 4 STEP -1
  740   FOR J=2 TO I/2
  750     IF L(J)=0 THEN 780
  760     LET M=1
  770     RETURN
  780   NEXT J
  790 NEXT I
  800 PRINT
  810 PRINT "I GET ";
  820 FOR I=1 TO N
  830   IF L(I)=0 THEN 860
  840   PRINT I;
  850   LET Z=Z+I
  860 NEXT
  870 PRINT " BECAUSE NO FACTORS OF ANY NUMBERS ARE LEFT."
  880 PRINT "MY TOTAL IS ";Z
  890 LET M=0
  900 RETURN
  910 PRINT
  920 IF Z>Y THEN 960
  930 IF Z=Y THEN 980
  940 PRINT " YOU ";Y;"      TAXMAN ";Z;"      YOU WIN!!!"
  950 RETURN
  960 PRINT "TAXMAN ";Z;"      YOU ";Y;"      THE TAXMAN WINS."
  970 RETURN
  980 PRINT " TAXMAN ";Z;"      YOU ";Y;"     TIE GAME!!!!!"
  990 RETURN
 1000 PRINT
 1010 PRINT
 1020 PRINT "AGAIN (1=YES,0=NO)";
 1030 INPUT R
 1040 IF R=0 THEN 1640
 1050 GOTO 210
 1060 PRINT
 1070 PRINT "HOW MANY NUMBERS DO YOU WANT IN THE LIST";
 1080 INPUT N
 1090 LET N=INT(N)
 1100 IF N<=0 THEN 1640
 1110 IF N<=50 THEN 1150
 1120 PRINT " AT THIS TIME,REGULATIONS ALLOW"
 1130 PRINT " ........ A MAXIMUM OF 50 NUMBERS."
 1140 GOTO 1060
 1150 REM...
 1160 LET Y=0
 1170 LET Z=0
 1180 PRINT
 1190 PRINT " THE LIST IS: ";
 1200 FOR I=1 TO N
 1210   PRINT I;
 1220   LET L(I)=1
 1230 NEXT I
 1240 IF N>1 THEN 1290
 1250 PRINT
 1260 PRINT "  GENEROUS OF YOU TO FORFEIT ALL TO THE  TAXMAN."
 1270 PRINT " TAXMAN  1    YOU  0      THE TAXMAN WINS."
 1280 GOTO 1000
 1290 RETURN
 1300 PRINT
 1310 PRINT " YOU TRY TO BEAT THE TAXMAN."
 1320 PRINT
 1330 PRINT "   WE START WITH A LIST OF WHOLE NUMBERS IN"
 1340 PRINT " NUMERICAL ORDER (YOU DECIDE HOW MANY)."
 1350 PRINT
 1360 PRINT " YOU TAKE A NUMBER FROM THE LIST -- THE TAXMAN"
 1370 PRINT " GETS ALL THE FACTORS OF YOUR NUMBER THAT"
 1380 PRINT " ARE STILL LEFT.    YOUR NUMBER AND ALL IT'S"
 1390 PRINT " FACTORS ARE THEN DELETED FROM THE LIST."
 1400 GOSUB 1590
 1410 PRINT TAB(10);"FOR EXAMPLE,"
 1420 PRINT " SUPPOSE YOU WANT 10 NUMBERS TO BE IN THE LIST."
 1430 PRINT " THEN THE LIST WOULD BE: 1 2 3 4 5 6 7 8 9 10"
 1440 PRINT
 1450 PRINT " IF YOU TOOK 8, THE TAXMAN WOULD GET 1, 2, AND 4"
 1460 PRINT " AND THE NEW LIST WOULD BE: 3 5 6 7 9 10"
 1470 PRINT
 1480 GOSUB 1590
 1490 PRINT " THE TAXMAN MUST GET SOMETHING EVERY TIME SO YOU"
 1500 PRINT " CAN ONLY PICK A NUMBER THAT HAS FACTORS LEFT."
 1510 PRINT
 1520 PRINT "    WHEN NONE OF THE REMAINING NUMBERS HAS"
 1530 PRINT " ANY FACTORS.... THE TAXMAN GETS THEM!!"
 1540 PRINT
 1550 PRINT "YOUR SCORE IS THE SUM OF THE NUMBERS YOU TAKE."
 1560 PRINT "IF YOU WANT TO GIVE UP,TAKE 0."
 1570 PRINT TAB(10);" GOOD LUCK!"
 1580 GOTO 210
 1590 PRINT
 1600 INPUT (1,100)" $$$ ENTER ANY NUMBER TO SEE MORE $$$ --->",I
 1610 PRINT
 1620 PRINT
 1630 RETURN
 1640 END