*
 ASCF 0   Do not print out ASCII assemblies
*
*
*        Wiz-Print     -- A Spooling Program for use
*        version 1.4      with the North Star MDS
*
*
*
DRVRAD EQU 02D00H  Print driver routine address
*
*BUFSIZ EQU 200H  Each I/O buffer is 0.5K long
BUFSIZ EQU 400H  Each I/O buffer is 1K long
*BUFSIZ EQU 800H  2K buffers
*
BUFSEC EQU BUFSIZ/100H
DSKBUF EQU 40H  sectors long
DATA EQU 38H  A NOP instruction used to flag data areas
*
DOS EQU 2000H
CIN EQU 10H
*
TRUE EQU 0
FALSE EQU -1
*
CHCR EQU 0DH
CHLF EQU 0AH
CHBEL EQU 7
CHRUB EQU 5FH
CHDEL EQU 7FH
*
 ORG DRVRAD
*
*
********************
*
*  Size the memory non-destructively
*
SETUP LXI SP,SETSTK
*
 MVI A,0C3H
 STA SETUP
 LXI H,DOS+DRET
 SHLD SETUP+1
*
SET0 LXI H,SGNON
 CALL OUTCHR
*
 LHLD MEMSIZ  If memory already sized,
 MOV A,H  no need to do it again
 ORA L
 JNZ SET2
*
 LXI H,MMMS1
 CALL OUTCHR
*
 LXI H,PRGEND  Point to first known good memory location
 MVI A,0AAH  This test byte has lots of one's and zero's
*
SET1 MOV B,M  Save the memory byte
 MOV M,A  Make the test
 CMP M
 MOV M,B  Restore the memory byte
*
 INX H  Bump the pointer
 JZ SET1  Loop up if test says memory is okay
*
 DCX H  Adjust pointer to reflect last good byte
 DCX H
*
 SHLD MEMSIZ  Save the starting address
*
 PUSH H
 CALL OUTADD
 LXI H,MMMS2
 CALL OUTCHR
 POP H
*
SET2 LXI D,START-PRGEND
 DAD D
 SHLD STRTADR
*
 LXI D,SERIAL-START
 DAD D
 SHLD PRNTADR
*
*  Send out the "Change system? " message
*
 LXI H,CHGQST
 CALL OUTCHR
 CALL YESNO  Go get an answer
 JNZ NOCHG  Give current system configuration if NO
*
********************
*
*  Ask about the NorthStar DOS
*
 LXI H,DOS  Set the default DOS location
 SHLD DOSADR
*
 LXI H,DOSQST  Ask where the new DOS is located
 CALL OUTCHR
 LHLD DOSADR  Send out the default address
 CALL OUTADD
*
 CALL GETADD  Go get the address
*
 JZ WZLOD  If he gave an address, go save it
*
 SHLD DOSADR  Save the location of the DOS
*
********************
*
*  Ask where Wiz-Print should load
*
*
WZLOD LXI H,WIZ1QST  Send out the question
 CALL OUTCHR
 LHLD MEMSIZ
 CALL OUTADD
 LXI H,WIZ2QST
 CALL OUTCHR
 LHLD STRTADR
 CALL OUTADD
 LXI H,WIZ3QST
 CALL OUTCHR
*
 LHLD STRTADR
 CALL OUTADD
 CALL GETADD  Go get the address
*
 MVI L,0  It must be on a page boundry
*
 JZ PRTLOD
*
 SHLD STRTADR  Store the load address
*
********************
*
*  Ask about the print driver
*
*
PRTLOD LXI H,PRTQST  Ask where the print driver is
 CALL OUTCHR
 CALL GETADD  Go get the address
*
 JZ NSPRT  If no address was given, assume NorthStar I/O
*
 SHLD PRNTADR  Store it
 CALL CRLF
 JMP GETDVC
*
*  Check to see if it is a parallel or serial printer
*
NSPRT LXI H,DVETYP  Send out the question
 CALL OUTCHR
 CALL YESNO
*
 LXI D,SERIAL-START  Assume serial
 JNZ DVESRL
*
 LXI D,PARAL-START  Oops, it's parallel
*
DVESRL LHLD STRTADR  Initialize  the print driver location
 DAD D
 SHLD PRNTADR
*
*  Ask about the printer device number
*
GETDVC MVI A,1  Default is device #1
 STA DVCNUM
*
 LXI H,DVEQST  Print the question
 CALL OUTCHR
*
 MVI L,'7'  Highest device number allowed
 MVI C,1  Only 1 digit input allowed
 CALL GETADD+4  Go get the device number
*
 MOV A,L  Pick up the value
*
 JNZ $+8  If a number was given, store it
*
 LDA DVCNUM  Otherwise, pick up the default
 PUSH PSW
 CALL OUTH1  And send it out
 POP PSW
