( Character to Graphic Print Routines )                         
0 VARIABLE CHBASE  DECIMAL                                      
: C.                    ( FROM  TO  ---  )                      
  320 OVER + SWAP    ( 320 = 40 * 8 )                           
  DO                                                            
    DUP C@ I C! 1+                                              
  40 +LOOP                                                      
  DROP ;                                                        
                                                                
: (C.")                ( TO --- )                               
  R COUNT DUP 1+ R> + >R                                        
  OVER + SWAP                                                   
  DO                                                            
    DUP I C@ 8 * CHBASE @ + ROT C. 1+                           
  LOOP DROP ;    ;S                                             
                                                                
 ( Screen # 1 XXXXX )                                           
 : LABEL  0 VARIABLE -2 ALLOT ;                                 
 : LISTS  OVER + SWAP DO I LIST LOOP ;                          
 : LOADS  OVER + SWAP DO I LOAD LOOP ;                          
 : 'S     SP@ 2 - ;                                             
 : DEPTH  S0 @ 'S - 2 / 2 - ;                                   
 : LOAD-ED   5 6 LOADS ;                                        
 : LOAD-$   15 4 LOADS ;                                        
 : NOT 0= ;                                                     
 : UMOVE   >R OVER OVER U< R> SWAP                              
           IF  <CMOVE  ELSE CMOVE ENDIF ;                       
 : MTB  EMPTY-BUFFERS  ;                                        
 : DCX  DECIMAL ;                                               
 14 LOAD                                                        
 2 3 LOADS   5 6 LOADS                         DECIMAL ;S       
                                                                
 ( DUMP routine )                                               
                                                                
 HEX                                                            
                                                                
 : .ADDR       100  /MOD  .HEX  .HEX  ." :  " ;                 
                                                                
 : .DUMP       DUP .ADDR DUP 10 + SWAP DO                       
               I C@ .HEX SPACE LOOP ;                           
                                                                
 : DUMP        OVER + SWAP DO CR I .DUMP 10 +LOOP ;             
                                                                
 DECIMAL    ;S                                                  
                                                                
                                                                
                                                                
                                                                
                                                                
 ( INDEX, TRIAD, LINE, E, COPY, CLEAR )     HEX                 
                                                                
 : INDEX        CR 1+ SWAP DO                                   
                   CR I 3 .R SPACE 0 I .LINE                    
                LOOP CR ;                                       
 : TRIAD        CR 3 / 3 * 3 OVER + SWAP                        
                DO CR I LIST LOOP CR                            
                CR CR ;                                         
 : LINE         DUP FFF0 AND 17 ?ERROR SCR @ (LINE) DROP ;      
 : E            LINE C/L BLANKS UPDATE ;                        
 : CLEAR        SCR ! 10 0 DO FORTH I E LOOP ;                  
 : COPY         B/SCR * OFFSET @ + SWAP B/SCR * B/SCR OVER      
                + SWAP DO DUP  FORTH I BLOCK 2 - ! 1+           
                UPDATE LOOP DROP FLUSH ;                        
                                                                
                                                 DECIMAL ;S     
 ( CASE:, TABLE, ARRAY, CARRAY, CVARIABLE, CCONSTANT )          
                                                                
 : GODO:        <BUILDS SMUDGE ] DOES> SWAP 2* + @ EXECUTE ;    
                                                                
 : ARRAY        <BUILDS 2* ALLOT DOES> SWAP 2* + ;              
                                                                
 : CARRAY       <BUILDS ALLOT DOES> SWAP + ;                    
                                                                
 : TABLE        <BUILDS 0 DO , LOOP DOES> SWAP 2* + @ ;         
                                                                
   HEX                                                          
                                                                
                                                                
                                                                
                                                                
                                        DECIMAL ;S              
 ( Proteus Fisk Forth                Forth Video Editor )       
                                                                
 HEX                                                            
                                                                
 VOCABULARY VEDIT  IMMEDIATE    VEDIT  DEFINITIONS              
                                                                
 0 VARIABLE VPTR      0 VARIABLE INSRT                          
                                                                
 : CSHOW    VPTR @ DUP C@ 80 OR SWAP C! ;                       
 : CBLANK   VPTR @ DUP C@ 7F AND SWAP C! ;                      
                                                                
 : TAB      CBLANK VPTR @ 8 + CFF8 AND   ( 8 place tab stop )   
            0C00 OR VPTR ! CSHOW ;                              
                                                                
                                             DECIMAL   ;S