10 REM*             RATES
   12 REM*
   14 REM*
   20 REM*        rates split limit policies
   30 CLEAR 
   40 DIM N$(30),A$(30),Z$(30),T$(10),C$(20),P$(1),C1$(80)
   50 DIM C(7,7),K(7,7),L(7,7),L9$(52)
   55 FILL L9$,"#"
   60 FILE #4;"A-PROSP"
   70 READ #4;N$,A$,Z$,T$,C$,P$,F$,S,A,F,T1,Q$,Q1$,T,C1$,P9
   80 CLOSE #4
   90 GOSUB 1340
  100 PRINT "Input BI limits desired."
  110 PRINT "$15/30......1"
  120 PRINT "25/50.......2"
  130 PRINT "50/100......3"
  140 PRINT "100/300.....4"
  150 INPUT "       Which limit ",X1
  160 IF X1>4 THEN 90
  170 PRINT "Input PD limits desired"
  180 PRINT "$5,000........1"
  190 PRINT " 10,000.......2"
  200 PRINT " 25,000.......3"
  210 PRINT " 50,000.......4"
  220 INPUT "    Which limit ",X2
  230 IF X2>4 THEN 170
  250 GOSUB 1340
  260 PRINT "INPUT NO FAULT COVERAGE"
  270 PRINT "BASIC....1"
  280 PRINT "OPT. 1...2"
  290 PRINT "OPT. 2...3"
  300 PRINT "OPT. 3...4"
  310 INPUT X3
  320 IF X3>4 THEN 250
  330 REM***SET VALUES FOR UIM AND T&L
  340 LET U=2: LET L=2
  350 IF P$="n" THEN 420
  360 IF P$="N" THEN 420
  370 GOSUB 1340
  380 INPUT "COMPREHENSIVE...ACV OR $50 DED...(enter ACV or 50): ",P1$
  390 IF P$="C" THEN 420
  395 IF P$="c" THEN 420
  400 PRINT : PRINT 
  405 ERRSET 200
  410 INPUT "COLLISION...$100 OR $200 DED...(enter 100 or 200) :",P2$
  420 FILE #5;Q$,3
  430 FOR I=1 TO 4
  440 READ #5;B(I)
  450 NEXT I
  460 FOR I=1 TO 4
  470 READ #5;P(I)
  480 NEXT I
  490 FOR I=1 TO 4
  500 READ #5;N(I)
  510 NEXT I
  520 REM****READ COMP AND COLL. ARRAYS
  530 FOR I=1 TO 7
  540 FOR J=1 TO 6
  550 READ #5;C(I,J)
  560 NEXT : NEXT 
  570 REM****FOLLOWING IS 100 DED COLL.
  580 FOR I=1 TO 7
  590 FOR J=1 TO 6
  600 READ #5;K(I,J)
  610 NEXT 
  620 NEXT 
  630 REM****FOLLOWING IS 200 DED ARRAY
  640 FOR I=1 TO 7
  650 FOR J=1 TO 6
  660 READ #5;L(I,J)
  670 NEXT J
  680 NEXT I
  685 READ #5;D$
  690 CLOSE #5
  695 ERRCLR 
  700 REM****COMPUTE BI,PD,PIP
  710 LET B=B(X1)*F
  720 LET P=P(X2)*F
  730 LET N=N(X3)*F
  740 IF P$="N" THEN 830
  745 IF P$="n" THEN 830
  750 REM****COMPUTE COMPREHENSIVE
  755 IF S>7 THEN  GOTO 2200
  760 LET C=C(S,A)
  770 IF P1$(1,1)="5" THEN  LET C=C*.8
  775 LET C=C*F
  780 IF P$="C" THEN 830
  781 IF P$="c" THEN 830
  785 REM*   Jump to coll. from ded. indicator, (P2$)
  790 IF P2$(1,1)="2" THEN 820
  795 IF S>7 THEN 2300
  800 LET K=K(S,A)
  810 GOTO 825
  820 IF S>7 THEN 2400
  822 LET K=L(S,A)
  825 LET K=K*F: IF P9=1 THEN  LET K=K*.65: REM* Adjust for Pick Ups
  830 REM*  Erase coll if comp only
  831 IF P1$="C" THEN  LET K=0: LET K$=""
  832 IF P$="c" THEN  LET K=0: LET K$=" "
  835 LET T=B+P+N+C+K+U+L
  840 LET T1=T+T1
  850 SET OF=#1
  860 PRINT "\[H"
  872 IF Q1$="#" THEN  GOTO 910
  880 PRINT "Quote For:",N$
  890 PRINT "Address  :",A$
  900 PRINT "          ",Z$
  902 PRINT "Telephone Number:",T$
  910 PRINT : PRINT "       Company Code  :";Q$,"Rates Dated ";D$
  920 PRINT "Automobile Quoted: ";C$;TAB(45);"Premium"
  930 PRINT "Symbol ";S,"Age ";A
  935 PRINT "                    *"
  940 PRINT "BI  Limits Code:",X1;%$C10F2,B
  950 PRINT "PD  Limits Code: ",X2;%$C10F2,P
  960 PRINT "PIP Limit Code :",X3;%$C10F2,N
  970 PRINT "Comprehensive  :",P1$;%$C10F2,C
  980 PRINT "Collision      :",P2$;%$C10F2,K
  982 PRINT "UIM and T&L Included"
  990 PRINT "Factor ";F$,"AT ";F;" %"
 1000 PRINT "ANNUAL PREMIUM for car is ";,%$C10F2,T
 1010 SET OF=#0
 1020 GOSUB 1340
 1030 PRINT "Policy rated for ANNUAL premium"
 1060 PRINT "For a 3 month policy type # 3 "
 1070 PRINT "For a 6 month policy type # 6 "
 1080 FILE #4;"A-PROSP"
 1085 REWIND #4
 1090 PRINT #4;N$,A$,Z$,T$,C$,P$,F$,S,A,F,T1,Q$,Q1$,T,C1$,P9
 1100 CLOSE #4
 1110 INPUT P1
 1115 LET P2=1
 1120 IF P1=3 THEN  LET P2=4
 1130 IF P1=6 THEN  LET P2=2
 1140 SET OF=#1
 1145 PRINT 
 1150 IF P1=3 THEN  PRINT "         **Quarterly Payment Option**"
 1160 IF P1<>3 THEN  PRINT "        **Six Month Payment Option**"
 1170 PRINT "Total for THIS CAR,split billings is  now ";%$C10F2;T/P2
 1175 IF LEN(C1$)<2 THEN 1200
 1180 PRINT 
 1190 PRINT "QUOTE SUMMARY.....PREMIUM: ",;%$C10F2;T1/P2
 1191 PRINT "CARS REVIOUSLY RATED: ": PRINT C1$
 1200 PRINT L9$
 1210 FOR I=1 TO 10: PRINT : NEXT I
 1230 PRINT "\[J"
 1240 SET OF=#0
 1250 PRINT "TYPE 1 TO RATE ANOTHER POLICY....."
 1260 PRINT "TYPE 2 TO MAKE SOME CHANGES....."
 1280 INPUT Q
 1290 ON Q GOTO 1300,1320,1330
 1300 REM**WRITE NEW POLICY
 1310 XEQ "AUTO"
 1320 XEQ "CHANGE"
 1330 END 
 1340 PRINT "\K": RETURN 
 2000 PRINT "\K": PRINT "YOU HAVE ASKED FOR A RATE NOT ON THE DISK..."
 2010 PRINT "PLEASE MAKE A NEW RATE FILE OR RATE ANOTHER COMPANY."
 2020 PAUSE 50: GOTO 1310
 2200 REM*   This rates comprehensive over sym 7
 2210 LET C=C(4,(A))
 2215 IF S=8 THEN  LET C=C*2.7
 2220 IF S=10 THEN  LET C=C*3.35
 2225 IF S=11 THEN  LET C=C*4.1
 2230 IF S=12 THEN  LET C=C*4.8
 2235 IF S=13 THEN  LET C=C*5.5
 2240 IF S=14 THEN  LET C=C*7
 2250 GOTO 770
 2300 REM*   This rates coll. 100 ded over sym 7
 2305 LET K=K(4,(A))
 2310 IF S=8 THEN  LET K=K*1.75
 2320 IF S=10 THEN  LET K=K*1.9
 2330 IF S=11 THEN  LET K=K*2.1
 2340 IF S=12 THEN  LET K=K*2.3
 2350 IF S=13 THEN  LET K=K*2.5
 2360 IF S=14 THEN  LET K=K*3.2
 2380 GOTO 810
 2400 REM*  This rates coll. 200 ded over sym 7
 2405 LET K=L(4,(A))
 2410 IF S=8 THEN  LET K=K*1.75
 2420 IF S=10 THEN  LET K=K*1.9
 2430 IF S=11 THEN  LET K=K*2.1
 2440 IF S=12 THEN  LET K=K*2.3
 2450 IF S=13 THEN  LET K=K*2.5
 2460 IF S=14 THEN  LET K=K*3.2
 2470 GOTO 825