*
 STA DVCNUM  Store the device number
*
*  Ask for the name of the spool file
*
 LXI H,SPLINF  Explain the next question
 CALL OUTCHR
 LHLD STRTADR
 CALL OUTADD
 LXI H,SPLQST  Point to the question (GETNME will send it out)
 CALL GETNME  Go get the name
*
*  Move the new spool file name to the output file name location
*
MOVNME LXI H,NMEBUF  Point to the name buffer
 LXI D,OUTFLE  Point to the output file name buffer
 MOV A,M  Pick up the character
 STAX D  Transfer it to the other buffer
 INX H  Bump both pointers
 INX D
 ORA A  Are we through?
 JNZ MOVNME+6  Keep looping if not
*
*  Ask about the size to make the spool file
*
GETSZE MVI A,DSKBUF  Set it to the default value
 STA FLESIZ
*
 LXI H,SIZQST  Ask the question
 CALL OUTCHR
*
 MVI C,2  Only a two digit number is allowed
 CALL GETADD+2  Go get the hex value
*
 MOV A,L  Pick up the size
*
 JNZ $+8  If given, go make sure it's large enough
*
 LDA FLESIZ  Get the default value
 PUSH PSW
 CALL OUTHEX  Send it out
 POP PSW
*
 CPI BUFSIZ/100H*2  Is the size at least two buffers long?
 JNC $+2  If so, go determine how many buffers long it is
*
 MVI A,BUFSIZ/100H*2  Make it two buffers long
*
 STA FLESIZ  Store the value
*
 MVI B,0  Initialize the count
BLKS INR B  Increment the count
 SUI <BUFSIZ  Do a divide by repetitive subtraction
*
 JZ $+13  Exactly an integral number of buffers long
*
 JP BLKS  Not through dividing yet
*
 CMA .  A fractional part is left, make it positive
 INR A
*
 MOV C,A  Save it
 LDA FLESIZ  Get the file size
 ADD C  And make it an integral number of buffers long
 STA FLESIZ  Store it
*
 MOV A,B  Store the answer
 STA SPLSIZ
*
********************
*
*  Ask about his input/output setup
*
 MVI A,TRUE  The assumption is that standard I/O is in use
 STA STNDIO
*
 LXI H,IOQST  Ask the user just in case he isn't
 CALL OUTCHR
 CALL YESNO  Go get the answer
*
 JNZ NOCHG  If he does, then no changes necessary
*
 LXI H,CSTMES  Inform the user where modification information
 CALL OUTCHR  can be found
*
 MVI A,FALSE  Remember that non-standard I/O is in use
 STA STNDIO
*
********************
*
*  Before saving this version, relocate Wiz-Print to its
*  proper load address
*
*
*  Calculate the offset for relocation later
*
NOCHG LHLD START+1  Pick up jump address
 LXI D,START-INIT  Calculate offset for all jumps
 DAD D
*
 MOV A,H  Take the two's complement of the offset
 CMA .
 MOV H,A  (i.e., HL = -HL)
 MOV A,L
 CMA .
 MOV L,A
 INX H
*
 SHLD OFFSET  Save it
*
 LXI H,RELMES
 CALL OUTCHR
*
 LXI H,START  Start relocating here
*
*  Start by checking for 3-byte opcodes
*
RELOC MOV A,H
 CPI PRGEND/100H+1
 JZ SYSSET
*
 LXI D,OPCODES
*
REL0 LDAX D
 INX D
 ORA A
 JZ REL2
 CMP M
 JNZ REL0
*
 INX H
 MOV E,M
 INX H
 MOV D,M
*
 PUSH H
 LHLD OFFSET
 DAD D
 XCHG .
 LHLD STRTADR
 DAD D
 XCHG .
 POP H
 MOV M,D
 DCX H
 MOV M,E
*
REL1 INX H
 INX H
 JMP RELOC
*
REL2 LDAX D
 ORA A
 JZ REL3
 INX D
 CMP M
 JNZ REL2
 JMP REL1
*
REL3 MOV A,M
 CPI DATA
 JNZ REL1+1
*
REL4 INX H
 CMP M
 JNZ REL4
*
 INX H
 CMP M
 JNZ REL4
*
 JMP REL1+1
*
*
*
SYSSET LDA FIXDAT+2  Make the first fix
 STA FIX1+1
*
 ADI BUFSIZ/100H  Now the second and third fixes
 STA FIX2+1
 STA FIX3+1
*
********************
*
*  The system is all setup.  Display the current settings
*  and ask for verification.
*
 LXI H,LIST1  Send out DOS's load address
 CALL OUTCHR
 LHLD DOSADR
 CALL OUTADD
