10 REM:
   20 REM:  Written and donated by Stephen Maguire, July 1980
   30 REM:
   40 DIM L$(65),N$(4)
   50 PRINT CHR(11)
   60 PRINT "ALS-8 to PTDOS; PTDOS to ALS-8 conversion program."
   70 PRINT 
   80 INPUT (1,0)"Which way?  1) A --> P     2) P --> A    :",W$
   90 IF W$<"1" THEN 80
  100 IF W$>"2" THEN 80
  110 PRINT 
  120 INPUT "Which file should I convert? ",F1$
  130 INPUT "Where should I put the resultant file? ",F2$
  140 PRINT 
  150 FILE #3;F1$,1: FILE #4;F2$,2: REWIND #4
  160 LET L$="",N$="0000",C=0,K=-1
  170 IF EOF(3)=6 THEN 360
  180 IF L$<>"" THEN  PRINT #4;L$
  190 SET CM=C: LET C=1-C
  200 LET K=K+1: IF (K+1)/10=INT((K+1)/10) THEN  PRINT ".";
  210 IF (K+1)/600=INT((K+1)/600) THEN  PRINT 
  220 LET X=0
  230 READ #3;L$
  240 IF L$="" THEN  LET X=1: GOTO 230
  250 IF W$="2" THEN 300
  260 IF X=1 THEN  LET L$=CHR(13)+L$
  270 IF LEN(L$)<=6 THEN  LET L$=" ": GOTO 170
  280 LET L$=L$(7)
  290 GOTO 170
  300 LET T$=STR(K)
  310 LET N$(5-LEN(T$))=T$
  320 LET L$=N$+CHR(32)+L$
  330 IF LEN(L$)>64 THEN  LET L$=L$(1,64)
  340 LET L$=CHR(LEN(L$)+2)+L$
  350 GOTO 170
  360 PRINT : PRINT : PRINT "All done."
  370 PRINT STR(K)+" lines processed and stored in file ";F2$
  380 PRINT 
  390 CLOSE #3,#4
  400 SET CM=1
  410 END