*
*
*
*
*         *******     ********     ******     ********
*         **    **       **       **     *    *  **  *
*         **    **       **       **             **
*         *******        **       **             **
*         **             **       **             **
*         **             **       **     *       **
*         **          ********     ******        **
*
*
*          A video display design editor for use with
*             the SOL computer and a Helios disk.
*                     Version 1.4 (Mod 0)
*
*                         Written by:
*
*                       Stephen Maguire
*                      P.O.  Box 3742 DT
*                     Anchorage, AK 99510
*
*                     Copyright (C)  1981
*                     All rights reserved
*
*
*
*
 ORG 100H
 XEQ $+3  Bypass the jump statement
*
*  Screen equates
*
SCREEN EQU 0CC00H  Upper-left hand side of screen
TOP EQU 0CBH  Just above screen
BOT EQU 0D0H  Just below the screen
*
*  Cursor key equates (high bit not striped)
*
CHUP EQU 97H  Move cursor up key
CHRGT EQU 93H  Move cursor right
CHLFT EQU 81H  Left
CHDWN EQU 9AH  Down
CHMODE EQU 80H  Exit the editor key
CHLOAD EQU 8CH  Abort edit key
CHHME EQU 8EH  Reverse polarity key (inverse <--> normal)
CHCLR EQU 8BH  Clear the current picture
*
CHLF EQU 0AH  Linefeed for printing
CHCR EQU 0DH  Carriage return
*
*  Copy in all of the system equates
*
 COPY NPTDEFS
*
 JMP INIT  If it is re-entered, ingore all disk operations
*
 LHLD SYSGLO  Set the Level-1 error trap address
 LXI D,GLERM  for returning to this program upon errors
 DAD D
 MVI M,-1
 INX H
 MVI M,-1
*
 LXI SP,STACK  Set up our stack
*
 XRA A  Set the output file status to "unprotected"
 STA PRTCT
*
*----------------------------------------*
*  Process the input file name.          *
*----------------------------------------*
*
CMD0 LXI D,FNAM1  Point to the file name receiving area
 MVI A,PSN  Get the file name
 CALL PSCAN
 STA LSTCHR  Save the last character read
*
CMD1 LXI H,ILGIFN  Illegal file name message
 JC ABTERR  If illegal name, then error
 LXI H,EXPIFN  Expected a file name error message
 JZ ABTERR  If no name, then error
*
 LXI D,FNAM1  Get the attribute byte of this file
 CALL GETAT
 STA FLAT1  Save it for later
 JC CMD2
*
*----------------------------------------*
*  If there is an error in the file name *
*  check it out here.                    *
*----------------------------------------*
*
 LXI H,ILGIFN  If it is an illegal file name, tell which one
 CPI ERINM
 JZ ABTERR
*
 CPI ERNEX  Is the file non-existent?
 JNZ ERROR  Give a serious abort if that's not the case
*
 LXI H,FDNE  Print the file does not exist message
 CALL PRINT
*
 CALL INPUT  Does he want the file created?
 CALL OUTPUT  Put out the answer
 ANI 5FH  Wait for a reply, then make it upper case
 CPI 'Y'
 JNZ RABRT  If he doesn't, then abort
*
 LXI D,FNAM1  Create the file
 LXI H,FNAM1
 MVI A,PSC+40H
 CALL PSCAN
*
 JMP CMD1  Go back up to check for any errors
*
*----------------------------------------*
*  The file is legal, check protection   *
*----------------------------------------*
*
CMD2 ANI PREA  Is the input file read protected?
 LXI H,IFLPRT  Abort if so
 JNZ ABTERR
*
 CALL DELM  Go see if command ended with a legal delimiter
 CPI ','  Was the delimiter a comma?
 JNZ CMD3  If not, no more command line
*
*----------------------------------------*
*  Process the output file name.         *
*----------------------------------------*
*
 LXI D,FNAM2  Create the output file if is doesn't exist
 MVI A,PSC  Do it now
 CALL PSCAN
 STA LSTCHR  Save the last character scanned
*
 LXI H,ILGOFN  If it's an illegal name, say so
 JC ABTERR
