10 REM ... TWONE.ECB
   20 PRINT "&K&J&J"
  100 REM === LAST MOD.    6/20/78   R.E.H.
  110 REM WRITTEN BY M. M.MORTAZAVI
  115 DIM Y(36)
  120 PRINT
  130 PRINT TAB(10);" ***  TWENTY - ONE  ***"
  140 PRINT
  150 PRINT "  DO YOU KNOW HOW TO PLAY? ( Y or N ) ---=>";
  160 INPUT (1,0)R$: LET R$=R$+"N"
  165 GOSUB 1390
  170 ON F GOTO 500,210,180
  180 PRINT " JUST A SIMPLE YES OR NO WOULD DO."
  190 GOTO 160
  210 PRINT
  220 PRINT "     THIS GAME IS PLAYED IN A SIMILAR WAY TO"
  230 PRINT "  BLACKJACK. THE DECK HAS 36 CARDS.  UNIVAC WILL"
  240 PRINT " DEAL THE CARDS IN A RANDOM SELECTION."
  250 PRINT " CARDS FROM 6 TO 10 HAVE THERE OWN VALUE."
  260 PRINT " THE JACK HAS VALUE    =  2 POINTS"
  270 PRINT " THE QUEEN HAS A VALUE =  3 POINTS"
  280 PRINT " THE KING HAS A VALUE  =  4 POINTS"
  290 PRINT " THE VALUE OF ACE      = 11 POINTS"
  300 GOSUB 1540
  310 PRINT " YOU WILL RECEIVE A CARD AND ARE INFORMED OF"
  320 PRINT " IT'S POINT VALUE.  THEN YOU WILL BE ASKED HOW"
  330 PRINT " MUCH YOU WANT TO BID ON THE CARD .  YOU CAN"
  340 PRINT " BID ANYTHING  FROM A DOLLAR TO THE AMOUNT OF"
  350 PRINT " THE BANK OR YOUR BALANCE, WHICH EVER HAS THE"
  360 PRINT " LOWEST VALUE.   THEN YOU ARE ASKED IF YOU"
  370 PRINT " WANT ANOTHER CARD , TO A YES  YOU WILL RECEIVE"
  380 PRINT " ONE MORE CARD AND YOU ARE INFORMED OF YOUR"
  390 PRINT " TOTAL POINTS."
  400 GOSUB 1540
  410 PRINT "         IF YOU SAY NO, UNIVAC WILL DEAL FOR"
  420 PRINT " HIMSELF AND EACH TIME WILL INFORM YOU OF THE"
  430 PRINT " RESULTS.   THE OBJECT IS TO GET THE HIGHEST"
  440 PRINT " POINTS WITHOUT  GOING OVER 21.  IN CASE OF A"
  450 PRINT " TIE THE DEALER (UNIVAC) WINS !   IF EITHER GETS"
  460 PRINT " TWO SUCCESSIVE ACES (POINT VALUE=22) THAT PARTY"
  470 PRINT " WINS!  THE BID VALUE WILL BE FORWARDED TO THE"
  480 PRINT " WINNER'S ACCOUNT.   THEN ANOTHER HAND WILL START."
  490 PRINT " ..... GO THROUGH THE SAME PROCESS. "
  500 FOR X=1 TO 36: READ Y(X): NEXT X
  510 DATA 2,2,2,2,3,3,3,3,4,4,4,4,6,6,6,6,7,7,7,7,8,8,8,8
  520 DATA 9,9,9,9,10,10,10,10,11,11,11,11
  530 REM... RANDOMIZE
  540 PRINT
  550 PRINT " HOW MUCH MONEY DO YOU HAVE ---=>";
  560 INPUT B
  570 IF B<0 THEN 1520
  580 LET A=(B/2)
  590 PRINT TAB(15);"BANK  =  ";A;"      YOUR BALANCE  =  ";B
  600 LET M=0
  610 LET C3=0
  620 LET S=0
  630 LET S1=0
  640 GOSUB 1350
  650 LET S=S+C1
  660 PRINT "     YOUR CARD IS ";C1;" YOUR TOTAL IS ";S
  670 IF M>0 THEN 710
  680 PRINT "  WHAT IS YOUR BID ---=>";
  690 INPUT D
  700 LET M=M+1
  710 IF D>B THEN 1330
  720 IF D>A THEN 1310
  730 IF D<0 THEN 1470
  740 IF S=21 THEN 850
  750 IF S<21 THEN 790
  760 IF C3<>11 THEN 1090
  770 IF C1=C3 THEN 1050
  780 GOTO 1090
  790 PRINT " DO YOU WANT ANOTHER CARD ---=>";
  800 LET C3=C1
  810 INPUT (1,0)R$: LET R$=R$+"N"
  815 GOSUB 1390
  820 ON F GOTO 640,850,830
  830 PRINT " JUST A SIMPLE YES OR NO WOULD DO."
  840 GOTO 810
  850 PRINT "  UNIVAC TAKES A CARD."
  860 LET C4=0
  870 GOSUB 1350
  880 LET S1=S1+C1
  890 PRINT TAB(10);"MY CARD IS ";C1;"    MY TOTAL IS ";S1
  900 IF S1=21 THEN 1130
  910 IF S>18 THEN 980
  920 IF S1<18 THEN 980
  930 IF S1<21 THEN 1030
  940 IF S1>21 THEN 1150
  950 IF C4<>11 THEN 1150
  960 IF C1=11 THEN 1130
  970 GOTO 1150
  980 LET C4=C1
  990 IF S1>21 THEN 940
 1000 IF S1>=S THEN 1130
 1010 PRINT " UNIVAC TAKES ANOTHER CARD."
 1020 GOTO 870
 1030 IF S1<S THEN 1050
 1040 GOTO 1130
 1050 PRINT " I HAVE ";S1;"  YOU HAVE ";S;" *******YOU WIN*********"
 1060 LET A=A-D
 1070 LET B=B+D
 1080 GOTO 1170
 1090 PRINT " YOU HAVE ";S;"  WHICH EXCEEDS 21,--YOU LOSE---"
 1100 LET A=A+D
 1110 LET B=B-D
 1120 GOTO 1170
 1130 PRINT " I HAVE ";S1;" YOU HAVE ";S;" ******I WIN******"
 1140 GOTO 1100
 1150 PRINT " I HAVE ";S1;"  WHICH EXCEEDS 21,----I LOSE----"
 1160 GOTO 1060
 1170 IF B<.1 THEN 1200
 1180 IF A<.1 THEN 1240
 1190 GOTO 590
 1200 PRINT "&J ******* I HAVE A GRAND TOTAL OF ";A;" *******&J"
 1210 PRINT " YOU HAVE LOST YOUR LAST PENNY."
 1220 PRINT TAB(10);" ... DO YOU WANT TO PLAY AGAIN ";
 1230 GOTO 1270
 1240 PRINT "&J ******* YOU HAVE A GRAND TOTAL OF ";B;" *******&J"
 1250 PRINT "  $$$  THE BANK IS BROKEN  $$$&J"
 1260 PRINT TAB(15);"DO YOU WANT TO START A NEW GAME ---=>";
 1270 INPUT (1,0)R$: LET R$=R$+"Y"
 1275 GOSUB 1390
 1280 ON F GOTO 550,1590,1290
 1290 PRINT "  JUST A SIMPLE YES OR NO WOULD DO."
 1300 GOTO 1270
 1310 PRINT " YOUR BID EXCEEDS BANK TRY AGAIN"
 1320 GOTO 1170
 1330 PRINT " COME NOW, YOU DONT HAVE THAT MUCH MONEY"
 1340 GOTO 1170
 1350 REM===== GENERATES RANDOM NUMBER
 1360 LET C1=INT(RND(0)*36)+1
 1370 LET C1=Y(C1)
 1380 RETURN
 1390 REM....DEF FNA
 1400 LET F=1
 1410 IF R$(1,1)="Y" THEN 1450
 1415 IF R$(1,1)="y" THEN 1450
 1420 LET F=2
 1430 IF R$(1,1)="N" THEN 1450
 1435 IF R$(1,1)="n" THEN 1450
 1440 LET F=3
 1450 RETURN : REM......FNEND
 1460 GOTO 1540
 1470 PRINT " YOU ARE FINED $ ";(B/10);" FOR CHEATING !!!"
 1480 LET A=A+(B/10)
 1490 LET B=B-(B/10)
 1500 PRINT TAB(15);"BANK =  ";A;TAB(30);"YOUR BALANCE  =  ";B
 1510 GOTO 680
 1520 PRINT " COME NOW, YOU'RE NOT THAT POOR. LET'S TRY AGAIN"
 1530 GOTO 550
 1540 PRINT
 1550 PRINT "$$$  TYPE IN ANYTHING TO SEE MORE  $$$ ---=>";
 1560 INPUT (1,200)I$
 1570 PRINT
 1580 RETURN
 1590 END