1 REM
    3 REM*                 R.FILE.-C
    4 REM
    5 REM*       FILE SETS UP RATE FILES FOR CSL POLICIES
    6 REM
    7 REM
    8 REM*******************************************************
   10 DIM C(7,7),K(7,7),L(7,7)
   20 PRINT "\K"
   25 CURSOR 5,15: PRINT "COMBINED LIMIT DATA FILES"
   30 PRINT "This program inputs data to the data files...It is very"
   40 PRINT "important that the data is imput exactly in the order the"
   50 PRINT "program calls for it.": PRINT : PRINT 
   60 PRINT "Type mode select, and then run to restart if errors."
   62 PRINT "You will need to input all data in capital letters."
   63 PRINT "Please press the 'UPPER CASE' key, it will light when"
   64 PRINT "actuated, and then type a 'Y'."
   65 INPUT Q9$
   66 IF Q9$<>"Y" THEN 63
   67 PRINT "\K"
   70 PRINT "            Company Identification"
   72 PRINT 
   74 PRINT "Type a 3 letter ID symbol for the name of your"
   76 PRINT "company data being input...example AFA=Aetna Family Auto."
   78 INPUT (3,0)Q$
   83 LET Q$=Q$+"C"
   84 PRINT 
   86 PRINT "This rate file will be forever known as :";Q$
   88 PRINT "Unless you type 'mode select' and restart the program"
   90 PRINT : PRINT "     ...a few seconds to change your mind "
   92 PAUSE 100
   93 INPUT "What is the date of the rates being input? : ",D1$
   95 PRINT "\K"
  100 REM**SAVE LIABILITY RATES
  110 PRINT : PRINT "Input rates for CSL limits codes"
  120 FOR I=1 TO 4
  130 PRINT "Code ";I;" Premium   ";: INPUT B(I)
  140 NEXT I
  150 REM**EXAMINE LIABILITY RATES
  160 PRINT "\K": PRINT "Here are the liability rates...": PRINT 
  170 FOR I=1 TO 4: PRINT B(I),: NEXT I
  175 PRINT 
  180 INPUT "IF ERROR THIS (#) :",Q9$
  190 IF Q9$="#" THEN 100
  200 REM***SAVE PIP RATES
  210 PRINT "\K": PRINT "Input rates for PIP, and options 1,2, and 3"
  220 FOR I=1 TO 4
  230 PRINT "PIP level ";I;" Premium   ";: INPUT N(I)
  240 NEXT I
  250 REM**EXAMINE THE SAVED RATES
  260 PRINT "\K": PRINT "Here are the PIP rates...": PRINT 
  270 FOR I=1 TO 4: PRINT N(I),: NEXT I
  275 PRINT 
  280 INPUT "If error type (#) :",Q9$
  290 IF Q9$="#" THEN 200
  300 REM***INPUT COMPREHENSIVE
  305 PRINT "\K"
  310 PRINT "Now we enter comp...enter symbol 1-7 of each age group..."
  320 FOR S=1 TO 7
  330 FOR A=1 TO 6
  340 PRINT "Symbol ";S;" age ";A;"   $";: INPUT C(S,A)
  350 NEXT : NEXT 
  360 REM**READ BACK COMPREHENSIVE RATES
  370 PRINT "\K"
  380 PRINT "Now check the rates below..."
  390 FOR A=1 TO 6: PRINT 
  400 FOR S=1 TO 7: PRINT %6F0;C(S,A);
  410 NEXT : NEXT : PRINT 
  420 REM**INPUT CORRECTIONS ON COMP.
  430 INPUT "Are all of these correct ? (Y=yes) : ",Q9$
  440 IF Q9$="Y" THEN 500
  450 INPUT "Enter symbol, then age of correction: ",S,A
  460 PRINT 
  470 PRINT "Enter correct premium for symbol ";S;", age ";A
  480 INPUT C(S,A)
  490 GOTO 360
  500 REM**INPUT 100 DED COLL.
  505 PRINT "\K"
  510 PRINT "Now we enter 100 ded. collision...enter per instructions."
  520 FOR S=1 TO 7
  530 FOR A=1 TO 6
  540 PRINT "Sumbol ";S;" age ";A;"   $";: INPUT K(S,A)
  550 NEXT : NEXT 
  560 REM**NOW READ BACK THE 100 COLL. RATES
  570 PRINT "\K"
  580 PRINT "Please check the rates below..."
  590 FOR A=1 TO 6: PRINT 
  600 FOR S=1 TO 7
  605 PRINT %6F0;K(S,A);
  610 NEXT : NEXT : PRINT 
  620 REM***INPUT CORRECTIONS 100 C0LL
  630 INPUT "Are all of these rates correct ? (Y=yes): ",Q9$
  640 IF Q9$="Y" THEN 700
  650 INPUT "Enter the symbol, and then the age, of correction :",S,A
  660 PRINT 
  670 PRINT "Enter correct premium for symbol ";S;", age ";A
  680 INPUT K(S,A)
  690 GOTO 560
  700 REM**INPUT 200 DED COLL
  705 PRINT "\K"
  710 PRINT "Now we enter 200 ded. collision...per instructions "
  720 FOR S=1 TO 7
  730 FOR A=1 TO 6
  740 PRINT "Symbol ";S;", age ";A;"   $";: INPUT L(S,A)
  750 NEXT : NEXT 
  760 REM**READ BACK THE 200 COLL RATES
  770 PRINT "\K"
  780 PRINT "Now check the rates below..."
  790 FOR A=1 TO 6: PRINT 
  800 FOR S=1 TO 7: PRINT %6F0;L(S,A);
  810 NEXT : NEXT : PRINT 
  820 REM**CORRECTIONS 200 COLL
  830 INPUT "Are all the above correct? (Y=yes) : ",Q9$
  940 IF Q9$="Y" THEN 1000
  950 INPUT "Enter symbol, then the age of correction :",S,A
  960 PRINT 
  970 PRINT "Enter correct premium for symbol ";S;", age ";A
  980 INPUT L(S,A)
  990 GOTO 760
 1000 REM:::::::::::W R I T E   T H E   F I L E:::::::::::
 1010 FILE #5;Q$,3
 1020 FOR I=1 TO 4
 1030 PRINT #5;B(I)
 1040 NEXT I
 1050 FOR I=1 TO 4
 1060 PRINT #5;N(I)
 1070 NEXT I
 1080 FOR S=1 TO 7
 1090 FOR A=1 TO 6
 1100 PRINT #5;C(S,A)
 1110 NEXT : NEXT 
 1120 FOR S=1 TO 7
 1130 FOR A=1 TO 6
 1140 PRINT #5;K(S,A)
 1150 NEXT : NEXT 
 1160 FOR S=1 TO 7
 1170 FOR A=1 TO 6
 1180 PRINT #5;L(S,A)
 1190 NEXT : NEXT 
 1195 PRINT #5;D1$
 1199 CLOSE #5
 2000 REM*_**QUIT OR GO AGAIN
 2005 PRINT "\K": CURSOR 5,5: PRINT "W R I T E   T H I S   D O W N"
 2006 PRINT "              ->  -> ";Q$;" <- <- "
 2007 PRINT "UPDATE THE AUTO PROGRAM TO REFLECT THIS FILE NAME"
 2008 INPUT "return to continue",Q9$
 2010 PRINT "\K": INPUT "Another company ?  (Y=yes) :",Q9$
 2020 IF Q9$<>"Y" THEN  XEQ "AUTO"
 2030 CLEAR 
 2040 GOTO 67