20 REM*                 R.FILE-S
   40 REM*  FILE SETS UP RATE FILES FOR SPLIT LIMIT POLICIES
   80 DIM C(7,7),K(7,7),L(7,7)
   90 PRINT "\K"
  100 CURSOR 5,15: PRINT "SPLIT LIMIT RATE FILES"
  110 PRINT "This program inputs data to the data files...It is very"
  120 PRINT "important that the data is imput exactly in the order the"
  130 PRINT "program calls for it.": PRINT : PRINT 
  140 PRINT "Type mode select, and then run to restart if errors."
  150 PRINT "You will need to input all data in capital letters."
  160 PRINT "Please press the 'UPPER CASE' key, it will light when"
  170 PRINT "actuated, and then type a 'Y'."
  180 INPUT (1,0)Q9$
  190 IF Q9$<>"Y" THEN 160
  200 PRINT "\K"
  210 PRINT "            Company Identification"
  220 PRINT 
  230 PRINT "Type a 3 letter ID symbol for the name of your"
  240 PRINT "company data being input...example AFA=Aetna Family Auto."
  250 INPUT (3,0)Q$
  260 LET Q$=Q$+"S"
  265 PURGE Q$
  270 PRINT 
  280 PRINT "This rate file will be forever known as :";Q$(1,3)
  290 PRINT "Unless you type 'mode select' and restart the program"
  300 PRINT : PRINT "     ...a few seconds to change your mind "
  310 PAUSE 100
  320 INPUT "What is the date of the rates being input? : ",D1$
  330 PRINT "\K"
  340 REM**SAVE BI LIABILITY RATES
  350 PRINT "Input rates for 15/30  25/50  50/100  and 100/300"
  360 FOR I=1 TO 4
  370 PRINT "Code ";I;" Premium   ";: INPUT B(I)
  380 NEXT I
  390 REM**EXAMINE BI LIABILITY RATES
  400 PRINT "\K": PRINT "Here are the liability rates...": PRINT 
  410 FOR I=1 TO 4: PRINT B(I),: NEXT I
  420 PRINT 
  430 INPUT (1,0)"IF ERROR TYPE THIS (#) :",Q9$
  440 IF Q9$="#" THEN 340
  450 REM**INPUT PD LIABILITY RATES
  460 PRINT "\K"
  470 PRINT "Input rates for these limits codes"
  480 PRINT "Code 1-$5,000"
  490 PRINT "Code 2-$10,000"
  500 PRINT "Code 3-$25,000"
  510 PRINT "Code 4-$50,000"
  520 FOR I=1 TO 4
  530 PRINT "Code : ";I;"  Premium ";: INPUT P(I)
  540 NEXT I
  550 PRINT "\K"
  560 PRINT "Now check these PD rates..."
  570 FOR I=1 TO 4
  580 PRINT P(I),
  590 NEXT I
  600 PRINT : INPUT (1,0)"If any errors type # : ",Q9$
  610 IF Q9$="#" THEN 450
  620 REM***SAVE PIP RATES
  630 PRINT "\K": PRINT "Input rates for PIP, and options 1,2, and 3"
  640 FOR I=1 TO 4
  650 PRINT "PIP level ";I;" Premium   ";: INPUT N(I)
  660 NEXT I
  670 REM**EXAMINE THE SAVED RATES
  680 PRINT "\K": PRINT "Here are the PIP rates...": PRINT 
  690 FOR I=1 TO 4: PRINT N(I),: NEXT I
  700 PRINT 
  710 INPUT "If error type (#) :",Q9$
  720 IF Q9$="#" THEN 620
  730 REM***INPUT COMPREHENSIVE
  740 PRINT "\K"
  750 PRINT "Now we enter comp...enter symbol 1-7 of each age group..."
  760 FOR S=1 TO 7
  770 FOR A=1 TO 6
  780 PRINT "Symbol ";S;" age ";A;"   $";: INPUT C(S,A)
  790 NEXT : NEXT 
  800 REM**READ BACK COMPREHENSIVE RATES
  810 PRINT "\K"
  820 PRINT "Now check the rates below..."
  830 FOR A=1 TO 6: PRINT 
  840 FOR S=1 TO 7: PRINT %6F0;C(S,A);
  850 NEXT : NEXT : PRINT 
  860 REM**INPUT CORRECTIONS ON COMP.
  870 INPUT "Are all of these correct ? (Y=yes) : ",Q9$
  880 IF Q9$="Y" THEN 940
  890 INPUT "Enter symbol, then age of correction: ",S,A
  900 PRINT 
  910 PRINT "Enter correct premium for symbol ";S;", age ";A
  920 INPUT C(S,A)
  930 GOTO 800
  940 REM**INPUT 100 DED COLL.
  950 PRINT "\K"
  960 PRINT "Now we enter 100 ded. collision...enter per instructions."
  970 FOR S=1 TO 7
  980 FOR A=1 TO 6
  990 PRINT "Sumbol ";S;" age ";A;"   $";: INPUT K(S,A)
 1000 NEXT : NEXT 
 1010 REM**NOW READ BACK THE 100 COLL. RATES
 1020 PRINT "\K"
 1030 PRINT "Please check the rates below..."
 1040 FOR A=1 TO 6: PRINT 
 1050 FOR S=1 TO 7
 1060 PRINT %6F0;K(S,A);
 1070 NEXT : NEXT : PRINT 
 1080 REM***INPUT CORRECTIONS 100 C0LL
 1090 INPUT "Are all of these rates correct ? (Y=yes): ",Q9$
 1100 IF Q9$="Y" THEN 1160
 1110 INPUT "Enter the symbol, and then the age, of correction :",S,A
 1120 PRINT 
 1130 PRINT "Enter correct premium for symbol ";S;", age ";A
 1140 INPUT K(S,A)
 1150 GOTO 1010
 1160 REM**INPUT 200 DED COLL
 1170 PRINT "\K"
 1180 PRINT "Now we enter 200 ded. collision...per instructions "
 1190 PRINT "The program will convert 100 ded to 200 rates if you don't"
 1192 PRINT "have 200 ded. rates published. ": PRINT 
 1193 PRINT "If desired, type a (#), otherwise, any other key :";: INPUT (1,0)Z9$
 1194 IF Z9$<>"#" THEN 1200
 1195 INPUT "Input conversion % like this (.87) :",Z8
 1200 FOR S=1 TO 7
 1220 FOR A=1 TO 6
 1230 PRINT "Symbol ";S;", age ";A;"   $";: INPUT L(S,A)
 1240 IF Z9$="#" THEN  GOSUB 1750
 1250 NEXT : NEXT 
 1260 REM**READ BACK THE 200 COLL RATES
 1270 PRINT "\K"
 1280 PRINT "Now check the rates below..."
 1290 FOR A=1 TO 6: PRINT 
 1300 FOR S=1 TO 7: PRINT %6F0;L(S,A);
 1310 NEXT : NEXT : PRINT 
 1320 REM**CORRECTIONS 200 COLL
 1330 INPUT "Are all the above correct? (Y=yes) : ",Q9$
 1340 IF Q9$="Y" THEN 1410
 1350 INPUT "Enter symbol, then the age of correction :",S,A
 1360 PRINT 
 1370 PRINT "Enter correct premium for symbol ";S;", age ";A
 1380 INPUT L(S,A)
 1390 IF Z9$="#" THEN  GOSUB 1750
 1400 GOTO 1260
 1410 REM:::::::::::W R I T E   T H E   F I L E:::::::::::
 1420 FILE #5;Q$,3
 1430 FOR I=1 TO 4
 1440 PRINT #5;B(I)
 1445 NEXT I
 1450 FOR I=1 TO 4
 1460 PRINT #5;P(I)
 1470 NEXT I
 1490 FOR I=1 TO 4
 1500 PRINT #5;N(I)
 1510 NEXT I
 1520 FOR S=1 TO 7
 1530 FOR A=1 TO 6
 1540 PRINT #5;C(S,A)
 1550 NEXT : NEXT 
 1560 FOR S=1 TO 7
 1570 FOR A=1 TO 6
 1580 PRINT #5;K(S,A)
 1590 NEXT : NEXT 
 1600 FOR S=1 TO 7
 1610 FOR A=1 TO 6
 1620 PRINT #5;L(S,A)
 1630 NEXT : NEXT 
 1640 PRINT #5;D1$
 1650 CLOSE #5
 1660 REM*_**QUIT OR GO AGAIN
 1670 PRINT "\K": CURSOR 5,5: PRINT "W R I T E   T H I S   D O W N"
 1680 PRINT "              ->  -> ";Q$;" <- <- "
 1700 INPUT "return to continue",Q9$
 1710 PRINT "\K": INPUT "Another company ?  (Y=yes) :",Q9$
 1720 IF Q9$<>"Y" THEN  XEQ "AUTO"
 1730 CLEAR 
 1740 GOTO 200
 1750 LET L(S,A)=L(S,A)*Z8
 1760 RETURN