10 REM*
   12 REM*              RATES-C
   14 REM*
   16 REM*      rates combined limits policices
   20 REM*
   30 CLEAR 
   40 DIM N$(30),A$(30),Z$(30),T$(10),C$(20),P$(1),C1$(80)
   50 DIM C(7,7),K(7,7),L(7,7),L9$(53)
   51 FILL L9$,"# "
   60 FILE #4;"A-PROSP"
   70 READ #4;N$,A$,Z$,T$,C$,P$,F$,S,A,F,T1,Q$,Q1$,T,C1$,P9
   80 CLOSE #4
   90 GOSUB 1340
   95 GOSUB 1500: REM* SUBROUTINE TO CHECK FOR MANDATORY 50 DED. MINIMUM COMP
  100 PRINT "Input liability limits desired"
  110 PRINT "$35,000.....1"
  120 PRINT "50,000......2"
  130 PRINT "100,000.....3"
  140 PRINT "300,000.....4"
  150 INPUT "       Which limit ",X1
  160 IF X1>4 THEN 90
  250 GOSUB 1340
  260 PRINT "INPUT NO FAULT COVERAGE"
  270 PRINT "BASIC....1"
  280 PRINT "OPT. 1...2"
  290 PRINT "OPT. 2...3"
  300 PRINT "OPT. 3...4"
  310 INPUT X3
  320 IF X3>4 THEN 250
  330 REM***SET VALUES FOR UIM AND T&L
  340 LET U=2: LET L=2
  350 IF P$="n" THEN 420
  360 IF P$="N" THEN 420
  370 GOSUB 1340
  375 IF F9=1 THEN 382
  380 INPUT "COMPREHENSIVE...ACV or 50 ded....(enter ACV or 50): ",P1$: GOTO 390
  382 INPUT "COMPREHENSIVE...50 or 100 ded....(enter 50 or 100): ",P1$
  390 IF P$="C" THEN 420
  395 IF P$="c" THEN 420
  400 PRINT : PRINT 
  410 INPUT "COLLISION...$100 OR $200 DED...(enter 100 or 200) :",P2$
  420 FILE #5;Q$,3
  430 FOR I=1 TO 4
  440 READ #5;B(I)
  450 NEXT I
  490 FOR I=1 TO 4
  500 READ #5;N(I)
  510 NEXT I
  520 REM****READ COMP AND COLL. ARRAYS
  530 FOR I=1 TO 7
  540 FOR J=1 TO 6
  550 READ #5;C(I,J)
  560 NEXT : NEXT 
  570 REM****FOLLOWING IS 100 DED COLL.
  580 FOR I=1 TO 7
  590 FOR J=1 TO 6
  600 READ #5;K(I,J)
  610 NEXT 
  620 NEXT 
  630 REM****FOLLOWING IS 200 DED ARRAY
  640 FOR I=1 TO 7
  650 FOR J=1 TO 6
  660 READ #5;L(I,J)
  670 NEXT J
  680 NEXT I
  685 READ #5;D$
  690 CLOSE #5
  700 REM****COMPUTE BI,PD,PIP
  710 LET B=B(X1)*F
  730 LET N=N(X3)*F
  740 IF P$="N" THEN 830
  742 IF P$="n" THEN 830
  750 REM****COMPUTE COMPREHENSIVE
  755 IF S>7 THEN 2200
  760 LET C=C(S,A)
  768 REM*IF P1$(1,1)="1" AND F9=1 THEN  LET C=C*.8: GOTO 780
  770 IF P1$(1,1)="5" THEN  LET C=C*.8
  775 LET C=C*F
  780 IF P$(1,1)="C" THEN  LET K=0: LET K$="": GOTO 830
  781 IF P$(1,1)="c" THEN  LET K=0: LET K$="": GOTO 830
  785 REM* jump to coll from ded indicatior P2$
  790 IF P2$(1,1)="2" THEN 820
  795 IF S>7 THEN 2300
  800 LET K=K(S,A)
  810 GOTO 825
  820 IF S>7 THEN 2400
  822 LET K=L(S,A)
  825 LET K=K*F: IF P9=1 THEN  LET K=K*.65
  830 REM* K&k$ cleared in 780,781
  835 LET T=B+N+C+K+U+L
  840 LET T1=T+T1
  850 SET OF=#1
  860 PRINT "\[H"
  872 IF Q1$="#" THEN  GOTO 910
  880 PRINT "Quote For:",N$
  890 PRINT "Address  :",A$
  900 PRINT "          ",Z$
  902 PRINT "Telephone:",T$
  910 PRINT : PRINT "       Company Code  :";Q$,"Rates Dated ";D$
  920 PRINT "Automobile Quoted:";C$;TAB(45);"Premium"
  930 PRINT "Symbol ";S,"Age ";A
  935 PRINT "                 *"
  940 PRINT "Liability Limits Code:",X1;%$C10F2,B
  960 PRINT "PIP limit code:",X3;%$C10F2,N
  970 PRINT "Comprehensive :",P1$;%$C10F2,C
  980 PRINT "Collision     :",P2$;%$C10F2,K
  982 PRINT "Towing, and UIM included"
  990 PRINT "Total Premium for car is ";%$C10F2,T
 1000 PRINT "Factor ";F$,"At ";F," %"
 1010 SET OF=#0
 1020 GOSUB 1340
 1030 PRINT "Policy rated for six month premium"
 1060 PRINT "For a 3 month policy type # 3 "
 1070 PRINT "For a 6 month policy type # 6 "
 1080 FILE #4;"A-PROSP"
 1085 REWIND #4
 1090 PRINT #4;N$,A$,Z$,T$,C$,P$,F$,S,A,F,T1,Q$,Q1$,T,C1$,P9
 1100 CLOSE #4
 1110 INPUT P1
 1120 IF P1=3 THEN  LET P2=2
 1130 IF P1<>3 THEN  LET P2=1
 1140 SET OF=#1
 1145 PRINT 
 1150 IF P1=3 THEN  PRINT "        **Quarterly Payment Option**"
 1160 IF P1<>3 THEN  PRINT "       **Six Month Payment Option**"
 1170 PRINT "Total for THIS CAR split billings is   ";%$C10F2,T/P2
 1180 PRINT 
 1190 PRINT "Quote Summary....Premium :";%$C10F2;T1/P2
 1191 PRINT "CARS PREVIOUSLY RATED:": PRINT C1$
 1200 PRINT L9$
 1210 FOR I=1 TO 10: PRINT : NEXT I
 1230 PRINT "\[J"
 1240 SET OF=#0
 1250 PRINT "TYPE 1 TO RATE ANOTHER POLICY....."
 1260 PRINT "TYPE 2 TO MAKE SOME CHANGES....."
 1280 INPUT Q
 1290 ON Q GOTO 1300,1320,1330
 1300 REM* GET ANOTHER PROGRAM
 1310 XEQ "AUTO"
 1320 XEQ "CHANGE"
 1330 END 
 1340 PRINT "\K": RETURN 
 1499 REM*********************************
 1500 REM* This check a list of companies that use 50 and 100 
 1510 REM* comp only, sets a flag, (f9) to 1 and adjusts output.
 1520 IF Q$="NFSC" THEN  LET F9=1: RETURN 
 1530 IF Q$="VFPC" THEN  LET F9=1: RETURN 
 1600 REM*********************************
 1610 RETURN 
 2200 REM*  Rates comp over sym.7
 2210 LET C=C(4,(A))
 2215 IF S=8 THEN  LET C=C*2.7
 2220 IF S=10 THEN  LET C=C*3.35
 2225 IF S=11 THEN  LET C=C*4.1
 2230 IF S=12 THEN  LET C=C*4.8
 2235 IF S=13 THEN  LET C=C*5.5
 2240 IF S=14 THEN  LET C=C*7
 2250 GOTO 768
 2300 REM*   This rates coll. 100 ded over sym 7
 2305 LET K=K(4,(A))
 2310 IF S=8 THEN  LET K=K*1.75
 2320 IF S=10 THEN  LET K=K*1.9
 2330 IF S=11 THEN  LET K=K*2.1
 2340 IF S=12 THEN  LET K=K*2.3
 2350 IF S=13 THEN  LET K=K*2.5
 2360 IF S=14 THEN  LET K=K*3.2
 2370 LET K=K*F
 2380 GOTO 810
 2400 REM*  This rates coll. 200 ded over sym 7
 2405 LET K=L(4,(A))
 2410 IF S=8 THEN  LET K=K*1.75
 2420 IF S=10 THEN  LET K=K*1.9
 2430 IF S=11 THEN  LET K=K*2.1
 2440 IF S=12 THEN  LET K=K*2.3
 2450 IF S=13 THEN  LET K=K*2.5
 2460 IF S=14 THEN  LET K=K*3.2
 2465 LET K=K*F
 2470 GOTO 825