*
 LXI H,EXPOFN  Abort if the command is like "PICT filename,;"
 JZ ABTERR  Give the "output file expected" error
*
 LXI D,FNAM2  Get the attribute byte for this file
 CALL GETAT
*
 LXI H,ILGOFN  If the output file name is illegal, abort
 JNC ABTERR
*
 ANI 7FH  Strip off the undefined portion
 STA FLAT2  Save it for later
*
*----------------------------------------*
*  Determine which file is the out file. *
*----------------------------------------*
*
 LDA LSTCHR  Get the last character scanned
 CALL DELM+6  The comma is not legal this time
CMD3 LDA FLAT2  Get the file number
 LXI H,FNAM2
 ORA A  Is the output different from the input file?
 JP CMD4  Yes, go move the file name into a text message
*
 LDA FLAT1  No, they are the same
 LXI H,FNAM1
*
CMD4 SHLD OUTFIL  Save the output file name address
*
 ANI PWRI+PALO  Is the file write or extend protected?
 JZ CMD5  Go open the file if all is okay
*
 LXI H,OFLPRT  Point to the error message
 CALL PRINT
*
 CALL INPUT  Ask if he would like to load the file anyway
 CALL OUTPUT  Send out his answer
 ANI 5FH  Convert any lower case answers
 CPI 'Y'
 JNZ RABRT  If he doesn't want to load, abort
*
 MVI A,-1  Indicate the the output file is protected
 STA PRTCT
*
*----------------------------------------*
*  Open the file; check if the file is   *
*  a device file -- abort if so.         *
*----------------------------------------*
*
CMD5 LXI D,FNAM1  Open the file now
 CALL OPEN
*
 LXI H,ILGIFN  Print the error message
 JZ ABTERR
*
*----------------------------------------*
*  Read in the file now.  Abort if the   *
*  file is too long to fit in the buffer *
*----------------------------------------*
*
 LXI D,BUFFER  Find the length of the buffer
 CALL SBTRCT
 LXI B,401H  Maximum length
*
 LDA FILEN  Get the file number
 LXI D,BUFFER  Point to the recieving buffer
 CALL SYS  Go read in the file
 DB RBLOP
 JMP CMD6
*
 LXI H,FTBIG  If we got here, the file is too big
 JMP ABTERR
*
*----------------------------------------*
*  If the read was okay, continue here   *
*----------------------------------------*
*
CMD6 CPI EREOF  If EOF has been reached, ignore it
 JNZ ERROR
*
 XCHG .  Blank fill the rest of the file
CMD7 MVI M,' '  Put in the blank
 MOV A,H  Are we done?
 CPI <BOTTOM  Test the high byte
 INX H  Bump pointer in case not
 JNZ CMD7  Continue blanking if necessary
*
 CALL CLOSE  Close the input file
*
 LHLD OUTFIL  Go open the output file
 XCHG .
 CALL OPEN  Do it now
*
 LXI H,ILGOFN  Abort if illegal output file name
 JZ ABTERR
*
*----------------------------------------*
*  Put some value in text messages that  *
*  will be printed at some time or other *
*----------------------------------------*
*
 LXI H,SGNON  Print the sign on message
 CALL PRINT
*
CMD8 CALL INPUT  Wait for a carriage return
 CPI CHCR
 JNZ CMD8
*
 CALL CLEAR  Clean up the screen
*
 LHLD SYSGLO  Tell PTDOS not to strip the MSB on input
 LXI D,GLBIO
 DAD D
 MOV A,M
 STA GLBSET  Save the value for restoration upon exit
 MVI M,-1
*
 JMP INIT  Go start working
*
*----------------------------------------*
*  Abort with an error message pointed   *
*  to by HL.                             *
*----------------------------------------*
*
ABTERR PUSH H  Save the message location
 LXI H,EDTABT  Send out the abort message
 CALL PRINT
 POP H  Get back unique message location
 CALL PRINT  Now, send that out
 JMP RABRT  Go abort
