5 REM ... WIDOW.ECB ...from Roseville   12-17-80
   10 REM CMSC 5 PROJECT 3, PROGRAMMER-JEFF JEWETT
   20 REM ELDERLY WIDOW PROGRAM-SHE HAS $15000 IN THE BANK, AND GETS
   30 REM $150 A MO. FROM S.S. HOW LONG WILL HER FUNDS LAST.
   40 PRINT TAB(25);"ELDERLY WIDOW PROGRAM"
   50 PRINT
   60 PRINT "WHAT IS THE INTEREST RATE IN PER CENT FOR 3 MONTHS";
   70 INPUT I
   80 IF I<.5 THEN 460: REM ...NEW BANK
   90 IF I<0 THEN 480: REM ...BAD DATA
  100 PRINT "WHAT IS THE TOTAL MONTHLY EXPENDITURE ---=>";
  110 INPUT X: REM ...NOTICE-IF X<0 THEN 390-MAYBE SHE WORKS
  120 LET B=15000
  130 LET X1=3*X
  140 FOR N=3 TO 10000 STEP 3: REM ...COMPUTE EVERY 3 MOS., TO SAVE TIME
  150   LET B=B+450-X1:        REM ...ADD THE S.S., SUBTRACT THE EXPENSES
  160   IF B<0 THEN 200:       REM ...RAN OUT OF MONEY
  170   LET B=((100+I)/100)*B: REM ...ADD THE INTEREST
  180   IF B>=15000 THEN 390:  REM ...ACCOUNT IS INCREASING
  190 NEXT N
  200 LET B=B-150+X: REM ...FIND OUT WHEN THE ACCOUNT WENT UNDER
  210 IF B>=0 THEN 290
  220 LET B=B-150+X
  230 IF B>=0 THEN 270
  240 LET B=B-150+X
  250 LET N=N-3: REM ...3 MONTHS AGO
  260 GOTO 300
  270 LET N=N-2: REM ...2 MONTHS AGO
  280 GOTO 300
  290 LET N=N-1: REM ...LAST MONTH
  300 LET Y=INT(N/12)
  310 PRINT
  320 PRINT "AFTER";
  330 IF Y=0 THEN 350
  340 PRINT Y;" YEARS";
  350 PRINT N-(Y*12);" MONTHS, THG OLD GIRL WILL HAVE"
  360 PRINT "$";B;" LEFT IN THE BANK. SHE WON'T LAST A MONTH."
  370 IF N>240 THEN 410
  380 GOTO 420
  390 PRINT "INFINITE LOOP-BANK ACCOUNT INCREASES EACH MONTH"
  400 GOTO 420
  410 PRINT "OF COURSE, SHE PROBABLY WON'T BE AROUND IN";Y;" YEARS."
  420 PRINT
  430 PRINT TAB(25);"*** NEW DATA ***"
  440 PRINT
  450 GOTO 60
  460 PRINT "   GET A NEW BANK"
  470 GOTO 90
  480 PRINT "*BAD DATA. BOO ON YOU, MAN*"
  490 GOTO 420
  500 END