*
 LXI H,LIST2  Send out Wiz-Print's location
 CALL OUTCHR
 LHLD STRTADR
 CALL OUTADD
*
 LXI H,LIST3  Send out the print driver's location
 CALL OUTCHR
 LHLD PRNTADR
 CALL OUTADD
*
 LXI H,LIST4  Send out the print file name
 CALL OUTCHR
 LXI H,OUTFLE
 CALL OUTCHR
*
 MVI A,' '  Follow it with a little space
 CALL OUTH2+2
 MVI A,' '
 CALL OUTH2+2
 LDA FLESIZ  ...And then its file size
 CALL OUTHEX
 LXI H,LST4
 CALL OUTCHR
*
 LXI H,LIST5  Say which device the driver will recognize
 CALL OUTCHR
 LDA DVCNUM
 CALL OUTH1
*
 LXI H,LIST6  Print out the I/O configuration
 CALL OUTCHR
 LDA STNDIO
 CPI TRUE
 LXI H,STNDRD
 JZ $+3
 LXI H,CUSTOM
 CALL OUTCHR
*
 LXI H,ABTMES
 CALL OUTCHR
 CALL YESNO
 JZ SET0
*
 LXI H,NMEINF  Explain the next question
 CALL OUTCHR
*
ASKNME LXI H,NMEQST  Get the name of the initialized version
 CALL GETNME
 CALL CRLF
*
*  We've got a name, does it already exist?
*
 MVI A,1  Default drive number
 LXI H,NMEBUF
 CALL DOS+DLOOK
 JC NOTFND
*
*  The file already exists, better verify overwrite...
*
 LXI H,OVRWRT
 CALL OUTCHR
*
 CALL YESNO
 JNZ ASKNME  Don't overwrite
*
NOTFND LXI H,DENQST  Ask about density in use
 CALL OUTCHR
 CALL YESNO
*
 MVI A,80H
 JZ $+1
 XRA A
 STA DNSTY
*
********************
*
*  OPEN, CREATE, and SAVE the file
*
 LXI H,SV0MES  Print out the saving message
 CALL OUTCHR
 LXI H,NMEBUF
 CALL OUTCHR
 LHLD STRTADR  HL has the go address
 LXI D,NMEBUF  DE points to its file name
 LDA DNSTY  B has the file density
 MOV B,A
 MVI C,1  C has the file type (in this case a GO file)
 MVI A,PRGEND/100H+1*100H-START/100H+1  A tells how long
 CALL FILE  Go Open/Create the file