*
*----------------------------------------*
*  If there is an error, abort here.     *
*----------------------------------------*
*
ERROR LXI H,DVCFL  Screen out device driver errors
 CPI ERDRI
 JC ERR1  Not a device driver error, abort here
 CPI ERNCT
 JC ABTERR  It is a device driver error, abort elsewhere
*
ERR1  STA ERRCDE  Otherwise setup for abort
*
 CALL CLOSE  Close the file in case it was open
*
 XRA A  Set registers before aborting
 LXI H,-1
 CALL UTIL  Do the abort
 DB UXOP
BADABT JMP BADABT  Loop forever if bad abort
 DB -1
ERRCDE DB -1
*
*----------------------------------------*
*  Open the file whose name is pointed   *
*  to by the register pair DE.           *
*                                        *
*  On return, zf=1 if error              *
*----------------------------------------*
*
OPEN LXI H,0  Give it a static buffer
 CALL SYS
 DB OPEOP
 XRA A  Set the zero flag if any errors occur
 RET .
 NOP .  Don't delete this NOP.  It's needed!!
*
 STA FILEN  Save the file number in case it was open
*
 MOV A,B  Get the file type
 ORA A  If it's zero, then it is a device file
 LXI H,DVCFL  Go abort if so
 JZ ABTERR
*
 RET .
*
*----------------------------------------*
*  Close the current file.               *
*----------------------------------------*
*
CLOSE LDA FILEN  Close the file
 CALL SYS
 DB CLOOP
 JMP BADABT
*
 CALL REOCMD  Go scratch any of the unused command string
*
 RET .
*
*----------------------------------------*
*  GETAT -- get the file attributes of   *
*  the file name pointed to by DE.  The  *
*  attribute byte is returned in A.      *
*----------------------------------------*
*
GETAT LXI H,STORAGE  Point to receiving area
 CALL SYS  Go get the information
 DB INFOP
 STC .  On error, return with the carry reset
 CMC .
 RET .
*
 LDA STORAGE+14  Get the attribute byte
*
 STC .  Set the carry for no error return
 RET .
*
*----------------------------------------*
*  DELM -- check for a legal delimeter.  *
*  Abort if no good.                     *
*----------------------------------------*
*
DELM LDA LSTCHR  Get the character
 CPI ','  If it's a comma, then okay
 RZ .
 CPI ';'  If a semicolon, still okay
 RZ .
 CPI CHCR  If it's not a C/R, then it's an illegal character
 RZ .
*
 LXI H,SYNTX  Give a syntax errkr
 JMP ABTERR
*
*----------------------------------------*
*  Read in the unused portion of the     *
*  command.                              *
*----------------------------------------*
*
REOCMD LDA LSTCHR  Get the last character read
*
 CPI CHCR  If it's a carriage return, then all done
 RZ .
 CPI ';'  A semicolon does it too
 RZ .
*
 MVI A,PSONE  Get the next character
 LXI D,STORAGE
 CALL PSCAN
 JMP REOCMD+3  Loop until the end of the command has been found
*
*----------------------------------------*
*  Various sign on/off messages.         *
*----------------------------------------*
*
 ASCF 0  Assemble with short ASCII printout
*
FDNE DB CHCR,CHLF
 ASCZ "File does not exist, create? "
*
SGNON DB CHCR,CHLF,CHLF
 ASC "PICT 1.4 (mod 0)"
 DB CHCR,CHLF
 ASC "PROTEUS Software Library"
 DB CHCR,CHLF
 ASC "Written by: Stephen Maguire"
 DB CHCR,CHLF,CHCR,CHLF
 ASCZ "C/R to continue: "
*
*----------------------------------------*
* All of the messages printed upon abort *
*----------------------------------------*
*
EDTABT DB CHCR,CHLF
 ASC "Pict aborted"
 DB CHCR,CHLF,0
*
FTBIG ASCZ "The file is not a picture file"
IFLPRT ASCZ "The input file is read protected"
*
OFLPRT ASC "The output file is protected."
 DB CHCR,CHLF
 ASCZ "Load input file for viewing only? "
