100 REM ...DARTS.ECB .. Program by STEVEN V. CASE
  110 REM ...: REVISED 12/8/77      Rev. 03-05-81  R.E.H.
  120 REM ...:
  130 REM ...: ROSEMOUNT SENIOR HIGH SCHOOL
  140 REM ...: ROSEMOUNT, MINNESOTA  55068
  150 PRINT "&K&J&J"
  160 PRINT "SIMULATION OF --> DARTS": PRINT
  170 DIM A$(200),B$(200),Z$(10),S(20),W(20)
  180 PRINT "     In this GAME up to twenty people throw DARTS at"
  190 PRINT "a target with 10, 20, 30, and 40 point zones."
  200 PRINT "       The OBJECT is to get 200 points first."
  210 PRINT
  220 PRINT "THROW","DISCRIPTION";TAB(35);"PROBABLE SCORE"
  230 PRINT " 1","Fast Overarm";TAB(35);"Bullseye or complete miss"
  240 PRINT " 2","Controlled Overarm";TAB(35);"10,20, or 30 points"
  250 PRINT " 3","Underarm";TAB(35);"Anything"
  260 FOR X=1 TO 20: LET B$=B$+"          ": NEXT X
  270 LET R=0,M=0,A$=B$
  280 FOR I=1 TO 20
  290   LET S(1)=0
  300 NEXT I
  310 INPUT "How many players ---=>",N
  315 IF N<1 THEN 960
  320 FOR I=1 TO N
  330   PRINT "Player #";I;", What is your name ---=>";
  335   INPUT Z$
  340   IF LEN(Z$)=0 THEN  LET Z$="Player # "+CHR(I+48)
  350   LET Z$=Z$+"         ": LET B$(I*10-9,I*10)=Z$(1,10)
  360 NEXT I
  370 PRINT
  380 LET R=R+1
  390 PRINT "ROUND ";R
  400 FOR I=1 TO N
  410   PRINT B$(I*10-9,I*10);", What is your throw (1 to 3)";
  420   INPUT (1,0)" ---=>",T
  430   ON T GOTO 450,500,550
  435   FOR X=1 TO N
  436     PRINT ,B$(X*10-9,X*10);" has ";%4I;S(X);" points."
  437   NEXT X
  440   GOTO 410
  450   LET P1=.65
  460   LET P2=.55
  470   LET P3=.5
  480   LET P4=.4
  490   GOTO 590
  500   LET P1=.99
  510   LET P2=.77
  520   LET P3=.43
  530   LET P4=.05
  540   GOTO 590
  550   LET P1=.95
  560   LET P2=.75
  570   LET P3=.45
  580   LET P4=.05
  590   FOR B=1 TO 5
  600     LET Q=RND(0)
  610   NEXT B
  620   IF Q>=P1 THEN 640
  630   GOTO 670
  640   LET B=40
  650   PRINT "BULLSEYE, 40 POINTS"
  660   GOTO 840
  670   IF U>=P2 THEN 690
  680   GOTO 720
  690   LET B=30
  700   PRINT "30-POINT ZONE"
  710   GOTO 840
  720   IF Q>=P3 THEN 740
  730   GOTO 770
  740   LET B=20
  750   PRINT "20-POINT ZONE"
  760   GOTO 840
  770   IF Q>=P4 THEN 790
  780   GOTO 820
  790   LET B=10
  800   PRINT "WHEW 10-POINT ZONE."
  810   GOTO 840
  820   PRINT "MISSED THE TARGET. TOO BAD."
  830   LET B=0
  840   LET S(I)=S(I)+B
  850   PRINT "TOTAL SCORE = ";S(I)
  860 NEXT I
  870 FOR I=1 TO N
  880   IF S(I)>=200 THEN  EXIT 910
  890 NEXT I
  900 GOTO 370
  910 PRINT "WE HAVE A WINNER"
  920 PRINT
  930 PRINT B$(I*10-9,I*10);" SCORED ";S(I);" POINTS."
  940 PRINT
  950 PRINT "THANKS FOR THE GAME.": PRINT : GOTO 970
  960 PRINT TAB(15);"&JThe DART board has been put away."
  970 END