*  RPAT (REPLACE OR DELETE PATTERN)
*  USED IN CONJUNCTION WITH THE TXT-2 EDITOR
*  WRITTEN BY DREW ROGGE
*
*  SYNTAX OF COMMAND LINE AFTER CNTL-V IS AS FOLLOWS:
*
*  PATT [R OR D] <S> <FROM LINE <TO LINE>>
*
*       [ ] DENOTES MUST BE ONE OR THE OTHER
*       < > DENOTES OPTIONAL USE
*  Only PA is significant in PATT.  Any word beginning
*  with PA can be used, but it must be followed by at
*  least one blank.  Line numbers are separated from
*  each other by at least one blank.  Otherwise blanks
*  are ignored.
*
*  [R OR D]  USE R TO REPLACE ONE PATTERN
*       WITH ANOTHER.  USE D TO DELETE ALL
*       OCCURANCES OF THE PATTERN (REPLACE
*       EACH PATTERN WITH THE NULL PATTERN).
*
*  <S>  OPTIONAL SELECT MODE WILL DISPLAY
*       EACH LINE CONTAINING THE PATTERN FOR
*       EVERY OCCURANCE OF THE PATTERN,
*       POSITION THE CURSOR ON THE NEXT LINE
*       DIRECTLY UNDER THE FIRST CHARACTER
*       OF THE CURRENT PATTERN TO REPLACE
*       AND WAIT FOR RESPONSE FROM THE USER.
*       THAT RESPONSE CAN CONSIST OF:
*       (ESC):  ABORT SEARCH, CLOSE UP FILE
*               AND RETURN TO EDITOR.
*        (N):   DO NOT REPLACE OR DELETE THIS
*               OCCURANCE OF THE PATTERN BUT
*               CONTINUE WITH SEARCH.
*       (ANY OTHER KEY):  REPLACE OR DELETE
*               THIS OCCURANCE OF PATTERN AND
*               CONTINUE WITH SEARCH.
*
*  <FROM LINE <TO LINE>>  ALLOWS YOU TO CON-
*       FINE THE SEARCH TO A SECTION IN THE
*       FILE DEFINED BY THE FIRST LINE TO
*       SEARCH THRU THE LAST LINE TO SEARCH,
*       INCLUSIVE.  THE DEFAULT FOR <FROM
*       LINE> IS THE FIRST LINE OF THE FILE
*       AND THE DEFAULT FOR <TO LINE> IS THE
*       LAST LINE OF THE FILE.  TO REPLACE A
*       PATTERN IN ONLY ONE LINE, USE THAT
*       LINE NUMBER FOR BOTH <FROM LINE> AND
*       <TO LINE>.
*
*  ERROR CONDITIONS:
*
*   FATAL ERRORS:
*
*    1) No 'R' or 'D' found after 'PA '
*    2) VALUE OF <FROM LINE> IS LARGER THAN
*       VALUE OF <TO LINE> or <FROM LINE> appears
*       later in the file than <TO LINE>.
*    3) <FROM LINE> OR <TO LINE> WAS NOT
*       FOUND IN THE FILE. IF EITHER <FROM
*       LINE> OR <TO LINE> IS LARGER THAN
*       THE LAST LINE NUMBER IN THE FILE
*       THIS PROGRAM WILL RETURN TO THE EDITOR
*       WITHOUT ANY ACTION BEING TAKEN AND
*       WITH NO RESPONSE COMING FROM ANYWHERE.
*    4) IF, DUE TO THE REPLACEMENT PATTERN
*       BEING LONGER THAN THE EXISTING
*       PATTERN, THE ADDRESS OF THE END
*       OF THE FILE WILL EXCEED THE VALUE
*       SET BY THE COMMAND 'SET' THIS PRO-
*       GRAM WILL CLOSE THE FILE AND RET-
*       URN TO THE EDITOR WITH A PROMPT TELLING
*       YOU WHAT HAS HAPPENED.
*
*   NON-FATAL ERRORS:
*
*    4) LENGTH OF PATTERN WAS LONGER THAN
*       MAXIMUM ALLOWED BY THE VARIABLE
*       'MXPT'.  PROGRAM WILL REPRINT PROMPT
*       AND ACCEPT A NEW PATTERN.
*    5) AFTER REPLACEMENT OF THE PATTERN, THE
*       LINE WILL BE LONGER THAN THE MAXIMUM
*       ALLOWED BY THE VARIABLE 'MAXL'.  THE
*       PROGRAM WILL PRINT AN ERROR PROMPT,
*       DISPLAY THE LINE AND WAIT FOR RES-
*       PONSE FROM THE USER.  THAT RESPONSE
*       IS TREATED THE SAME AS IN THE SELECT
*       MODE.
*
*
*  First we must process the arguments.
*
RPAT CALL HFARG
*
 CPI 'R'  'Replace' option?
 JZ RP1
 CPI 'D'  'Delete' option?
 JNZ WHAT
 XRA A