*
SYNTX ASCZ "Illegal character in command"
DVCFL ASCZ "Device files cannot be edited"
ILGIFN ASCZ "The input file name is illegal"
EXPIFN ASCZ "The input file name is missing"
ILGOFN ASCZ "The output file name is illegal"
EXPOFN ASCZ "The output file name is missing"
*
*----------------------------------------*
*  Sign off information/verify message.  *
*----------------------------------------*
*
SGNOFF DB CHCR,CHLF
 ASC "*** Pict exit"
 DB CHCR,CHLF,CHCR,CHLF
 ASC "File start address: "
BEGADR ASC "0000"
 DB CHCR,CHLF
 ASC "File end address: "
ENDADR ASC "0000"
 DB CHCR,CHLF
 ASC "File count: "
FLECNT ASC "0400"  This will always be 400H (i.e. 1 screenful)
 DB CHCR,CHLF,CHCR,CHLF
 ASCZ 'OK to write to "'
QUESTN ASCZ '"? '
*
ABTMES DB CHCR,CHLF
 ASCZ 'Abort? '
*
*----------------------------------------*
*  This is the main body of the program  *
*----------------------------------------*
*
INIT LXI H,SCREEN  Put cursor at the top
 SHLD POINT
*
FILL CALL CLEAR  Blank the screen
 LXI B,BUFFER  Point to the internal buffer
 LXI H,SCREEN  And, point to the screen
FIL1 MOV A,B  Put the buffer on the screen
 CPI <BOTTOM Are we through moving the buffer?
 JZ THRU  Yep, so stop
 LDAX B  No, get the character
 MOV M,A  Put it on the screen
 INX B  Increment the buffer pointer
 INX H  Increment the screen pointer
 JMP FIL1
*
THRU LHLD POINT  Get present cursor location
 MOV A,M  Get character in that position
 STA CHAR  and save it
 ADI 80H  Inverse the character
 MOV M,A  Now put it on the screen
*
MOVE LXI H,1500H  Set time length between blinks
 PUSH H  Save the blink count
 CALL CONTST  has he typed a key? (test keyboard status)
 POP H  Get back the blink count
 JNZ MOV2  If so go process it
 DCX H  Is it time to blink?
 MOV A,H
 ORA L  Let's check
 JNZ MOVE+3  Nope, go check the input
*
 MVI A,80H  Reverse the cursor polarity
 LHLD POINT  Get the character at cursor position
 ADD M  Change the character now
 MOV M,A  Put it to the screen
 JMP MOVE  Go check for input
*
MOV2 CALL INPUT  Pick up the character
 PUSH PSW  Save the character
 LXI D,OFFST  Distance between screen and buffer
 LHLD POINT  Get the present cursor position
 LDA CHAR  Put original character to the screen
 MOV M,A
 POP PSW  Now get the character back
*
 CPI CHUP  Are we moving the cursor up?
 JZ CURUP
 CPI CHLFT  How about left?
 JZ CURLF
 CPI CHRGT  Let's check for right
 JZ CURGT
 CPI CHDWN  Are we moving down?
 JZ CURDWN
 CPI CHHME  Do we want inversed print?
 JZ INVRS
 CPI CHMODE  Are we finished?
 JZ EXIT
 CPI CHLOAD  Are we aborting?
 JZ RABORT
 CPI CHCLR  Are we clearing the old picture?
 JNZ POKE  Nope, must be a printable character
*
*----------------------------------------*
* He's typed "CLEAR", was it by mistake? *
*----------------------------------------*
*
 CALL CLEAR  Let's ask
 LXI H,CLRCHK  Print out the question
 CALL PRINT
 CALL INPUT  Wait for an answer
 ANI 5FH  Convert any lower case to uppercase
 CPI 'Y'  Yes?
 JNZ FILL  No, it WAS a mistake
*
 LXI H,BUFFER  Point to the buffer
 CALL CLR  Clear the buffer
 JMP INIT  Go start over
*
CLRCHK DB CHCR,CHLF
 ASCZ 'Clear picture? '
*
*----------------------------------------*
*  Not a special character, print it.    *
*----------------------------------------*
*
POKE LHLD POINT  Get old cursor position
 MOV B,A   Get character
 LDA INVOP  Inverse it if wanted
 ADD B  Now put it to the screen
 MOV M,A
