100 REM-  COPYRIGHT, FRANK SANDERS, 10/19/79
  110 REM-  PROGRAM TO ENTER AMOUNTS IN A PERSONAL EXPENSE FILE
  115 REM- AND OBTAIN READOUT OF TOTALS AND PERCENTAGES
  120 DIM A$(50)
  130 PRINT "IF YOU WISH  TO HAVE A TOTAL LISTING ONLY"
  140 INPUT "TYPE 'T',OTHERWISE TYPE ANY LETTER & HIT RETURN ",T$
  150 IF T$="T" THEN 560
  160 PRINT : PRINT : PRINT : PRINT : PRINT 
  170 PRINT "ENTER # OF RECORD. "
  180 PRINT "ENTER DEPOSIT OR WITHDRAWAL "
  190 PRINT "IF NO ENTRY IS TO BE MADE AND YOU WISH TO CHECK "
  200 PRINT "ANY ENTRY, ENTER A ZERO "
  210 PRINT 
  220 FILE #1;"EXPENSES/1",,,64,1216
  230 SET XI=1
  240 INPUT "RECORD #",I
  250 PRINT 
  260 IF I=0 THEN  GOTO 400
  270 IF I>75 THEN  GOTO 400
  280 READ #1,I;I,A$,B,A,S,C
  290 PRINT "ACCNT #                 ";%Z;I
  300 PRINT "TITLE                   ";A$
  310 PRINT "BALANCE                $";%C11F2;B
  320 INPUT "ADD TO ACCNT           $",A
  330 INPUT "WITHDRAW FROM ACCT     $",S
  340 LET B=B+A-S
  350 LET T2=T2+A
  360 LET T4=T4+S
  370 PRINT #1,I;I,A$,B,A,S,C
  380 PRINT "EOF() AFTER PRINT =";%Z;EOF(1)
  390 GOTO 240
  400 REM- CHECK ENTRY
  410 PRINT "TO CHECK ANY ENTRY OR RECORD,ENTER THE #. "
  420 PRINT "TO GET LISTING OF TOTAL, ENTER A '0'."
  430 PRINT 
  440 SET XI=1
  450 INPUT "RECORD #",I
  460 IF I=0 THEN  GOTO 560
  470 IF I>75 THEN  GOTO 560
  480 READ #1,I;I,A$,B,A,S,C
  490 PRINT "ACCNT. #             ";%Z;I
  500 PRINT "TITLE                ";A$
  510 PRINT "BALANCE             $";%D;B
  520 PRINT "LAST ADDITION TO ACCOUNT ";A
  530 PRINT "WITHDREW FROM ACCT.   ";S
  540 GOTO 450
  550 CLOSE #1
  560 REM-ROUTINE TO TOTAL
  570 PRINT 
  580 PRINT " NO.  ACCOUNT NAME                    BALANCE   ";
  590 PRINT "  % OF TOTAL"
  600 PRINT "==============================================";
  610 PRINT "==============="
  620 FILE #1;"EXPENSES/1",,,64,1216
  630 SET XI=1
  640 FOR I=1 TO 75
  650 READ #1,I;I,A$,B,A,S,C
  660 LET T=T+B
  670 LET T1=T1+C
  680 NEXT I
  690 FOR I=1 TO 75
  700 READ #1,I;I,A$,B,A,S,C
  710 LET C=(B/T)*100
  720 PRINT I;TAB(4);A$;TAB(35);%C11F2;B;
  730 PRINT TAB(55);%6F2;C
  740 PRINT #1,I;I,A$,B,%8F2,A,S,C
  750 NEXT I
  760 PRINT "================================================";
  770 PRINT "==============="
  780 PRINT "     TOTALS FOR THIS ENTRY "
  790 PRINT "     ---------------------"
  800 PRINT "GRAND TOTAL OF ACCOUNTS $";%D;T
  810 PRINT "TOTAL DEPOSITS          $";%D;T2
  820 PRINT "TOTAL WITHDRAWALS      $ ";%D;T4
  830 PRINT "TOTAL PERCENTAGE CHECK   ";%D;T1
  840 END