RP1 STA RMODE  Replace mode.
*
 CALL NONBL  Next non-blank should be an 'S', line #, or CR
 CPI 'S'  'Select' option?
 JZ RP2
 DCX H  So NONBL will read this char again.
 XRA A  Not 'Select'.
RP2 STA SMODE  Select mode.
*
 XCHG .  Save HL.
 LHLD BFP  Get 1st address of file and
 SHLD BOSP  save it in case no 1st line # specified.
 XCHG .  Get HL back (pointer to arguments).
 CALL ZBUF  Zero ABUF where line numbers will go.
*
 LXI D,ABUF  DE-> where to put next line number.
 CALL GETNUM  1st line # to ABUF (HL stays on terminator)
 JZ RP3  Missing -- defaults to 1st line of file.
 PUSH H
 CALL FIND  Get address of line with this number.
 JNZ LNFE  Doesn't exist.
 SHLD BOSP  Save new start address.
 POP H
 LXI D,ABUF+7  Where second line number goes.
 CALL GETNUM
 JZ RP3  Missing -- use end of file.
 LXI H,ABUF+3  Compare 1st and 2nd line numbers.
 LXI D,ABUF+10
 CALL COM0
 JC WHAT  1st was larger.
 LXI H,ABUF+10
 CALL FIND+3  Get address of line with 2nd line #.
 JNZ LNFE  Not found.
 MOV A,M  Compute start of next line.
 CALL ADR
 JMP RP4
*
*
*   SCAN IN THE FIRST ARGUMENT FROM INPUT LINE
*
HFARG LXI H,IBUF  HL-> Argument line.
*
RP00 MOV A,M  Find end of command ('PA', 'PAT', etc)
 INX H
 CPI CR
 JZ WHAT  No arguments at all.
 CPI SPACE  Space terminates command.
 JNZ RP00
 CALL NONBL  First non
blank after command should be R or D
 RET
*
*
* Move line number from HL to DE.  Leave HL at the
* terminator which may be either a blank or CR.  Any
* illegal characters result in a jump to WHAT which
* terminates execution of RPAT and returns to the editor.
*
GETNUM CALL NONBL  Get next non-blank from HL.
 DCX H  Point to it.
 CPI CR
 RZ .  Line number is missing.
 CALL CNTDIG  Count # of digits in number (to A and C).
 CPI 4  Can't have more than 4.
 JZ COPNUM  Exactly four--don't need leading zeroes.
 JP WHAT  Too many.
 MVI A,4
 SUB C  A=4-C is # of leading zeroes to add.
 MOV B,A
 MVI A,'0'  Lead with ascii zeroes.
LEAD0 STAX D
 INX D
 DCR B
 JNZ LEAD0  Not done yet.
COPNUM MOV A,M  Copy number from HL to DE.
 STAX D
 INX D  Next destination.
 INX H  Next source.
 DCR C
 JNZ COPNUM  Still more to copy.
 INR C  Reset zero flag.
 RET
*
* Count number of digits starting at HL.
*
CNTDIG PUSH H  Save old pointer.
 MVI C,0  Count.
CNT0 MOV A,M
 CPI SPACE
 JZ CNT1  Done.
 CPI CR
 JZ CNT1  Ditto.
 CPI '0'
 JM WHAT  Bad digit.
 CPI '9'+1
 JP WHAT
 INR C  count=count+1
 INX H
 JMP CNT0
CNT1 POP H  Get old pointer back.
 MOV A,C  Copy count to A.
 RET
*
* Return next non-blank character beginning at HL.
* HL is left pointing just after this char.
*
NONBL MOV A,M
 INX H
 CPI SPACE
 JZ NONBL
 CALL MAP  Change lower case to upper.
 RET
*
RP3 LHLD EFP
RP4 MOV A,M  GET R.L. FOR THIS LINE
 STA EOSC  AND SAVE IT. THEN PUT END
 MVI M,2+80H  OF SEARCH MARKER IN FILE.
 LXI H,PPRM  'PATTERN:' PROMPT
 LXI D,PTMP-1  PATTERN STOREAGE
 CALL GPAT  GET PATTERN TO REPLACE
 LDA RMODE  REPLACE OR DELETE?
 ORA A
 JNZ RP5  IS REPLACE SO GET STRING
 LXI H,RTMP-1  IS NOT SO USE
 MOV M,A  DUMMY STRING. NEEDS R.L.
 INX H  OF ZERO AND A
 MVI M,0DH  CARRIAGE RETURN
 JMP RP6