*
 PUSH H  Save the cursor position
 DAD D  Now get the buffer position
 MOV M,A  Put the character in the buffer
*
 POP H  Get the screen location back
 INX H  Advance the cursor
POK0 MOV A,H  Are we off the bottom?
 CPI BOT  Let's check
 JNZ POK1  Nope, we're okay
 MVI H,0CCH  Oops, we have to fix it
*
POK1 SHLD POINT
 JMP THRU  Go put cursor on the screen
*
*----------------------------------------*
*  Move the cursor up; off the top?      *
*----------------------------------------*
*
CURUP LHLD POINT  Get the cursor position
 LXI D,0FFC0H  Move it up
 DAD D
 MOV A,H  Are we off the top?
 CPI TOP
 JNZ POK1  Nope, so print the cursor
*
 MVI H,0CFH  Yes, put it at the bottom
 JMP POK1  And print the cursor
*
*----------------------------------------*
*  Move the cursor left; off the side?   *
*----------------------------------------*
*
CURLF LHLD POINT  Get the cursor position
 DCX H  Move left one space
 MOV A,L  Are we over the edge?
 ANI 3FH  Set up for checking
 CPI 3FH
 JNZ POK1  No, we're okay
*
 LXI D,0040H  Yes, so wrap around
 DAD D  Do it now
 JMP POK1  Go print the cursor
*
*----------------------------------------*
*  Move the cursor right; off the side?  *
*----------------------------------------*
*
CURGT LHLD POINT  Get the cursor position
 INX H  Move right once
 MOV A,L  Are we on this edge?
 ANI 3FH
 JNZ POK1  No, so print the cursor
*
 LXI D,0FFC0H  Yes, wrap around
 DAD D
 JMP POK1  Go print the cursor
*
*----------------------------------------*
*  Move the cursor down; off the bottom? *
*----------------------------------------*
*
CURDWN LHLD POINT  Get the cursor position
 LXI D,0040H  Move down once
 DAD D
 JMP POK0  Go check is out
*
*----------------------------------------*
*  Clear screen and buffer memories.     *
*----------------------------------------*
*
CLEAR XRA A  Clear A
 OUT 0FEH  Set the Sol screen parameters
 OUT 0C8H  Set the VDM also
 LXI H,SCREEN
CLR LXI B,400H
 MVI M,' '  Push in a blank
 DCX B  Subtract one from the count
 INX H  Increment the pointer
 MOV A,B  Are we through yet?
 ORA C  Let's check
 JNZ CLR+3  Nope, keep blanking
 RET  Yes
*
*---------------------------------*
*  Subtract the DE pair from HL.  *
*---------------------------------*
*
SBTRCT MOV A,D  Take the one's complement of DE
 CMA .
 MOV D,A
 MOV A,E
 CMA .
 MOV E,A
 INX D  Now, make it the two's complement
 DAD D  Add it to HL
 RET .  Return with HL=HL-DE, DE=-DE
*
*---------------------------------*
*  Send out a four digit ASCII    *
*  string representing the value  *
*  of the DE register pair.       *
*---------------------------------*
*
PRDE MOV A,D  Get the high byte
 CALL PRHEX  Send it out
 MOV A,E  Now, send out the low byte
*
PRHEX PUSH PSW  Save the byte
 RLC .  Pick up the high nybble
 RLC .
 RLC .
 RLC .
 CALL PRH1  Send out the character
 POP PSW  Now, get the low nybble
*
PRH1 ANI 0FH  Strip off unwanted bits
 CPI 0AH  Is it a number? (0-9)
 JC PRH2  If so, go convert it to ASCII
 ADI 7  No, it's a letter (A-F)
*
PRH2 ADI 30H  Make it ASCII
 MOV M,A  Put it out now
 INX H
 RET .  Exit
*
*---------------------------------*
*  All I/O calls are made here.   *
*---------------------------------*
*
INPUT CALL CONIN  Go check the keyboard
 RET .
 DS 5  Leave some room for user modification
