5 PRINT "\G"
   10 REM*****AUTO INPUT PROGRAM
   20 DIM N$(30),A$(30),Z$(30),C$(20),P$(1),C1$(80)
   25 SET OF=#0
   30 PRINT "\K": CURSOR 5,0
   50 PRINT "PRINTER CHECK"
   60 PRINT "Inhibit, 30 cps, line feed 1, auto L.F. off"
   70 INPUT (1,0)"Ready, type (CR)",Q$
   80 GOSUB 820
   90 CURSOR 3,14
  100 PRINT "    THE INSURANCE AGENCY PROGRAM"
  130 PRINT 
  140 PRINT "Rate and type an auto quote             1"
  150 PRINT "Do a 'quickie' auto quote               2"
  160 PRINT "Make a new file of CSL rates            3"
  170 PRINT "Make a new file of Split Limit rates    4"
  210 PRINT 
  220 INPUT "Your request ",Q2
  230 ON Q2 GOTO 290,350,240,250
  235 GOTO 80
  240 XEQ "R.FILE-C"
  250 XEQ "R.FILE-S"
  290 PRINT 
  300 INPUT "INSURED'S NAME :",N$
  310 INPUT "INSURED'S ADDRESS :",A$
  320 INPUT "CITY, STATE,ZIP :",Z$
  330 INPUT "TELEPHONE NUMBER : ",T$
  340 GOTO 360
  350 GOSUB 820: LET Q1$="#"
  360 INPUT "YEAR AND MAKE OF CAR :",C$
  362 GOSUB 900
  370 PRINT "PHYSICAL DAMAGE REQUESTED? enter Y for yes,"
  375 INPUT "N for no and C for Comprehensive only :",P$
  380 IF P$(1,1)="Y" THEN 420
  390 IF P$(1,1)="y" THEN 420
  400 LET P$="N"
  410 GOTO 460
  420 INPUT "WHAT ARE SYMBOL AND AGE :",S,A
  430 IF S=9 THEN  PRINT "I never heard of symbol 9": GOTO 420
  440 IF A>6 THEN  PRINT "I never heard of age ";A: GOTO 420
  450 PRINT 
  460 INPUT (7,0)"Input rating code (ex. 8111-10): ",F$
  470 INPUT (4,0)"Input rating factor (ex 1.1%)   : ",F
  480 PRINT 
  490 INPUT "TYPE THE TERR. THAT APPLYS (ex. 2): ",T
  500 GOSUB 820
  510 PRINT "Select the company you want to rate:"
  520 PRINT "Aetna Family Auto......1"
  530 PRINT "Aetna Auto Rite........2"
  540 PRINT 
  550 PRINT "Trinity Family Auto....3"
  560 PRINT "Trinity Preferred Auto.4"
  570 PRINT 
  580 PRINT "CNA Standard...........5"
  590 PRINT "CNA Preferred..........6"
  600 PRINT 
  610 PRINT "INA....................7"
  620 PRINT "Transamerica Auto Flex.9"
  630 INPUT Q
  640 REM****SET UP SERIAL FILE
  650 FILE #4;"A-PROSP",3
  660 ON Q GOTO 670,680,690,700,710,720,730,740,750
  670 LET Q$="AFAS": GOSUB 760: XEQ "RATES"
  680 LET Q$="AARC": GOSUB 760: XEQ "RATES-C"
  690 LET Q$="TFAS": GOSUB 760: XEQ "RATES"
  700 LET Q$="TPAS": GOSUB 760: XEQ "RATES"
  710 LET Q$="NFSC": GOSUB 760: XEQ "RATES-C"
  720 LET Q$="VFPC": GOSUB 760: XEQ "RATES-C"
  730 LET Q$="INA": GOSUB 760: XEQ "RATEINA"
  740 LET Q$="DLA": GOSUB 760: XEQ "DLAND"
  750 LET Q$="TAFC": GOSUB 760: XEQ "RATES-C"
  760 REM*****************************************
  770 REWIND #4
  780 PRINT #4;N$,A$,Z$,T$,C$,P$,F$,S,A,F,T1,Q$,Q1$,T,C1$,P9
  790 CLOSE #4
  800 RETURN 
  810 REM*****************************************
  820 PRINT "\K"
  830 CURSOR 3,1
  840 RETURN 
  900 REM* Routine to find Pick Up truck
  910 SEARCH "P",C$,P8: IF P8>1 THEN  GOTO 1000
  920 SEARCH "p",C$,P8: IF P8>1 THEN  GOTO 1000
  930 RETURN 
 1000 INPUT (1,0)"Is this a Pick Up? (y or n) :",P8$
 1010 IF P8$="y" THEN  LET P9=1
 1012 IF P8$="Y" THEN  LET P9=1
 1020 RETURN