RP5 LXI H,RPRM  'REPLACE:' PROMPT
 LXI D,RTMP-1  REPLACEMENT STOREAGE
 CALL GPAT
RP6 CALL CRLF
*
*  CALCULATE DIFFERENCE OF LENGTHS
*
 LDA PTMP-1
 MOV B,A
 LDA RTMP-1
 SUB B
 STA DIFF  DIFFERENCE OF LENGTHS
 XRA A
 STA NCHNG  INITIALIZE NUM. PAT'S CHANGED
 LHLD BOSP  BEGINING OF SEARCH POINTER
NMCH SHLD RADR  ADDR. OF CURRENT LINE R.L.
 MVI A,0FFH
 STA CCC  SET CURRENT CHAR. COUNT
NM1 INX H
NM2 SHLD ATMP  BEGINING OF CURRENT STRING
 LXI D,CCC  CURRENT CHAR. COUNT
 LDAX D
 INR A  INCREMENT CHAR. COUNT
 STAX D
 INX D  PATTERN LENGTH
 LDAX D
 MOV C,A  COUNTER FOR SEAR ROUTINE
 INX D  PATTERN TO COMP. AGAINST
 MOV A,M  GET CURRENT CHARACTER
 CPI 0DH  CHECK FOR CARRIAGE RETURN
 JNZ EOL2  IS NOT CHECK FOR PAT. MATCH
EOL INX H  WAS CR SO NEXT CHAR. IS RL
 MVI A,2+80H  END OF SEARCH MARKER
 CMP M  SEE IF AT END OF SEARCH
 JNZ NMCH  WE'RE NOT THERE YET
EOL1 LDA EOSC  GET CHAR. TO PUT BACK.
 MOV M,A  PUT IT BACK IN FILE
 CALL CRLF
 LDA NCHNG  GET NUM. PATTERNS CHANGED
 CALL DOUT  PRINT NUM. PATTERNS
 LXI H,NPAT  POINT TO NUM. PAT., PRINT
 CALL PRINT  IT AND GO HOME.
 JMP STRTED
EOL2 CALL SEAR  COMPARE STRINGS
 SHLD AT1  ADDR. OF CHAR. AFTER STRING
 LHLD ATMP  START OF LAST STRING
 JNZ NM1  NO MATCH. TRY AGAIN
 LDA DIFF  CHECK FOR FILE OVERFLOW
 ORA A
 PUSH H
 JZ EOL3  FILE WILL STAY SAME LENGTH
 JM EOL3  FILE WILL GET SHORTER
 LHLD EFP  CURRENT END OF FILE
 CALL ADR  CALCULATE NEW EFP
 XCHG
 LHLD EOSP  GET LAST USEABLE MEMORY LOCATION
 INX H  ADJUST IT A LITTLE
 MOV A,D  SEE IF EFP IS STILL
 CMP H  SMALLER THAN THE VALUE
 JC EOL3  IN EOSP
 MOV A,E
 CMP L
 JC EOL3
 CALL CRLF
 LXI H,FOFE  FILE OVERFLOW ERROR
 CALL PRINT  Print it.
 POP H  CLEAN UP STACK
 JMP OL3  RETURN TO EDITOR
EOL3 POP H
 LDA SMODE  SELECTED REPLACEMENT
 ORA A  OR NOT?
 JZ EOL4  IS NOT. REPLACE IT
 CALL OUTL  WANTS TO LOOK AT IT FIRST
 JZ NM1  DOESN'T WANT TO CHANGE IT
EOL4 LHLD RADR  GET ADDR. OF CURENT R.L.
 LDA DIFF  GET LENGTH DIFF. OF STRINGS
 ADD M  ADJUST RECORD LENGTH
 CPI MAXL+3  LONGER THAN MAXIMUM?
 JC EOL5  IF NOT GO AHEAD AND REPLACE
 MOV E,A  SAVE ADJUSTED LENGTH
 CALL CRLF
 LXI H,LOFE  'LINE OVERFLOW ERROR'
 CALL PRINT  PRINT ERROR COMMENT
 MOV A,E  GET LENGTH BACK
 SUI MAXL+2  CALCULATE OVERFLOW
 CALL DOUT  PRINT IT
 LXI H,INLN  REST OF ERROR COMMENT
 CALL PRINT  PRINT IT
 CALL OUTL  SHOW'EM WHICH LINE
 LHLD RADR  Skip to next line -- we can't change this one.
 MOV A,M  Get length of this line.
 CALL ADR  HL-> length byte of next line.
 DCX H  HL-> preceding CR.
 JMP EOL  Take care of end of line.