*
* Note: MSB is left unstripped to distiguish between
*       Control codes and the cursor keys.
*
OUTPUT PUSH B
 PUSH H
 CALL CONOUT  Call PTDOS output routine
 POP H
 POP B
 RET .
*
*----------------------------------------*
*  The exit routine; ask if he's sure.   *
*----------------------------------------*
*
EXIT CALL CLEAR  Clear the screen
*
 LXI H,BEGADR  Set up the buffer's beginning address
 LXI D,BUFFER
 CALL PRDE
*
 LXI H,3FFH  Set up the ending address
 DAD D
 LXI D,ENDADR
 XCHG
 CALL PRDE
*
 LXI H,SGNOFF  Now, print out the signoff message
 CALL PRINT
*
 LHLD OUTFIL  Send out the output file name
 CALL PRINT
*
 LXI H,QUESTN  Print the question: "Save?"
 CALL PRINT
*
 CALL INPUT  Wait for the answer
 CALL OUTPUT  Send it out
 ANI 5FH  Convert any lower case to uppercase
 CPI 'Y'
 JNZ FILL  Not "YES", so must have been a mistake
*
 LDA FILEN  Rewind the file pointer
 LXI D,0
 CALL SYS
 DB SPAOP
 JMP ERROR  Report any errors
*
 LDA FILEN  Get the file number
 LXI B,400H  The file is 1k long
 LXI D,BUFFER  Tell where the file is
 CALL SYS
 DB WBLOP  Write out the file
 JMP ERROR
*
 LDA FILEN  End-file the file
 CALL SYS
 DB EOFOP
 JMP ERROR
 JMP RABRT  Do a clean abort
*
*----------------------------------------*
*  He's hit the abort key; ask if sure.  *
*----------------------------------------*
*
RABORT CALL CLEAR  Clear the screen
 LXI H,ABTMES  Print out the question
 CALL PRINT
*
 CALL INPUT  Wait for input
 CALL OUTPUT  Send out the answer
 ANI 5FH  Convert lower case to upper
 CPI 'Y'
 JNZ FILL  No, he doesn't want to abort
*
RABRT LHLD SYSGLO  Restore the original PTDOS binary I/O status
 LXI D,GLBIO  Calculate its location
 DAD D
 LDA GLBSET  Get the original value
 MOV M,A  Restore it
*
 CALL CLOSE  Close the output file
 CALL SYS  Exit to PTDOS
 DB RETOP
*
*----------------------------------------*
*  Send out the message pointed to by HL *
*----------------------------------------*
*
PRINT MOV A,M  Get character to be printed
 ORA A  Are we through?
 RZ . If so stop
 CALL OUTPUT
 INX H
 JMP PRINT  And print it
*
*----------------------------------------*
*  Reverse the polarity of typed chars.  *
*----------------------------------------*
*
INVRS LDA INVOP  Change color of characters
 ADI 80H  This will change it from inversed
 STA INVOP  to normal, or vice versa
 JMP MOVE
*
*----------------------------------------*
*  Data storage area.                    *
*----------------------------------------*
*
POINT DW 0  Points to the cursor location on the screen
CHAR DB 0  The character over which the cursor sits
INVOP DB 0  The polarity status
*
LSTCHR DB 0  Last character scanned by PSCAN
FILEN DB 0  The currently open file's file-number
FLAT1 DB 0FFH  Attribute byte of the input file
FLAT2 DB 0FFH  Attribute byte of the output file
OUTFIL DS 2  Points to the output file name (FNAM1 or FNAM2)
PRTCT DS 1  The output file protect status (0 = unprotected)
GLBSET DS 1  The PTDOS binary I/O status
*
 DB 89H  Source file: type = 09  (picture file)
 DW 100H
 DB 0
FNAM1 DS 20
*
 DB 89H  Output file: type = 09  (picture file)
 DW 100H
 DB 0
FNAM2 DS 20
*
STORAGE DS 20  Scratch pad for PSCAN
*
 DS 25  Some stack space
STACK EQU $-1
*
HERE EQU <$
 ORG 100H*HERE+100H
BUFFER DS 400H
BOTTOM EQU $
OFFST EQU BUFFER-SCREEN
*
 END