100 REM-  COPYRIGHT, FRANK SANDERS,10/19/79
  110 REM-  PROGRAM TO ENTER DEPOSITS AND WITHDRAWALS 
  115 REM- IN VARIOUS BANK OR STOCK ACCOUNTS
  120 DIM A$(50)
  140 PRINT "IF YOU WISH  TO HAVE A TOTAL LISTING ONLY"
  145 PRINT 
  150 INPUT "TYPE 'T',OTHERWISE TYPE ANY LETTER & HIT RETURN ",T$
  160 IF T$="T" THEN 530
  170 PRINT : PRINT : PRINT : PRINT : PRINT 
  180 PRINT "ENTER # OF RECORD. "
  190 PRINT "ENTER DEPOSIT OR WITHDRAWAL "
  200 PRINT "IF NO ENTRY IS TO BE MADE AND YOU WISH TO CHECK "
  210 PRINT "ANY ENTRY, ENTER A ZERO "
  230 PRINT 
  240 FILE #1;"ACCOUNTS/1",,,64,1216
  250 SET XI=1
  260 INPUT "RECORD #",I
  270 PRINT 
  280 IF I=0 THEN  GOTO 390
  290 IF I>12 THEN  GOTO 390
  300 READ #1,I;I,A$,B,A,S,C
  310 PRINT "ACCNT #                 ";%Z;I
  320 PRINT "TITLE                   ";A$
  330 PRINT "BALANCE                $";%C11F2;B
  340 INPUT "ADD TO ACCNT           $",A
  345 INPUT "WITHDRAW FROM ACCT     $",S
  350 LET B=B+A-S
  355 LET T2=T2+A
  356 LET T4=T4+S
  360 PRINT #1,I;I,A$,B,A,S,C
  370 PRINT "EOF() AFTER PRINT =";%Z;EOF(1)
  380 GOTO 260
  390 REM- CHECK ENTRY
  400 PRINT "TO CHECK ANY ENTRY OR RECORD,ENTER THE #. "
  410 PRINT "TO GET LISTING OF TOTAL, ENTER A '0'."
  420 PRINT 
  430 SET XI=1
  440 INPUT "RECORD #",I
  450 IF I=0 THEN  GOTO 530
  460 IF I>12 THEN  GOTO 530
  470 READ #1,I;I,A$,B,A,S,C
  480 PRINT "ACCNT. #             ";%Z;I
  490 PRINT "TITLE                ";A$
  500 PRINT "BALANCE             $";%D;B
  505 PRINT "LAST ADDITION TO ACCOUNT ";A
  506 PRINT "WITHDREW FROM ACCT.   ";S
  520 GOTO 440
  525 CLOSE #1
  530 REM-ROUTINE TO TOTAL
  540 PRINT 
  550 PRINT " NO.  ACCOUNT NAME                    BALANCE   ";
  560 PRINT "  % OF TOTAL"
  570 PRINT "==============================================";
  580 PRINT "==============="
  585 FILE #1;"ACCOUNTS/1",,,64,1216
  586 SET XI=1
  590 FOR I=1 TO 12
  600 READ #1,I;I,A$,B,A,S,C
  610 LET T=T+B
  611 LET T1=T1+C
  613 NEXT I
  614 FOR I=1 TO 12
  615 READ #1,I;I,A$,B,A,S,C
  620 LET C=(B/T)*100
  630 PRINT I;TAB(4);A$;TAB(35);%C11F2;B;
  640 PRINT TAB(55);%6F2;C
  650 PRINT #1,I;I,A$,B,%8F2,A,S,C
  660 NEXT I
  670 PRINT "================================================";
  671 PRINT "==============="
  675 PRINT "     TOTALS FOR THIS ENTRY "
  678 PRINT "     ---------------------"
  680 PRINT "GRAND TOTAL OF ACCOUNTS $";%D;T
  685 PRINT "TOTAL DEPOSITS          $";%D;T2
  687 PRINT "TOTAL WITHDRAWALS      $ ";%D;T4
  689 PRINT "TOTAL PERCENTAGE CHECK   ";%D;T1
  690 END