EOL5 MOV M,A  PUT NEW LENGTH IN FILE
 LDA NCHNG
 INR A
 STA NCHNG
 LDA RTMP-1  GET LENGTH OF PATTERN
 LXI H,CCC  ADJUST CURRENT
 ADD M  CHARACTER COUNT.
 DCR A
 MOV M,A  SAVE IT
 LDA DIFF  GET DIFF. OF LENGTHS
 ORA A  SET FLAGES
 LHLD AT1  ADDR. OF CHAR. AFTER STRING
 JZ MPAT  DIFF=ZERO. JUST MOVE PATT.
 JM CFIL  DIFF<ZERO. SHORTEN FILE.
 MOV B,M  SAVE CHAR. AFTER STRING.
 MVI C,3+80H  TERMINATOR FOR RMOV
 MOV M,C  PUT TERMINATOR IN FILE.
 LHLD EFP  HL GETS END OF FILE POINTER
 MOV E,L  DE ALSO GETS IT
 MOV D,H
 CALL ADR  ADD DIFF TO EFP
 SHLD EFP  PUT NEW EFP BACK
 CALL RMOV  OPEN FILE BY 'DIFF' AMOUNT
 MOV M,B  PUT CHAR. AFTER STRING BACK
 JMP MPAT  MOVE IN REPLACEMENT PATT.
CFIL MOV E,L  GET HERE TO SHORTEN FILE
 MOV D,H
 CALL SUBA  GET STARTING ADDR. FOR LMOV
 PUSH H  SAVE IT
 LHLD EFP
 MOV B,M  SAVE END OF FILE CHAR.
 MVI C,3+80H  TERMINATOR FOR LMOV
 MOV M,C
 POP H
 CALL LMOV  SHORTEN FILE
 MOV M,B  REPLACE END OF FILE MARKER.
 SHLD EFP  SAVE NEW END OF FILE ADDR.
 LHLD AT1  GET START OF NEXT STRING
 LDA DIFF  GET OFFSET AMOUNT
 CALL SUBA  CALCULATE NEW ADDR
MPAT SHLD AT1  SAVE IT
 LHLD ATMP  START TO REPLACE STRING
 LXI D,RTMP  POINT TO REPLACE STRING
 MVI C,0DH  TERMINATOR FOR LMOV
 CALL LMOV  MOVE IN NEW STRING
 JMP NM2  GO BACK FOR NEXT PATTERN
SUBA ADD L  THIS ROUTINE ADDS TWO'S
 MOV L,A  COMP. NUMBER IN ACC FROM HL
 RC .
 DCR H
 RET
GPAT PUSH D  THIS ROUTINE GETS PATTERNS
 CALL CRLF  FROM USER BY CALLING READ
 CALL PRINT  OUT PROMPT POINTED TO BY HL
 CALL PROMPT  GET INPUT STRING AND RETURN
 CPI MXPT+1  LENGTH IN ACCUMULATOR
 JC GP1
 CALL CRLF  PATTERN TOO LONG. TELL'EM
 LXI H,IBOE  'INPUT OVERFLOW' ERROR
 CALL PRINT
 POP H  CLEAN UP STACK
 POP H  AND AGAIN
 LXI D,-9  GET READY TO GO BACK
 DAD D  TO CALLING ROUTINE
 PCHL
GP1 POP D  GET LENGTH STORAGE LOCATION
 STAX D  STORE LENGTH
 INX D  PATTERN STORAGE ADDR.
 LXI H,IBUF  ADDR. OF IBUF
 MVI C,CR  DELIMITER FOR LMOV
 XCHG .
 CALL LMOV  MOVE PATTERN FROM IBUF
 MVI M,CR  END PATTERN WITH A CR (NOT COUNTED IN LENGTH)
 RET .  TO STORAGE.
OUTL CALL CRLF
 LHLD RADR  OUT CURRENT LINE TO
 INX H  CURRENT DEVICE
 CALL PRINT
 CALL CRLF
 LDA CCC  OUT 'CCC' SPACES
 ORA A  SET FLAGS
 JZ OL1  WE DON'T WANT TO OUT
 MOV C,A  256 SPACES!!!
 CALL BLKO
OL1 CALL CONIN  GET RESPONSE FROM USER
 ANI 7FH  CHUCK THE PARITY.
 CPI 1BH  ASCII ESCAPE?
 JNZ OL4