*
*  Tell whether file is  [New, [Old, or [Re-created
*
 MVI A,'['  Send out the bracket
 CALL OUTH2+2
*
 LDA FLESTT  Get the file status
 ORA A
 JNZ OLDFLE  It must be an old file
*
 LXI H,SV1MES  It is a new file, but is it re-created?
 LDA RECRET  Let's check
 ORA A
 JNZ $+3  No it's not, so print it out
*
 LXI H,SV15MES  Yes it is, so say so
*
 CALL OUTCHR  Send out the appropriate message
 JMP WRTFLE  ...And then save the file
*
OLDFLE LXI H,SV2MES  Send out the "[Old" message
 CALL OUTCHR
*
WRTFLE LXI H,SV3MES  Send out the "file] **" message
 CALL OUTCHR
*
********************
*
*  The file has been OPENed, and CREATEd, now SAVE it
*
 LHLD DSKADR  Pick up the disk address
 LXI D,START  DE points to where the data are in memory
*
 LDA DNUM  Get the drive number
 MOV C,A
 LDA DNSTY  Add in the density data
 ORA C
 MOV C,A  Put the information in C
*
 MVI B,OPWRT  We are going to do a write operation
 MVI A,PRGEND/100H+1*100H-START/100H+1  Tells length of file
*
 CALL DOS+DCOM  Go do a disk operation
*
********************
*
*  Send out the Wiz-Print execution message
*
 LXI H,GOMES  "Type GO"
 CALL OUTCHR
*
 LXI H,NMEBUF  "file name"
 CALL OUTCHR
*
LEAVE CALL CRLF  Send out a couple of CR/LF's
 CALL CRLF
*
 JMP DOS+DRET  Exit to the DOS
*
********************
*
*  Ask for a Yes/No answer.  Z-flag set if "Yes"
*
YESNO CALL INCHAR
*
 ANI 5FH  Convert possible lower case to uppercase
*
 CPI 'Y'  Is it a "Yes"?
 PUSH PSW  Save the flags
 LXI H,MESYES  Point to the "Yes" message
 JZ $+3  Go print it if "Yes"
*
 LXI H,MESNO  Else print "No"
*
 CALL OUTCHR  Do it
 POP PSW  Restore the flags
*
 RET .
*
********************
*
*  Send out a carriage return/line feed
*
CRLF MVI B,CHCR  Send out a carriage return
 XRA A  To device 0
 CALL DOS+PRNTR  Send it out
*
 MVI B,CHLF  Do the same for the line feed
 XRA A
 CALL DOS+PRNTR
*
 RET .
*
********************
*
*  Get one character of input from device 0
*
INCHAR XRA A  From device 0
 CALL DOS+CIN  Go ask for the character
*
 CPI 03H  Has he typed a CTRL-C ?
 RNZ .  Return if not
*
 JMP LEAVE
*
********************
*
*  Print out the four digit ASCII representation of HL
*
OUTADD MOV A,H  Get H
 CALL OUTHEX  Send it out
 MOV A,L  Get L and fall through to send it out
*
*  Output the two digit ASCII representation of A
*
OUTHEX PUSH PSW  Save it
 RLC  Bring the high nybble to the low
 RLC
 RLC
 RLC
 CALL OUTH1  Send it out
*
 POP PSW  Restore A for printing low nybble
*
OUTH1 ANI 0FH  Strip off unwanted bits
 CPI 0AH  Is it an alphabetic hex digit?
 JC OUTH2  If not, go print it
*
 ADI 7  Otherwise, add offset
*
OUTH2 ADI 30H  Convert it to ASCII
 MOV B,A  Put character in B
 XRA A  Send it to device 0
*
 JMP DOS+PRNTR  Go do it
*
*********************
*
*  Get a four digit hexadecimal number from the user.
*  Editing features are available.
*
GETADD MVI C,4  Maximum number digits allowed
 MVI L,'F'  Highest hex value allowed
*
 INR C  Adjust for later
 INR L
*
 MOV H,C  Used in DELT routine
*
 LXI D,ADDBUF  Point to the address buffer
*
 MVI B,20H
 CALL OUTH2+3
*
*  All done initializing, get address
*
ADDLP CALL INCHAR  Go get one character from user
*
 CPI CHRUB  Is it a rubout?
 JZ DELT
 CPI CHDEL  Or a delete?
 JZ DELT  Back up a character if so
*
 CPI CHCR  How about a carriage return?
 JZ ENTR  Go convert ASCII digits to binary if so
*
 CPI 'A'  Is lower to uppercase conversion necessary?
 JC $+2  Carry says no
 ANI 5FH  Do the conversion
*
 CMP L  Compare with highest hex value allowed
 JNC ADDLP  If value not in range, ignore it
 CPI '0'  Test lower bounds also
 JC ADDLP
*
 DCR C  Do we already have enough digits?
 INX B  Increment BC (really C) without changing flags
 JZ ADDLP  Loop back up and wait for RUBOUT or C/R if so
*
 STAX D  Store the character in memory
 INX D  Bump the buffer pointer
*
 DCR C  Decrement the digit count
 CALL OUTH2+2  Send out the character
*
 JMP ADDLP  All done
*
*  Rubout routine
*
DELT MOV A,C  Do we have nothing to delete?
 CMP H
 JZ ADDLP  Ingore if that's the case
*
 INR C  Add to the digit count
 DCX D  Decrement the buffer pointer
*
 MVI B,CHRUB  Send a rubout to device 0
 CALL OUTH2+3
*
 JMP ADDLP  And get some more input
*
*  Convert ASCII to binary
*
ENTR STAX D  Use carriage return as end-of-address mark
*
 LXI D,ADDBUF  Point to address buffer
 LXI H,0  Initialize binary value
 MVI B,0
*
CNVRT LDAX D  Get the digit
 INX D  Bump the pointer
*
 CPI CHCR  Are we all done?
 JZ ANYINPT  Check for no input case if so
*
 DAD H  We've got a legal digit,
 DAD H  multiply current value by 16
 DAD H
 DAD H
*
 CPI 'A'  Convert this digit to a 4-bit binary value
 JC $+2
 SUI 7  Convert alphabetic hex if necessary
 ANI 0FH  Strip off unwanted bits
*
 MOV C,A  Make value a full 16 bits
 DAD B  Add it to the current value
*
 JMP CNVRT  Keep converting
*
*  If no input was given, return with the Z-flag set
*
ANYINPT EQU $
 LDA ADDBUF Is the first character the end-of-number mark?
 CPI CHCR  Make the test
 RET .  Return with result in hand
*
ADDBUF DS 5  Storage for 4 digits + end of number mark
*
********************
*
*  Get a disk file name from the user.  Upon input, sytax
*  is checked and re-asks user for a file name if an error
*  is discovered.  Editing features are available.
*
GETNME SHLD PRMPT  On entry, HL points to prompt string
 CALL OUTCHR  Send out the prompt
*
 LXI D,NMEBUF  Point to the name buffer
 MVI C,11  An 11 character name or larger is illegal
*
*  Pick up the name
*
NMELP CALL INCHAR  Get an input character
*
 CPI CHCR  If it's a carriage return, check systax
 JZ CHKNME
*
 CPI 21H  Ignore all other control characters
 JC NMELP
*
 CPI 'a'  Is it lower case?
 JC $+2
 ANI 5FH  Convert to uppercase if necessary
*
 CPI CHRUB  Is it a rubout/delete?
 JZ ERASE  Go back up if so
*
 DCR C  Decrement the character count and set flags
 INX B  Increment the character count without modifying flags
 JZ NMELP  Loop back up if already enough characeters entered
*
 DCR C  Decrement the character count
 STAX D  Store the character
 INX D  Bump the pointer
 CALL OUTH2+2  Send the character out
*
 JMP NMELP  Go get some more
*
*  Delete one input character
*
ERASE MOV A,C  Is there nothing to delete?
 CPI 11
 JZ NMELP  Ingore rubout/delete if so
*
 DCX D  Decrement the buffer pointer
 INR C  Increment the character count
*
 MVI A,CHRUB  Send a rubout to device 0
 CALL OUTH2+2
*
 JMP NMELP  Go get some more
*
*  Check the systax of the file name:  filename{,drive}
*
CHKNME STAX D  Store the end-of-name mark
 LXI D,NMEBUF  Point to the buffer
 MVI C,8  Name is maximum of 8 characters long
*
CHKLP LDAX D  Get the character
*
 CPI ','  If it's a comma, then check for a legal drive #
 JZ CHKDRV
*
 CPI CHCR  End-of-name mark?
 JZ NMENOP  Go check if anything entered if so
*
 INX D  Bump the pointer
 DCR C  Decrement the character count
 JNZ CHKLP  If name is still < 8 chars long, then loop up
*
 LDAX D  Name is 8 characters long,
*
 CPI CHCR  It had better be followed by the end-of-name mark,
 JZ NMENOP
*
 CPI ','  Or by a comma
*
 LXI H,ILGNME
 JNZ NMERR  Report an error if it's not
*
CHKDRV INX D  Bump pointer past the comma
 LDAX D  Pick up the drive number
*
 CPI '1'  If it's less than '1' then error
 LXI H,ILGDRV
 JC NMERR
*
 CPI '4'+1  If it's greater than '4' then error
 JNC NMERR
*
 INX D  Bump pointer past drive number
*
NMENOP MVI A,' '  Follow the name with a blank (for DLOOK)
 STAX D
 INX D  Bump the pointer
 XRA A  End it all with a 0  (for OUTCHR)
 STAX D
*
 LDA NMEBUF+1 Get the first input character (past the blank)
 ORA A  Is it the 0?
*
 RNZ .  Return if a name has been entered
*
 LXI H,NONAME  Otherwise, tell that a name is needed
*
*  Illegal filename
*
NMERR CALL OUTCHR  Print out the error message
 LHLD PRMPT  ...And re-prompt for input
*
 JMP GETNME  Go get the name
*
*  Data storage used by GETNME
*
 DB ' '  Used for creating new files
NMEBUF DS 12  Storage for filename,drive + end of name mark
PRMPT DS 2
*
NONAME DB CHCR,CHLF
 ASC '   *** A file name must be given'
 DB 0
ILGDRV DB CHCR,CHLF
 ASC '   *** Illegal drive number'
 DB 0
ILGNME DB CHCR,CHLF
 ASC '   *** File name is too long'
 DB 0
*
********************
*
*  Print the text message pointed to by HL
*
OUTCHR MOV B,M  Pick up the character
 XRA A  Send it to the console
 CALL DOS+PRNTR  Go do it
*
 PUSH H
 PUSH B
*
 CALL DOS+CONTC
*
 LXI B,400
*
OUTWT DCX B  Wait a bit
 MOV A,B
 ORA C
 JNZ OUTWT
*
 POP B
 POP H
*
 INX H  Pick up the next character
 MOV A,M
 ORA A
 JNZ OUTCHR
 RET .  All done, return
*
*
*  Same as CREATE
*
FILE EQU $
*
 SHLD GOADR
 XCHG .
*
 STA NUMSEC
*
 STA FLESTT  Fill these with non-zero values
 STA RECRET
*
 MOV A,B
 STA FLEDEN
 ORA A
 JZ $+9
 LDA NUMSEC
 RAR
 ANI 7FH
 STA NUMSEC
*
 MOV A,C
 STA FLETYP
 SHLD FLELOC
*
FILE1 MVI A,1
 CALL DOS+DLOOK
*
 STA DNUM
 JNC FILE7
*
 XRA A  File is new
 STA FLESTT
*
 SHLD DSKADR
 SHLD 0BFFEH
 LDA DNUM
 LHLD FLELOC
 DCX H
 CALL DOS+DLOOK
 RC .  Return with carry set if no room in directory
*
 MVI D,0FFH
 MVI E,-8
 DAD D
*
 XCHG
 LHLD FLELOC
 XCHG
*
 MVI C,8
FILE2 LDAX D
 CPI ' '
 JZ FILE3
 CPI ','
 JZ FILE3
 MOV M,A
 INX D
 INX H
 DCR C
 JNZ FILE2
*
FILE3 INR C
 DCR C
 JZ FILE4
 MVI M,' '
 INX H
 JMP FILE3+1
*
FILE4 XCHG
 LHLD DSKADR
 XCHG .
 MOV M,E
 INX H
 MOV M,D
*
 INX H  Now, number of sectors
 LDA NUMSEC
 MOV M,A
 INX H
 MVI M,0
*
 INX H  Set type with density
 LDA FLEDEN
 MOV M,A
 LDA FLETYP
 ORA M
 MOV M,A
*
 ANI 7FH
 CPI 07H  Spoler?
 INX H
 MVI D,20H  Fill DE with blanks
 MVI E,20H
 JZ FILE5
*
 PUSH H
 LHLD GOADR
 XCHG .
 POP H
FILE5 MOV M,E
 INX H
 MOV M,D
 INX H
 MVI M,' '
*
 CALL DOS+DWRIT
*
 LHLD FLELOC
 JMP FILE1
*
FILE6 EQU $
 JMP 0C004H
*
FILE7 PUSH H
 MOV E,M  Get the disk address and save it
 INX H
 MOV D,M
 XCHG .
 SHLD DSKADR
 XCHG .
 INX H
 LDA NUMSEC
 CMP M
 JNZ FILE8
 INX H
 INX H
 LDA FLETYP
 MOV B,A
 LDA FLEDEN
 ORA B
 CMP M
 JNZ FILE8
 INX H
 LDA GOADR
 CMP M
 JNZ FILE8
 INX H
 LDA GOADR+1
 CMP M
*
FILE8 POP H
 RZ .
*
 MVI D,0FFH
 MVI E,-8
 DAD D
 MVI A,16
FILE9 MVI M,' '
 DCR A
 JNZ FILE9
*
 STA RECRET
*
 CALL DOS+DWRIT
*
 LHLD FLELOC
 JMP FILE1
*
DNUM DS 1  Drive number
*
********************
*
*  System output messages
*
SGNON DB CHCR,CHLF,CHCR,CHLF
 ASC 'Wiz-Print Version 1.4'
 DB CHCR,CHLF
 ASC 'By Stephen Maguire'
 DB CHCR,CHLF
 ASC 'Copyright (C) 1981'
 DB CHCR,CHLF,0
*
MMMS1 DB CHCR,CHLF
 ASC 'Memory available to '
 DB 0
*
MMMS2 DB 'H',CHCR,CHLF,0
*
CHGQST DB CHCR,CHLF
 ASC 'Wiz-Print is now set up to run with N* DOS release 5.2,'
 DB CHCR,CHLF
 ASC 'loading at 100H, and using standard input/output (I/O).'
 DB CHCR,CHLF
 ASC 'Wiz-Print can be changed to accomodate practically any'
 DB CHCR,CHLF
 ASC 'other system configuration, such as a DOS at F000H, or'
 DB CHCR,CHLF
 ASC 'with a print device number other than #1.  NOTE:  it is'
 DB CHCR,CHLF
 ASC 'possible to run as many as 8 devices simultaneously by'
 DB CHCR,CHLF
 ASC 'reconfiguring Wiz-Print with different device numbers'
 DB CHCR,CHLF
 ASC 'and different load addresses.'
 DB CHCR,CHLF,CHCR,CHLF
 ASC 'Would you like to reconfigure the system? (C/R = No) '
 DB 0
*
DOSQST DB CHCR,CHLF
 ASC 'For all of the following questions, typing a single'
 DB CHCR,CHLF
 ASC 'carriage return in response indicates that you would'
 DB CHCR,CHLF
 ASC 'like to use the default value.'
 DB CHCR,CHLF,CHCR,CHLF
 ASC 'DOS start address: '
 DB 0
*
WIZ1QST DB CHCR,CHLF,CHCR,CHLF
 ASC 'Since it is possible to relocate the NorthStar DOS'
 DB CHCR,CHLF
 ASC 'anywhere in your available memory, you have the option'
 DB CHCR,CHLF
 ASC 'of specifying where you would like Wiz-Print to load'
 DB CHCR,CHLF
 ASC 'and execute.  Wiz-Print requires between 3 and 3.5K of'
 DB CHCR,CHLF
 ASC 'memory space (the 1/2 K of memory is reserved for the'
 DB CHCR,CHLF
 ASC 'printer driver routine),'
 DB CHCR,CHLF,CHCR,CHLF
 ASC 'You have memory available to '
 DB 0
*
WIZ2QST ASC 'H therefore, this'
 DB CHCR,CHLF
 ASC 'version of Wiz-Print will load at '
 DB 0
*
WIZ3QST ASC 'H unless other-'
 DB CHCR,CHLF
 ASC 'wise specified.'
 DB CHCR,CHLF,CHCR,CHLF
 ASC 'Load address for Wiz-Print: '
 DB 0
*
PRTQST DB CHCR,CHLF,CHCR,CHLF
 ASC 'If you have a custom print driver that you would like'
 DB CHCR,CHLF
 ASC 'to use, you may specify its start address.  Note that'
 DB CHCR,CHLF
 ASC 'the driver must adhere to the rules as described in'
 DB CHCR,CHLF
 ASC "the Wiz-Print User's Manual.  If no address is given"
 DB CHCR,CHLF
 ASC '(i.e., nothing but a carriage return), the default'
 DB CHCR,CHLF
 ASC 'driver written for a NorthStar Horizon is used.'
 DB CHCR,CHLF,CHCR,CHLF
 ASC 'Print routine address: '
 DB 0
*
DVETYP ASC ' NorthStar Horizon Print Routine'
 DB CHCR,CHLF,CHCR,CHLF
 ASC 'Does the printer use the parallel port? (C/R = serial) '
 DB 0
*
DVEQST DB CHCR,CHLF
 ASC 'Since up to 8 separate output devices (numbered 0 to 7)'
 DB CHCR,CHLF
 ASC 'may be active at one time, you must specify which device'
 DB CHCR,CHLF
 ASC 'this initialization of Wiz-Print will recognize.  Note:'
 DB CHCR,CHLF
 ASC 'do not select device #0 before reading the Wiz-Print'
 DB CHCR,CHLF
 ASC 'User's Manual about this special case.'
 DB CHCR,CHLF,CHCR,CHLF
 ASC 'Printer device number: (C/R = #1)'
 DB 0
*
SPLINF DB CHCR,CHLF,CHCR,CHLF
 ASC 'When Wiz-Print is active, it transfers output that would'
 DB CHCR,CHLF
 ASC 'normally go to the printer to a file on the disk where it'
 DB CHCR,CHLF
 ASC 'can be read later.  If you wish to specify the name of'
 DB CHCR,CHLF
 ASC 'of that disk file, you may do so.  The recommended name'
 DB CHCR,CHLF
 ASC 'is "$PRxxxx,d" where "xxxx" is the load address for this'
 DB CHCR,CHLF
 ASC 'initialization of Wiz-Print and where "d" is the number'
 DB CHCR,CHLF
 ASC 'of the disk drive where the file is to reside.'
 DB CHCR,CHLF,CHCR,CHLF
 ASC 'Wiz-Print loads at: '
 DB 0
*
SPLQST DB CHCR,CHLF,CHCR,CHLF
 ASC 'Wiz-Print output file: '
 DB 0
*
SIZQST DB CHCR,CHLF,CHCR,CHLF
 ASC 'Since the output file takes up valuable disk space,'
 DB CHCR,CHLF
 ASC 'you have the option of making the file smaller (if you'
 DB CHCR,CHLF
 ASC 'usually have little to print) or larger (if you generally'
 DB CHCR,CHLF
 ASC 'have much to print).  In the unlikely event that this'
 DB CHCR,CHLF
 ASC 'disk file should become full, output will slow down as'
 DB CHCR,CHLF
 ASC 'though Wiz-Print were inactive.  Once the printer has'
 DB CHCR,CHLF
 ASC 'caught up, however, normal Wiz-Print operation will'
 DB CHCR,CHLF
 ASC 'resume.  The following question must be answered with a'
 DB CHCR,CHLF
 ASC 'hexadecimal value.'
 DB CHCR,CHLF,CHCR,CHLF
 ASC 'Some useful values are:  2K=8, 4K=10H, 8K=20H, 16K=40H'
 DB CHCR,CHLF,CHCR,CHLF
 ASC 'How many sectors long? (C/R = 40H)'
 DB 0
*
IOQST ASC ' Hex'
 DB CHCR,CHLF,CHCR,CHLF
 ASC 'If you have a NorthStar Horizon and the input/output'
 DB CHCR,CHLF
 ASC 'routines of the DOS have not been modified, then your'
 DB CHCR,CHLF
 ASC 'system has STANDARD I/O.  If the I/O routines have been'
 DB CHCR,CHLF
 ASC 'modified, then they must be configured according to'
 DB CHCR,CHLF
 ASC "the specifications outlined in the Wiz-Print User's"
 DB CHCR,CHLF
 ASC 'Manual.  Examples are given of how to do this.'
 DB CHCR,CHLF,CHCR,CHLF
 ASC 'Do you have NON-standard I/O? (C/R = No) '
 DB 0
*
CSTMES ASC 'See manual for I/O specifications.'
 DB CHCR,CHLF,0
*
ABTMES EQU $
 ASC 'A new version of Wiz-Print has been created according'
 DB CHCR,CHLF
 ASC 'to the specifications above.  If these data are correct,'
 DB CHCR,CHLF
 ASC 'then Wiz-Print will save this initialized version on'
 DB CHCR,CHLF
 ASC 'disk for you.  If the above data are incorrect, then'
 DB CHCR,CHLF
 ASC 'you may re-initialize Wiz-Print before saving the new'
 DB CHCR,CHLF
 ASC 'version on disk'
 DB CHCR,CHLF,CHCR,CHLF
 ASC 'Re-initialize Wiz-Print? (C/R = No) '
 DB 0
*
NMEINF DB CHCR,CHLF
 ASC 'This new version of Wiz-Print is ready to be saved'
 DB CHCR,CHLF
 ASC 'on disk.  You must now specify a file name that this'
 DB CHCR,CHLF
 ASC 'initialization will be saved under.  The recommended'
 DB CHCR,CHLF
 ASC 'file name is "WIZPRTx,d" where "x" is the device number'
 DB CHCR,CHLF
 ASC 'associated with this version of Wiz-Print, and where'
 DB CHCR,CHLF
 ASC '"d" is the drive you wish the program to be saved on.'
 DB CHCR,CHLF,0
*
NMEQST DB CHCR,CHLF
 ASC 'Disk file name: '
 DB 0
*
OVRWRT EQU $
 ASC 'That file already exists, overwrite? (C/R = No) '
 DB 0
*
DENQST EQU $
 ASC 'Is double-density in use? (C/R = No) '
 DB 0
*
RELMES DB CHCR,CHLF
 ASC 'Now initializing Wiz-Print...'
 DB 0
*
SV0MES DB CHCR,CHLF
 ASC '** Saving '
 DB 0
SV1MES ASC 'New'
 DB 0
SV15MES ASC 'Re-created'
 DB 0
SV2MES ASC 'Old'
 DB 0
SV3MES ASC ' file] **'
 DB 0
*
GOMES DB CHCR,CHLF,CHCR,CHLF
 ASC 'This new initialization of Wiz-Print has now been saved'
 DB CHCR,CHLF
 ASC 'on disk for you.  You may now execute this version of'
 DB CHCR,CHLF
 ASC 'Wiz-Print by typing:  GO '
 DB 0
*
MESYES ASC 'Yes'
 DB CHCR,CHLF,0
MESNO ASC 'No'
 DB CHCR,CHLF,0
*
LIST1 DB CHCR,CHLF,CHCR,CHLF
 ASC 'DOS at location '
 DB 0
LIST2 DB CHCR,CHLF
 ASC 'Wiz-Print at '
 DB 0
LIST3 DB CHCR,CHLF
 ASC 'Print driver at '
 DB 0
LIST4 DB CHCR,CHLF
 ASC 'Printer disk file is '
 DB 0
LST4 ASC 'H sectors'
 DB 0
LIST5 DB CHCR,CHLF
 ASC 'It is recognized as device # '
 DB 0
LIST6 DB CHCR,CHLF
 ASC 'User I/O is '
 DB 0
*
STNDRD ASC 'NorthStar Standard.'
 DB CHCR,CHLF,CHLF,0
CUSTOM ASC 'Custom.'
 DB CHCR,CHLF,CHLF,0
*
STRTADR DW 2  Start address of Wiz-Print
MEMSIZ DW 0  User memory size
*
********************
*
*  Storage/Data for the Wiz-Print relocator
*
OFFSET DS 2
*
OPCODES EQU $
 DB 0C3H,0C2H,0CAH,0D2H,0DAH,0E2H,0EAH,0F2H,0FAH  Jumps
 DB 0CDH,0C4H,0CCH,0D4H,0DCH,0E4H,0ECH,0F4H,0FCH  Calls
 DB 2AH,3AH,22H,32H,01H,11H,21H,31H  Loads
*
 DB 0  End of three byte opcodes
*
 DB 06H,0EH,16H,1EH,26H,2EH,36H,3EH  Move immediates
 DB 0C6H,0CEH,0D6H,0DEH,0E6H,0EEH,0F6H,0FEH  Acc. immediates
 DB 0D3H,0DBH  Input/Output
*
 DB 0  End of opcode table
*
********************
*
*  End of the Wiz-Print setup routine
*
 DS 25
SETSTK EQU $
*
 ORG $/100H*100H+100H
*