10 REM ...AWORD.ECB ..FROM MECC : SHARE   03-01-78
   20 PRINT "&K&J&J"
   30 PRINT TAB(15);"A  W  O  R  D"
   40 PRINT
   50 PRINT
  100 REM ***GUESS WORDS STARTING WITH 'A'. COMPUTER GIVES CLUES.
  110 REM
  120 REM ***VARIABLE TABLES
  130 REM ***A$=ANSWER. S$=SYNONYM. G$=GUESS. R=RIGHTS. W=WRONGS
  140 REM ***N$=ORDINALS. L$=LAST LETTER. D=NUMBER OF DASHES.
  150 REM ***S$=SYNONYM. C COUNTS TRIES. T TOTALS TRIES. Z NUMBER OF WORDS
  160 REM ***CURT TORGERSON, KJHS, ROCHESTER, MN 55901
  170 REM
  175 REM ***INITIALIZATION. READ IN ORDINAL NAMES.
  180 LET Z=9
  190 DIM A$(20),L$(1),N$(80),S$(50)
  200 LET T=0
  210 LET N$="SECOND  THIRD   FOURTH  FIFTH   "
  220 LET N$=N$+"SIXTH   SEVENTH EIGHTH  NINTH   "
  250 PRINT "INFORMATION? ( Y or N ) ---=>";
  260 INPUT (1,0)I$
  265 LET I$=I$+"N"
  270 IF I$(1,1)="N" THEN 360
  280 PRINT "  'AWORD' HAS A BUNCH OF MYSTERY WORDS ALL BEGINNING WITH 'A.'"
  290 PRINT "COMPUTER WILL GIVE YOU CLUES TO HELP YOU GUESS THE WORD."
  300 PRINT "  CLUE 1: LAST LETTER OF MYSTERY WORD."
  310 PRINT "  CLUE 2: A DASH FOR EACH LETTER BETWEEN 1st and LAST LETTERS."
  320 PRINT "  CLUE 3: A WORD OR PHRASE THAT MEANS THE SAME AS THE WORD."
  330 PRINT "  IF YOU CAN'T GET THE MYSTERY WORD, TYPE 'HELP' AND COMPUTER"
  340 PRINT "(KIND SOUL) WILL GIVE YOU THE ANSWER."
  350 PRINT "  TYPE 'DONE' TO STOP 'AWORD.'"
  355 PRINT "  'STARS' WILL KEEP TRACK OF YOUR RIGHTS AND WRONGS."
  360 PRINT
  370 REM
  380 REM ***QUERY AND ANSWER
  390 FOR K=1 TO Z
  400   LET C=0
  410   READ L$,D,S$,A$
  420   LET Q=LEN(A$)
  430   PRINT K;")  A";
  440   FOR J=1 TO D
  450     PRINT "-";
  460   NEXT J
  470   PRINT L$;
  480   PRINT "  <>  ";S$;" ";
  485   IF LEN(S$)>20 THEN  PRINT  ELSE  PRINT "<--";
  490   PRINT "Your guess ---=>";
  500   INPUT G$
  510   IF G$="DONE" THEN 730
  520   IF G$<>"HELP" THEN 550
  530   PRINT "**AW, THE ANSWER IS '";A$;"'."
  540   GOTO 410
  550   IF G$=A$ THEN 660
  560   LET C=C+1
  570   IF C<D THEN 620
  580   PRINT "-->SORRY, ONLY ONE LETTER LEFT. THE WORD IS '";A$;"'."
  590   LET T=T+C
  595   LET W=W+1
  600   PRINT
  610   GOTO 720
  620   PRINT " *NO*  ";N$(C*8-7,C*8);" LETTER IS ";A$(C+1,C+1)
  630   LET W=W+1
  640   LET R=R-W
  650   GOTO 490
  660   LET R=R+2
  670   FOR L=1 TO R
  680     PRINT "*";
  690   NEXT L
  700   PRINT
  710   PRINT
  720 NEXT K
  730 PRINT
  740 PRINT TAB(15);"Thanks for playing  A W O R D."
  750 REM ***LEXICON
  760 DATA "M",2,"TINY PARTICLE","ATOM"
  765 DATA "A",5,"EUROPEAN COUNTRY","AUSTRIA"
  770 DATA "T",3,"CASH","ASSET"
  775 DATA "E",3,"WALK","AMBLE"
  780 DATA "R",4,"RESPONSE","ANSWER"
  785 DATA "A",5,"MATHEMATICS","ALGEBRA"
  787 DATA "K",4,"FIGHT","ATTACK"
  790 DATA "L",3,"ISLAND","ATOLL"
  800 DATA "E",8,"VALUE AND ENJOY SOMETHING","APPRECIATE"
  810 END