OL2 LHLD AT1  WANTS TO QUIT SO
OL3 INX H  FIND TERINATION CHAR.
 MOV A,M
 CPI 2+80H
 JNZ OL3
 JMP EOL1  GO BACK AND FINISH UP
OL4 LHLD ATMP
 CPI 'N'  SET FLAGS BEFORE RETURNING
 RZ
 CPI 'n'
 RET
LNFE LXI H,LNF  POINT TO PROMPT
 CALL PRINT  PRINT IT AND RETURN
 JMP STRTED
*
* This routine is used to find a ln in the file area
* which is greater than or equal to the current line number
*
FIND LXI H,ABUF+3  buffer address
 SHLD ADDS  Save address.
FIN1 LHLD BFP  begin file address
FI1 CALL EO1  Check for end of file.
 XCHG
 LHLD ADDS  Fetch find address.
 XCHG
 MVI A,4
 CALL ADR  ln address
 CALL COM0  Compare line numbers.
 RC
 RZ
FI2 MOV A,M
 CALL ADR  next line address
 JMP FI1
*
* This routine checks if the current address when
* searching through the file area is the end of file.
*
EO1 MVI A,EOF
 CMP M
 RNZ
 JMP LNFE  Line number wasn't found so forget it.
*
* This routine is used to compare two character strings
* of length 4.  On return zero flag set means both strings
* are equal.  Carry flag = 0 means string addressed
* by D,E was greater than or equal to character string
* addressed by H,L.
*
COM0 MVI C,4  string length
 MVI B,1  equal counter
 ORA A  Clear carry.
CO1 LDAX D  Fetch character.
 SBB M  Compare characters.
 JZ CO2
 INR B  Increment equal counter.
CO2 DCX D
 DCX H
 DCR C
 JNZ CO1
 DCR B
 RET
*
* This routine converts a binary value to ascii decimal
* digits and outputs the characters to the TTY.
*
DOUT CALL BIND  Convert value.
 LXI H,HCON  Get converted digits.
 CALL PRINT
 RET
*
* Convert the binary value in A into ascii decimal digits
* at HCON, terminated by a binary 0.
*
BIND LXI H,HCON  Conversion address.
 MVI B,100
 CALL BID1  Convert hundreds digit.
 MVI B,10
 CALL BID1  Convert tens digit.
 ADI '0'  Get units digit.
 MOV M,A  Store it.
 INX H
 MVI M,0  Terminate with binary zero for PRINT.
 RET
*
* Convert value in A to decimal.
*
BID1 MVI M,'0'-1  Initialize digit count.
BID2 INR M
 SUB B  Check digit.
 JNC BID2
 ADD B  Restore value.
 INX H
 RET
*
* Output a variable number of blanks.
*
BLKO MVI A,SPACE
 CALL CONOUT
 DCR C
 JNZ BLKO
 RET
*
* Output 'What?' message and return.
*
WHAT CALL OUST
 ASC /What?/
 DW 0A0DH
 DB 0
 JMP STRTED
MXPT EQU 30  MAXIMUM PATTERN LENGTH
MAXL EQU 64  MAXIMUM LINE LENGTH
FOFE ASC 'File will overflow buffer.'
 DB 0
NPAT ASC ' patterns changed.'
 DB 0
LOFE ASC 'line overflow of '
 DB 0
INLN ASC ' byte(s) in this line:'
 DB 0
LNF ASC 'Line not found'
 DB 0
IBOE ASC 'Input buffer overflow'
 DB 0
PPRM ASC 'Pattern'
 DB 0
RPRM ASC 'Replace'
 DB 0
CCC DS 1  CURRENT CHARACTER COUNT
 DS 1
PTMP DS MXPT+1  STOREAGE FOR PATTERN
 DS 1
RTMP DS MXPT+1  STORAGE FOR REPLACEMENT
NCHNG DS 1  NUMBER OF PAT'S CHANGED
DIFF DS 1  DIFF IN LENGTH OF PATTERNS
ATMP DS 2  BEGINING ADDR. OF PATTERN
AT1 DS 2  CHAR. AFTER PATTERN ADDR.
RADR DS 2  ADDR OF CURRENT RECORD LEN.
SMODE DS 1  SELECT OR NOT. 0 FOR NOT
RMODE DS 1  DELETE OR REPLACE. 0 = DEL
BOSP DS 2  BEGINING OF SEARCH ADDR.
EOSC DS 1  CHAR. AT END OF SEARCH
ADDS DS 2  Address for FIND.
HCON DS 4  Conversion address -- 3 digits + terminator.