10 REM ...ESP.ECB ..from ?? via Roseville   3-15-81  R.E.H.
   20 PRINT "&K&J&J"
   30 DIM C$(25),D$(25),G$(25),N$(20)
   40 LET Z=0
   41 LET T=0
   50 PRINT "THIS PROGRAM IS USED TO EVALUATE THE POSSIBILITY"
   55 PRINT "OF ESP (EXTRA-SENSORY PRECEPTION) IN AN INDIVIDUAL."
   60 PRINT "THE TEST IS PATTERNED AFTER TESTS BEING RUN IN"
   65 PRINT "PARAPSYCHOLOGY LABORATORIES."
   70 PRINT
   80 INPUT "YOUR NAME PLEASE. ---=>",N$
   85 IF LEN(N$)=0 THEN  LET N$="Anonymous person "
   87 PRINT
   90 PRINT N$;", DO YOU WANT TO GUESS BEFORE OR AFTER THE"
   95 PRINT "COMPUTER SETS UP THE DECK? (ENTER B OR A)";
   96 INPUT (1,0)A$
  100 LET A$=A$+"A"
  105 LET C$="                         "
  110 IF A$(1,1)="A" THEN  GOSUB 500
  113 PRINT
  120 PRINT "YOUR GUESS (* + = $ #):      (Enter 25 symbols)"
  125 PRINT "     ....!....!....!....!....!"
  130 INPUT (25,0)"---=>",G$
  135 GOTO 1100
  140 IF A$(1,1)<>"A" THEN  GOSUB 500
  200 REM ...COMPARISON ROUTIINE
  210 LET N=0
  220 FOR I=1 TO 25
  221   LET X$=G$(I,I)
  230   IF X$=D$(I,I) THEN  LET N=N+1
  240 NEXT I
  300 REM ...OUTPUT RESULTS
  310 PRINT
  312 PRINT "RESULTS:"
  320 PRINT "COMPUTER DECK:  ";
  330 FOR I=1 TO 25
  340   PRINT D$(I,I);
  350 NEXT I
  360 PRINT
  370 PRINT "YOUR GUESSES:   ";G$
  375 GOSUB 999
  380 PRINT "YOU HAD ";N;" CORRECT, WHICH IS ";N/25*100;"%."
  400 LET Z=Z+N
  401 LET T=T+1
  450 PRINT "ANOTHER TRY (Y,N)";
  451 INPUT (1,0)T$
  460 IF T$="Y" THEN  GOTO 110
  465 PRINT
  466 PRINT
  470 PRINT "THE RESULTS FOR ALL OF THE TRIES FOR ";N$
  475 PRINT "are";Z;" correct out of";T*25;" cards."
  480 PRINT "THIS IS AN AVERAGE OF";Z/T/25*100;"%."
  485 PRINT "REMEMBER, CHANCE WOULD BE 20%."
  490 GOTO 2000
  500 REM ...ROUTINE TO CREATE A 25 CARD DECK
  501 REM ...FIRST FILL WITH ALL "A"
  520 LET D$="AAAAAAAAAAAAAAAAAAAAAAAAA"
  530 REM ...PLACE 5 *"S AT RANDOM IN DECK
  535 FOR Q=1 TO 5
  540   LET R=INT(25*RND(0))+1
  550   IF D$(R,R)<>"A" THEN 540
  560   LET D$(R,R)="*"
  570 NEXT Q
  600 REM ...PLACE 5 +'s AT RANDOM IN DECK
  610 FOR Q=1 TO 5
  620   LET R=INT(25*RND(0))+1
  630   IF D$(R,R)<>"A" THEN 620
  640   LET D$(R,R)="+"
  650 NEXT Q
  700 REM ...PLACE 5 ='s AT RANDOM IN DECK
  710 FOR Q=1 TO 5
  720   LET R=INT(25*RND(0))+1
  730   IF D$(R,R)<>"A" THEN 720
  740   LET D$(R,R)="="
  750 NEXT Q
  800 REM ...PLACE 5 $'s AT RANDOM IN DECK
  810 FOR Q=1 TO 5
  820   LET R=INT(25*RND(0))+1
  830   IF D$(R,R)<>"A" THEN 820
  840   LET D$(R,R)="$"
  850 NEXT Q
  900 REM ...FILL REM AINING CARDS as #'s
  910 FOR Q=1 TO 25
  920   IF D$(Q,Q)="A" THEN  LET D$(Q,Q)="#"
  930 NEXT Q
  940 REM ...RETURN TO PROGRAM WITH 25 CARD DECK
  950 RETURN
  999 REM ...ROUTINE FOR ADDING ^ TO MARK MATCHES
 1000 FOR I=1 TO 25
 1001   LET C$(I,I)=" "
 1002 NEXT I
 1005 FOR I=1 TO 25
 1006   LET X$=G$(I,I)
 1010   IF X$=D$(I,I) THEN  LET C$(I,I)="^"
 1020 NEXT I
 1030 PRINT "RIGHT......     ";
 1040 FOR I=1 TO 25
 1050   PRINT C$(I,I);
 1060 NEXT I
 1070 PRINT
 1080 RETURN
 1100 REM ...ERROR ROUTINE FOR INPUT
 1110 IF LEN(G$)<25 THEN 1150
 1120 IF LEN(G$)>25 THEN 1180
 1130 GOTO 140
 1150 PRINT "YOU DID NOT ENTER ENOUGH CHARACTERS.. TRY AGAIN."
 1155 GOTO 120
 1180 PRINT "YOU ENTERED TOO MAY CHARACTERS.  ONLY THE FIRST 25"
 1185 PRINT "WILL COUNT."
 1190 GOTO 140
 2000 END